Flash and ActionScript

Typewriter Effect in Flash ActionScript AS3

2012-09-21T03:06:00.001-07:00

Problem Statement

I wish to display text animation in typewriter format.

Solution

Use Timer to display letters after typing intervals. Play typing sound each time you display the letter.

Source Code

import fl.text.TLFTextField;
import flash.utils.Timer;
import flash.events.TimerEvent;
import flash.events.Event;

const WRITE_TIME:Number = 50;
const BLINK_TIME:Number = 200;
var typewriter_msg:String;
var typewriter_complete_idx:Number=-1;
var blink_timer:Timer = new Timer(BLINK_TIME,0);
var tlf:TLFTextField = new TLFTextField();
tlf.width = stage.stageWidth;
stage.addChild(tlf);

var mySound:Sound = new Sound();
mySound.load(new URLRequest("type.mp3"));


show_typewriter_msg("This is a sample message");

function show_typewriter_msg(msg:String)
{
 stop_blinking();
 typewriter_msg = msg;
 tlf.text = "_";
 
 var timer:Timer = new Timer(WRITE_TIME,1); 
 timer.addEventListener(TimerEvent.TIMER, write_next_letter);
 timer.start();
}
function write_next_letter(e:TimerEvent)
{
 e.target.removeEventListener(TimerEvent.TIMER, write_next_letter);
  
 if(typewriter_complete_idx < typewriter_msg.length-1)
 {
  typewriter_complete_idx++;
  if( typewriter_msg.substr(typewriter_complete_idx,1) != " ")
  {
   mySound.play();
  }
  tlf.text = typewriter_msg.substr(0,typewriter_complete_idx+1);
  var timer:Timer = new Timer(WRITE_TIME,1); 
  timer.addEventListener(TimerEvent.TIMER, write_cursor);
  timer.start();
 }
 else
 {
  keep_blinking();
 }
}
function write_cursor(e:TimerEvent)
{
 e.target.removeEventListener(TimerEvent.TIMER, write_cursor);

 tlf.appendText("_");
 var timer:Timer = new Timer(WRITE_TIME,1); 
 timer.addEventListener(TimerEvent.TIMER, write_next_letter);
 timer.start();
}
function stop_blinking()
{
 blink_timer.removeEventListener(TimerEvent.TIMER, blink_cursor);
 blink_timer.stop();
}
function keep_blinking()
{
 blink_timer.addEventListener(TimerEvent.TIMER, blink_cursor);
 blink_timer.start();
}
function blink_cursor(e:TimerEvent)
{
 if(tlf.text.indexOf("_") >-1)
 {
  tlf.text = typewriter_msg;
 }
 else
 {
  tlf.appendText("_");
 }
}

Download Source Files

You can download source files from here.

2012-08-31T21:52:00.001-07:00

Flash AS3 URLRequest and URLLoader Cache Issue

Problem Statement

I am loading a page from a url, which I dont want to be cahced. I want a refreshed copy each time I try to load it.

Solution

Simply change URLRequestHeader values to set no-cache mode

Source Code

var ldr:URLLoader = new URLLoader();

var req:URLRequest = new URLRequest(link );

var header:URLRequestHeader = new URLRequestHeader("pragma", "no-cache");

req.requestHeaders.push(header);

ldr.addEventListener(Event.COMPLETE,onURLLoaded);

How to copy image from clipboard ( Flash AS3 )

2012-08-26T19:29:00.002-07:00

Problem Statement

I want to copy image from clipboard directly to Flash. How to do it?

Solution

Simply create a clipboard instance and retrieve data in bitmap format. Then create a bitmap using that data!

Source Code - Flash / AS3 / ActionScript


import flash.display.MovieClip;
import flash.desktop.Clipboard;
import flash.desktop.ClipboardFormats;
import flash.desktop.ClipboardTransferMode;
import flash.display.Bitmap;
import flash.display.BitmapData;
 
public function copy_from_clipboard()
{   
 var systemClipboard:Clipboard = Clipboard.generalClipboard;
 var bmd:BitmapData = BitmapData( systemClipboard.getData(ClipboardFormats.BITMAP_FORMAT));
 bmp = new Bitmap(bmd, "auto",true);
 stage.addChild(bmp);    
}

How to access elements in child swf

2012-08-23T00:55:00.000-07:00

Accessing child SWF elements

Problem Statement

I want to load a child SWF and then access elements or movieclips in parent SWF. How to do it?

Solution

In child FLA (from which the child SWF is generated), make sure you have a document class.

Load the SWF in parent using Loader.
Then typecast loader content to child Document.
You can start using this typecasted object to access public elements of child SWF.

Source Code - Flash / AS3 / ActionScript

/*CHILD DOCUMENT CLASS START*/
package  
{
 import flash.display.MovieClip;
 import fl.controls.Button;
 import flash.events.Event;

 public class MyChild extends MovieClip 
 {
  public var btn:Button;
  public function MyChild() 
  {
    btn = new Button();
    addChild(btn);
    btn.x = btn.y = 50;
    btn.label = "Child";
  }
 }
 
}
/*CHILD DOCUMENT CLASS END*/

/*PARENT DOCUMENT CLASS START*/
package  
{
 import flash.display.MovieClip;
 import flash.events.Event;
 import flash.display.Loader;
 import flash.net.URLRequest;
 import fl.controls.Button;
 import flash.events.MouseEvent;

 public class MyParent extends MovieClip 
 {
  var mychild:MyChild;
  public function MyParent() 
  {
   addEventListener(Event.ADDED_TO_STAGE,onAddedToStage);
  }
  public function onAddedToStage(e:Event)
  {
   var loader:Loader = new Loader();
   var url_request:URLRequest = new URLRequest("MyChild.swf");
   loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onChildSWFLoaded);
   loader.load(url_request);
  }
  public function onChildSWFLoaded(e:Event)
  {
   trace("onChildSWFLoaded");
   //add child before referencing. Else you'd get Security Error
   stage.addChild(e.target.content);
   mychild = MyChild(e.target.content);
   mychild.btn.addEventListener(MouseEvent.CLICK,onBtnClicked);
  }
  public function onBtnClicked(e:MouseEvent)
  {
   mychild.btn.label = "Hello";
  }
 }
 
}

/*PARENT DOCUMENT CLASS END*/

Source Files

Download From Here