IT Non-whizzos

Perl: report total size of memory used by certain processes in Linux.

2011-12-16T16:44:00.000-06:00

Nothing fancy in this script. I merely have to write down my scripts somewhere, right?

I originally wrote this to tell me how much memory a certain Apache instance was using. I made it slightly more general purpose. You pass it a regular expression that matches the processes which you want to see the total memory usage of. You can use a debug option to get more verbose output.

I'm aware that the binary itself is not counted multiple times when totaling memory consumption, but in Apache this always comes to less than 10% of the total, so I don't even bother anymore.

Updated version after taking John's excellent suggestions below.

use strict;
use warnings;
use Getopt::Long;

my $debug;
GetOptions('debug|verbose|d|v' => \$debug);

die "Missing regular expression.\n" if ! $ARGV[0];

my $regex = shift;

my @ps_out = qx{ ps -eo pid,vsz,args };

my @proc_lines = grep { m/$regex/ } @ps_out;

my %pids = map { (split)[0,1] } @proc_lines;

delete $pids{$$};

my $total;
my $len = length((sort { $b <=> $a } values %pids)[0]);

for my $pid (keys %pids) {
    $total += $pids{$pid};
    printf "%s = %${len}s\n", $pid, $pids{$pid} if $debug;
}

$len = length($total);
print "=" x ($len + 11);
print "\n";

print "total KB = $total\n" if $debug;

my $mb_total = int($total / 1024);
printf "total MB = %${len}s\n", $mb_total;

My original and very inefficient and inelegant version.

use strict;
use warnings;
use Getopt::Long;

my $debug;
GetOptions('debug|verbose|d|v' => \$debug);

die "Missing regular expression.\n" if ! $ARGV[0];

my $regex = shift;

my @ps_out = qx{ ps -ef };

my @proc_lines = grep { m/$regex/ } @ps_out;

my %pids;

for my $line (@proc_lines) {
    my $pid = (split /\s+/, $line)[1];
    my @out = qx{ ps -o vsz -p $pid };
    chomp @out;
    my $vsz = $out[-1];
    $vsz =~ s/\s+//;
    $pids{$pid} = $vsz;
}

my $total;
my $len = length((sort { $b <=> $a } values %pids)[0]);

for my $pid (keys %pids) {
    $total += $pids{$pid};
    printf "%s = %${len}s\n", $pid, $pids{$pid} if $debug;
}

$len = length($total);
print "=" x ($len + 11);
print "\n";

print "total KB = $total\n" if $debug;

my $mb_total = int($total / 1024);
printf "total MB = %${len}s\n", $mb_total;

Here is me using it.

$ ./1.pl --debug '/httpd\.conf'
5293 =  10696
5298 = 290096
5294 =   7408
5296 = 289124
=================
total KB = 597324
total MB =    583

AJP ping/pong: update to ajp_ping.pl.

2011-11-18T15:43:00.001-06:00

I wrote a terrible ping script for AJP a while back. Here is an updated version.

#!/usr/bin/perl -w

use warnings;
use strict;

use Socket;

my $host = 'localhost';
my $port = '8009';

# The host and port arguments can be specified by either space or colon
# separating the values.
if (scalar(@ARGV) >= 2) {
    $host = shift @ARGV;
    $port = shift @ARGV;
}
elsif (scalar(@ARGV) == 1) {
    if ($ARGV[0] =~ /:/) {
        ($host, $port) = split /:/, shift @ARGV, 2;
    }
    else {
        $host = shift @ARGV;
    }
}

# If the port has anything other than numbers, assume it is an /etc/services
# name.
if ($port =~ /\D/) {
    $port = getservbyname $port, 'tcp' ;
    die "Bad port: $port" unless $port;
}

my $iaddr = inet_aton($host) or die "No such host: $host";

# Get a printable IP address from the in_addr_t type returned by inet_aton().
my $ip = join('.', unpack('C4', $iaddr));

# Now that the port value is a number, and the host (if it was originally a
# name) has been resolved to an IP address, then print a status header like
# the real ping does.
print "AJP PING $host ($ip) port $port\n";

my $paddr = sockaddr_in($port, $iaddr) or die $!;

# Grab the number for TCP out of /etc/protocols.
my $proto = getprotobyname 'tcp' ;

my $sock;
# PF_INET and SOCK_STREAM are constants imported by the Socket module.  They
# are the same as what is defined in sys/socket.h.
socket $sock, PF_INET, SOCK_STREAM, $proto or die $!;

# This is the ping packet.  For detailed documentation, see
# http://tomcat.apache.org/connectors-doc/ajp/ajpv13a.html
# I stole the exact byte sequence from
# http://sourceforge.net/project/shownotes.php?group_id=128058&release_id=438456
# instead of fully understanding the packet structure.
my $ping = pack 'C5'    # Format template.
    , 0x12, 0x34        # Magic number for server->container packets.
    , 0x00, 0x01        # 2 byte int length of payload.
    , 0x0A              # Type of packet. 10 = CPing.
;

# If the connection is closed, log a decent message.
$SIG{PIPE} = sub { die $!; };

connect $sock, $paddr or die $!;

syswrite $sock, $ping or die $!;

print 'Sent:     ';
for my $value (unpack 'C5', $ping) {
    printf '%02d ', $value;
}
print "\n";

my $pong;

$pong = 0;

sysread $sock, $pong, 5 or die $!;

print 'Received: ';
for my $value (unpack 'C5', $pong) {
    printf '%02d ', $value;
}
print "\n";

close $sock or warn $!;

# This is the expected pong packet.  That is, this is what Tomcat sends back
# to indicate that it is operating OK.
my $expected = pack 'C5'    # Format template.
    , 0x41, 0x42            # Magic number for container->server packets.
    , 0x00, 0x01            # 2 byte int length of payload.
    , 0x09                  # Type of packet. 9 = CPong reply.
;

print 'Expected: ';
for my $value (unpack 'C5', $expected) {
    printf '%02d ', $value;
}
print "\n";

if ($pong eq $expected) {
    print "Server pong OK.\n";
    exit 0;
}

print "Server pong FAILED.\n";
exit 1;

Here it is running against a good host.

me@mybox:~/ajp_ping
$ ./ajp_ping.pl xxx 12440 ; echo rc = $?
AJP PING xxx (10.1.1.16) port 12440
Sent:     18 52 00 01 10
Received: 65 66 00 01 09
Expected: 65 66 00 01 09
Server pong OK.
rc = 0

Here is a bad response. I went to an HTTP port instead of an AJP one.

me@mybox:~/ajp_ping
$ ./ajp_ping.pl xxx 12040 ; echo rc = $?
AJP PING xxx (10.1.1.16) port 12040
Sent:     18 52 00 01 10
Received: 72 84 84 80 47
Expected: 65 66 00 01 09
Server pong FAILED.
rc = 1

Here is a timeout (using system TCP timeout defaults).

me@mybox:~/ajp_ping
$ time ./ajp_ping.pl yyy 12040 ; echo rc = $?
AJP PING yyy (10.16.1.8) port 12040
Connection timed out at ./ajp_ping.pl line 67.

real    0m21.031s
user    0m0.010s
sys     0m0.018s
rc = 110

Here is an attempt at a connection to a port where nothing is listening.

me@mybox:~/ajp_ping
$ ./ajp_ping.pl xxx 99 ; echo rc = $?
AJP PING xxx (10.1.1.16) port 99
Connection refused at ./ajp_ping.pl line 67.
rc = 111

Viewing hard drive in Finder on OS X Lion.

2011-11-06T09:50:00.001-06:00

Apple has cleaned up the left column in Finder windows on Lion. It no longer lists the hard drive or the whole computer itself.

So now the way I navigate to top of the hierarchy in a Finder window is my CTRL-clicking on the folder name at the top of the window. This brings up a mini pull down menu of the hierarchy. Like this:

Xcode "Save All" is still Opt+Cmd+S

2011-11-05T07:17:00.000-05:00

Not sure why this was taken from the File pull down menu in the last several versions of Xcode, but the hotkey for it still works: S.

How does UIApplicationMain figure out its delegate?

2011-10-29T19:32:00.001-05:00

I didn't mean to turn this blog into a list of bookmarks, but I was curious how my iOS app got from main.m to MyAppDeletegate.m, and this is just too good an explanation to not document:

http://oleb.net/blog/2011/06/app-launch-sequence-ios/

I found this when I was wondering, "How the hell does the UIApplicationMain figure out its delegate?" Hence, the title of this post. The answer is so simple and straightforward that it is stunning. Thanks in no small part to Ole Begemann, of course.

Add Framework to Project in Xcode 4.1

2011-10-29T17:28:00.000-05:00

Not sure why this got so hard in Xcode 4.1, but this guy covered it great:

http://www.thinketg.com/Company/Blogs/11-03-20/Xcode_4_Tips_Adding_frameworks_to_your_project.aspx

Thank you, David!

Recorded for posterity.

List Windows 7 shares and Twig's Tech Tips

2011-10-10T12:13:00.004-05:00

Thank you Windows guy:

http://twigstechtips.blogspot.com/2009/08/list-and-unshare-folders-in-windows-7.html

You should be the #1 hit for a search of "windows 7 list all shares" instead of #2.

Don't forget this.

2011-07-11T11:48:00.002-05:00

http://en.wikipedia.org/wiki/Dunning%E2%80%93Kruger_effect

I may be stupid, but if I constantly look for this in myself, then I have a better chance of reducing the impact of my stupidity.

Most important NFS link of all time.

2011-07-01T12:23:00.002-05:00

I might be a tad nonobjective about this right now, but everyone should know this:

http://nfsworld.blogspot.com/2005/03/whats-deal-on-16-group-id-limitation.html

Perl throw-away: finding mtime of cron jobs commands from cron log (AIX)

2011-03-16T20:39:00.006-05:00

We had two AIX boxes use all of their memory (real + paging) today. Looking back over performance logs this happened suddenly and exactly on the hour.

The precise time at the top of the hour points to a possible cron job problem. You know how humans are: always scheduling things at nice round numbers.

I wanted to parse the cron logs for all the commands there were run. The first thing I wanted to do was to check the mtime and see if anything changed recently.

Here is a sample of the cron logs AIX spits out.


bob1    : CMD ( [[ -f /opt/bin/Logging.ksh ]] && /opt/bin/Logging.ksh start >/dev/null 2>&1 & ) : PID ( 512208 ) : Wed Mar 16 20:15:00 2011
bob1    : CMD ( /home/bob1/scripts/check.pl ) : PID ( 843892 ) : Wed Mar 16 20:15:00 2011
root      : CMD ( /etc/init.d/agent status > /dev/null 2>&1 || /etc/init.d/agent start > /dev/null 2>&1
) : PID ( 258288 ) : Wed Mar 16 20:15:00 2011
root      : CMD ( /opt/bin/get_down >/dev/null 2>&1 ) : PID ( 548972 ) : Wed Mar 16 20:15:00 2011
Cron Job with pid: 512208 Successful
Cron Job with pid: 548972 Successful
Cron Job with pid: 258288 Successful
Cron Job with pid: 843892 Successful
bob1    : CMD ( [[ -f /etc/init.d/xyz_3.6 ]] && /etc/init.d/xyz_3.6 restart >/dev/null 2>&1 ) : PID ( 950448 ) :
 Wed Mar 16 20:16:00 2011
root      : CMD ( /opt/bin/get_down >/dev/null 2>&1 ) : PID ( 258052 ) : Wed Mar 16 20:16:00 2011
Cron Job with pid: 258052 Successful

Here is my perl script to grab the command and report on their mtimes.


#!/usr/bin/perl -wan

use strict;
use warnings;
use POSIX qw(strftime);

# Hash key = command, value = mtime.
our %cmds;

if ( /CMD \(/ ) {
    if ($F[4] =~ /^\//) {
        $cmds{$F[4]} = strftime('%Y-%m-%dT%H:%M:%S', localtime((stat($F[4]))[9]));
    }
}

END {
    for my $cmd (sort(keys %cmds)) {
        print "$cmds{$cmd}\t$cmd\n";
    }
}

Here is the example output.


root@ccaitacb:/tmp/jmm6ry
# ./1.pl log
2009-11-25T16:03:42     /etc/init.d/agent
2008-04-04T14:33:25     /home/archie/bin/clearWebLogs.sh
2010-09-24T16:49:29     /home/bob1/scripts/check.pl
2003-09-10T13:32:04     /opt/bin/get_webdat
2004-01-06T16:28:08     /opt/bin/nim_prep
2004-01-06T16:28:08     /opt/bin/clr_tmp
2003-09-11T08:12:17     /opt/bin/get_down
2004-04-12T14:36:29     /opt/bin/xy_clr_tmp
2010-03-01T19:18:20     /usr/bin/errclear
2006-10-24T23:34:02     /usr/lib/ras/dumpcheck
2010-10-04T01:55:44     /var/perf/pm/bin/pmcfg

If you're thinking, "Hey, stupid, just look in the crontab files for that info," ummm, yeah, I had a reason for doing it this way, I'm sure of it. I just can't think of it right now.

You'll also see that my script does not actually get all the commands. I guess I need to fix that.

Perl one-liner: count Apache connections to local app servers.

2011-03-06T14:00:00.002-06:00

I had this one-liner lying around that I meant to drop on here. Looking at it I'm fairly certain the scenario was as follows.

This one box has a single Apache (IBM HTTP Server, really) instance talking to a lot of different application servers (WebSphere), which also run locally. Ignore the wisdom or lack thereof for this configuration. For whatever reason (verify load balance settings?), I had to count the number of connections Apache was making to each application server.

root@somebox:/tmp
# lsof -i TCP -P | perl -ane 'next unless /^httpd/ && /->somebox/; $p{(split(":", $F[-2]))[2]}++; END { for $i (keys %p) {print  "$i = $p{$i}\n"}}'
8056 = 305
8054 = 30
8053 = 27
8057 = 31
8050 = 353

So as we can see, at the time I ran this script, the balance of connections was really lopsided. The application server listening on port 8056 had 305 connections and the one listening at port 8054 had 30 connections, and so on.

Perl throw-away: extracting info from giant list of file names.

2011-03-04T17:12:00.009-06:00

I had a giant list of files that followed a pattern similar to this:

me@mybox:~/sandbox
$ ls -rlt
total 0
-rw-r--r-- 1 root root 0 Mar  4 18:10 bob.1234.x
-rw-r--r-- 1 root root 0 Mar  4 18:10 bob.9870.x
-rw-r--r-- 1 root root 0 Mar  4 18:10 bob.3245.x

Except there were thousands of these files, not just three.

I need to get a sorted list of the numbers in each file name. I did this:

me@mybox:~/sandbox
$ perl -e '@f = glob("bob*"); @s = map {substr($_,4,4)} @f; for $n (sort(@s)) {print "$n\n";}'
1234
3245
9870

Yes, I could have done this in the shell.

me@mybox:~/sandbox
$ ls -1 bob* | cut -c5-8 | sort
1234
3245
9870

Using join instead of for now looks pretty because of Anonymous comment below. Thanks, buddy.

jbm@Foucault:~/tmp
$ ls bob*
bob.0012.x bob.7123.x bob.9865.x
jbm@Foucault:~/tmp
$ perl -le '@f = glob("bob*"); @s = map {substr($_,4,4)} @f; print join("\n",sort(@s));'
0012
7123
9865

UPDATE

poisonbit and Yanick have more flexible solutions in the comments below because they don't rely on my brain dead method of counting the exact columns in which the digits appear in the file name.

Of course, poisonbit's solution requires cool bash features, and Yanick's requires newer Perl builds. Using their better answer in crustier Perl or Korn shell is left as an exercise for the reader.

Perl throw-away: Apache HTTP status codes count by hour.

2011-02-16T15:15:00.006-06:00

With the combined LogFormat.


LogFormat "%h %l %u %t \"%r\" %>s %b \"%{Referer}i\" \"%{User-Agent}i\"" combined

I wanted status return code counts for /myuri broken down by hour. I was looking into back end Tomcat problems.


#!/usr/bin/perl -anw

use strict;
use warnings;

our %data;

next if ! m{GET /myuri/};

my $hour = substr($F[3],13,2);

# To get status in this CustomLog format, first, throw away everything up to
# the "GET <URI>" field...
my $status = $_;
$status =~ s/^.*HTTP\/1\.[10]"\s*//;
# ...then grab the first field after that.
$status = (split(/\s+/, $status))[0];

$data{$hour}->{$status}++;

END {
    for my $h (sort(keys %data)) {
        print "$h\n";
        for my $s (sort(keys %{$data{$h}})) {
            print "\t$s = $data{$h}->{$s}\n";
        }
    }
}

Here is some example output.


14
        200 = 48812
        206 = 2
        302 = 31807
        304 = 11926
        400 = 2462
        404 = 2122
        416 = 1
        503 = 339
15
        200 = 40747
        206 = 3
        302 = 24270
        304 = 9157
        400 = 2637
        404 = 2021
        500 = 2
        503 = 399

HP-UX noob warning about /var/adm/sw/save

2011-02-11T12:00:00.002-06:00

If /var is full or nearly full on any HP-UX systems, do not remove anything from the directory /var/adm/sw/save using rm. The only appropriate method of freeing space from this particular directory is:


# cleanup  -c  1

And reply y to the prompt.

I have no idea why, I'm just blindly following an HP-UX coworker's advice. If you want to know more, then man cleanup, obviously.

Xcode creates MainMenu.nib in new project even in version 3.2.5.

2010-12-18T19:03:00.006-06:00

Xcode is creating a MainMenu.nib file instead of a MainMenu.xib file when you select File | New Project. Your Xcode version is 3.2.5 (more or less). This should not be happening. It should be creating XIB files so you can check in Interface Builder files into SCM.

Why is it doing this? You probably upgraded from some old version of Xcode from some old version of OS X. I originally started on Tiger (10.4), and have upgraded straight into Snow Leopard (10.6). There is cruft left from the old installation from years back. Delete these files under /Developer/Library/Xcode/Project Templates/Application/Cocoa Application/Cocoa Application. Notice the dates!

UPDATE: Oops! Except for TemplateChooser.plist, which has a date in the year 2010. Don't delete that!

This thread on Apple support discussions is what lead me to this solution.

Cocoa: +keyPathsForValuesAffecting lowercase letter mistake.

2010-12-18T15:14:00.004-06:00

When you use KVO and create your class method with a name matching the pattern +keyPathsForValuesAffecting<Key> don't forget to capitalize the first letter of the "Key" part.

It might seem obvious to me now, especially with that uppercase "K" in "Key", but all my keys start with a lowercase letter, not uppercase (in keeping with Apple style guidelines), and the KVO Protocol Reference documentation does not call out the uppercase letter requirement. This particular warning is buried within the KVO Programming Guide, instead.

Good:

+ (NSSet *)keyPathsForValuesAffectingAmountInOtherCurrency {
 return [NSSet setWithObjects: @"dollarsToConvert", @"exchangeRate", nil];
}

Bad:

+ (NSSet *)keyPathsForValuesAffectingamountInOtherCurrency {
 return [NSSet setWithObjects: @"dollarsToConvert", @"exchangeRate", nil];
}

Yes, the bad version even looks bad, so I guess I should have figured that out faster.

Perl throw-away script: netstat report on a certain port.

2010-12-15T07:52:00.003-06:00

SYN* means a connection is opening. *WAIT means a connection is closing.


#!/usr/bin/perl -w

use strict;
use warnings;

use Getopt::Std;

our %opt;
getopt('p', \%opt);

my $port = 80;
if (exists $opt{'p'}) {
    $port = $opt{'p'};
}

my @lines = qx{ /usr/bin/netstat -an };

my %status;

for my $line (@lines) {
    my @fields = split /\s+/, $line;

    next if !exists $fields[3];
    next unless $fields[0] =~ /^tcp/;

    if ($fields[3] =~ /\.$port$/) {
        $status{$fields[-1]}++;
    }
}

my $total;
for my $key (keys %status) {
    print "$key = $status{$key}\n";
    $total += $status{$key};
}

print '-' x 15 . "\n";
print "total = $total\n";

Example of running it:


me@mybox:/~
$ ./netstat_port_report.pl -p 8054
CLOSE_WAIT = 1
FIN_WAIT_2 = 166
ESTABLISHED = 148
LISTEN = 1
---------------
total = 316

Perl one-liner: checking Listen ports on Apache HTTP configuration files.

2010-11-25T16:37:00.008-06:00

You stumble upon an installation of Apache HTTP Server that has a few configuration files. You want to do a quick visual inspection of their Listen directives to check for conflicts.

This will also help you find if any Listens are duplicated within a single file. See port 443 in foo_httpd.conf.

jbm@Foucault:~/tmp/conf$ perl -mData::Dumper -ane '$f{$ARGV}->{$F[1]}++ if /^\s*Listen/; END { print Data::Dumper::Dumper(\%f);}' *conf
$VAR1 = {
          'bar_httpd.conf' => {
                                '94' => 1,
                                '494' => 1
                              },
          'admin.conf' => {
                            '8008' => 1
                          },
          'blarf_httpd.conf' => {
                                  '8011' => 1
                                },
          'foo_httpd.conf' => {
                                '90' => 1,
                                '443' => 2,
                                '80' => 1,
                                '490' => 1
                              },
          'httpd.conf' => {
                            '80' => 1
                          }
        };

Yes, this is a long way to type a grep command, but I think the output lends itself more to visual inspection, which is what I'm after.

jbm@Foucault:~/tmp/conf$ egrep '^[[:space:]]*Listen' *conf
admin.conf:Listen 8008
bar_httpd.conf:Listen 494
bar_httpd.conf:Listen 94
blarf_httpd.conf:Listen 8011
foo_httpd.conf:Listen 90
foo_httpd.conf:Listen 443
foo_httpd.conf:Listen 80
foo_httpd.conf:Listen 490
foo_httpd.conf:Listen 443
httpd.conf:Listen 80

What Sony PIIQ clip-on earbuds (Qlasp) look like when worn.

2010-11-25T11:21:00.006-06:00

Suppose you're in Target looking for new headphones for your iPod shuffle because your current behind-the-neck headphones get yanked out of your ears when you're doing push-ups and a few other exercises during your workout. You see what looks like a solution to your problem in the form of the Sony PIIQ™ clip-on earbuds (Qlasp™).

However, because the design is so unique, you are in doubt about how to actually wear them, and you want to confirm your suspicions about the design of these things. So you pull out your iPhone/Android and Google™ for images of folks wearing them but are surprised to find no photos of people wearing them, not even on the Sony site.

Problem solved.

Oh, right! Do they solve my problem? Well, I've stopped using my behind-the-neck headphones and exclusively use the PIIQ clip-ons.

I have not done a scientific survey to see which earphones I mess with less while working out. However, I'm kind of fussy about that. A normal person would probably not fiddle as much as I.

In general, I'd say that behind-the-neck phones are better for straight-out running (maybe, see below). PIIQ clip-on earbuds are better for the quasi-cardio strength training workout that I do when I'm not running. However, even on my runs, I do 22 push-ups and 22 leg lifts every mile, so I still wear my PIIQ clip-ons for my typical run.

I think configuring the PIIQ clip-ons is key to their staying put during activity. During my last run, I used the smallest set of earbuds that came with the PIIQ, and I reset my left earbud only once during the 3 miles (and 66 push-ups, 44 leg lifts, 22 sit-ups). For reasons yet unknown, I could not setup my right ear like my left, so I reset that earbud a lot. There was some subtle positioning I seemed to be missing.

Oops! I did not mean to turn this into a product review. I merely wanted to let other people know what these earbuds looked like while being worn. Here is another view from a slightly different angle.

Perl one-liner: getting sorted fingerprint list from keytool.

2010-11-19T08:51:00.012-06:00

I need to determine which X.509 certificates in one Java keystore are missing from another. I do this by comparing fingerprints. Here is how I get a sorted list of fingerprints from one keystore.

me@mybox:/usr/ibm_java/jre/lib/security
$ keytool -list -keystore cacerts -storepass changeit >~/keytool.out
me@mybox:/usr/ibm_java/jre/lib/security
$ cd ~
me@mybox:~
$ perl -ane '$f{$F[-1]}++ if /fingerprint/; END {for $k (sort {$a <=> $b} keys %f) {print "$k\n";}}' <keytool.out >fingerprints.list

I do this to both keystores.

Once I've got my list of fingerprints from each file, I get a list of fingerprints that are in one file, but not another.


me@mybox:~
$ diff fingerprints_123.list fingerprints.list | perl -ane 'print "$F[-1]\n" if /^>/' >diff_fingerprints.list

Then I wrote this script to read the list of missing fingerprints and tell me the aliases that correspond to these fingerprints in the keystore that has them.


#!/usr/bin/perl -w

# 1st arg = file with list of missing fingerprints.
# 2nd arg = file with keytool output from keystore with additional certs.

use strict;
use warnings;
use Data::Dumper;

# Slurp up all the missing fingerprints.
open my $want_fh, '<', $ARGV[0] or die;
my @wanted = <$want_fh>;
chomp @wanted;
close $want_fh;

my $previous;   # Previous line of keytool.out.
my %data;       # Key = fingerprint, value = line prior to fingerprint.

# Populate %data with all relevant keytool output from file with additional certs.
open my $data_fh, '<', $ARGV[1] or die;
while (<$data_fh>) {
    chomp;
    if (/fingerprint/) {
        $data{(split(/\s/, $_))[-1]} = $previous;
    }
    $previous = $_;
}
close $want_fh;

#print Dumper(\%data);

# Find hash key in %data for each item in @wanted, and print the previous keytool output line.
for my $finger (@wanted) {
        print "$data{$finger}\n";
}

exit 0;

Now that I think about it, I should have just written this as one bigger script instead of two one-liners and a script plus miscellaneous temp files. Oh, well. I'll do that another day.

Perl one-liner: which directories do I need to restore?

2010-11-06T10:56:00.001-05:00

I just ran an automatic process on a directory much higher up in the file system hierarchy than I wanted. Specifically, I accidentally did a Subversion Import on /Users from Xcode SCM dialog.

I can't just do a blanket restore starting at that top level directory. Specifically, Time Machine won't let me restore /Users. I quit Xcode shortly into the operation, and I need to know which subdirectories got hit so I can restore those.

How to do this? Do a find on which files were modified, then parse the output.

jbm@Foucault:~
$ sudo find /Users -mmin -15 -ls >/tmp/screwup.list 2>&1

jbm@Foucault:~
$ perl -ane '$p{join(" ", (split("/", $F[10]))[1..4])}++; END {for $i (keys %p) {print "$i\n";}}' /tmp/screwup.list 
Users jbm Library Preferences
Users jbm Library Application
Users jbm Code CoreDataTutorial
Users jbm Code MyApp
Users jbm Library Cookies
Users jbm Code Build
Users jbm Code SVN
Users jbm Library Caches
Users jbm Library Safari
Users jbm Code
Users jbm .DS_Store

Perl one-liner: listing command line arguments one line at a time.

2010-10-21T14:44:00.000-05:00

You know how Java application servers have loads of command line arguments? And every once in a while you want to list all those arguments one line at a time?

In other words, you want a perl version of using tr to change spaces to newlines.

ps -ef | grep appServerName | tr '[:space:]' '[\n*]'

Here is one way. This lends itself to extending the one-liner for processing the args in some way via @F.

ps -ef | perl -lane 'print join("\n", @F) if $F[-1] =~ /appServerName/'

Here is another.

ps -ef | perl -ne 'next unless /appServerName/; s/\s+/\n/g; print;'

Amoebae and anthropomorphism.

2010-10-21T11:55:00.000-05:00

http://www.cs.utexas.edu/users/EWD/transcriptions/EWD09xx/EWD936.html

Just saving this link for later.

Perl one-liner: a process is communicating with which hosts (using lsof)?

2010-10-21T10:43:00.001-05:00

You want to know which hosts that a process is communicating with. You use lsof. You want a Perl one-liner to parse the output nicely for you.

In the below example, the PID of the process I am observing is 1114114.

lsof -p 1114114 -a -i TCP -P | perl -ane '$h{(split(":", (split("->", $F[-2]))[-1]))[0]}++ if /ESTABLISHED/; END {for $i (keys %h) {print "$i = $h{$i}\n";}}'

Example output:

bob.example.com = 6
lemon.example.com = 12
smart100.example.com = 60
smart101.example.com = 8
windows.example.com = 2

Personal Note: NSOperation and NSOperationQueue and atomicity.

2010-10-03T20:10:00.000-05:00

I may need to review this later.

bbum's weblog-o-mat entry about atomicity, properties, and threading.

Main point I'm getting: don't have two threads (NSOperations) operating on the same instance variables of the same object unless you really, really must, and if you're still thinking you do, then you're probably wrong.

Oh, and atomic != thread-safe != syncronized.