Livecode Italia

I margini del testo

2019-05-21T04:04:00.003+02:00

Quando si mettono i campi nel testo questi hanno i margini impostati a 8 pixel dai bordi.

Ma possiamo cambiarli sia con la proprietà margins per impostare tutti e 4 i valori insieme, ad esempio:

on mouseUp
set the margins of field 1 to 0
end mouseUp

oppure tutti e quattro i lati separatamente:

on mouseUp
set the margins of field 1 to 2,10,10,0
end mouseUp

Oppure potete utilizzare le singole proprietà topMargin, rightMargin , bottomMargin , leftMargin.

Testo giustificato

2019-04-03T04:48:00.000+02:00

Per fare un testo giustificato in livecode non c'è l'opzione già pronta,comunque ci sono delle soluzioni.
Una è un widget gratuito per testi, hhtextEdit:

E' basato sul widget browser ed è pieno di opzioni. Potete scaricarlo da: http://livecodeshare.runrev.com/stack/860/HHTextEditBasic

In alternativa, come seconda soluzione, potete mettere questo codice in un campo di testo:

local finaltext

on closefield
justifyme
end closefield

on justifyme
   lock screen
   put empty into finaltext
   stripspaces
   set the dontwrap of me to true
   put the text of me into temp
   set the text of me to empty

   replace return with (space & chartonum(1) & space ) in temp #we separete words with newlines attached, and much more, newline is a word now

   put the width of me into tw
   put the number of words of temp into nw
   repeat with i=1 to nw
      if word i of temp is chartonum(1) then
         put return after me
         put the text of me after finaltext
         put empty into me
         next repeat
      end if
      put word i of temp after me
      if the formattedwidth of me > tw then
         delete the last word of me
         addspaces 0
         put word i of temp & space into me
      else
         put space after me
      end if
   end repeat
   put the text of me after finaltext
   set the text of me to finaltext
   set the dontwrap of me to false
   unlock screen
end justifyme

on addspaces temp
   if the number of words of me is 1 then
      put the text of me after finaltext
      set the text of me to empty
      exit addspaces
   end if

   put the width of me into tw

   put the number of words of me  -1 into nspaces  #the correct number of spaces between words is nspaces -1, but we'll use mod

   put temp mod nspaces into temp
   add 1 to temp
   put space after word temp of me
   if the formattedwidth of me > tw then
      put the number of chars of word 1 to temp of me into tc
      delete char (tc +1) of me
      put the text of me & space after finaltext
      set the text of me to empty
   else
      addspaces temp
   end if
end addspaces

on stripspaces
   put the text of me into temp
   repeat for each char tchar in temp
      if (tchar is space) and (the last char of t2 is space) then
         next repeat
      else
         put tchar after t2
      end if
   end repeat
   set the text of me to t2
end stripspaces

on resizeControl
justifyme
end resizeControl

Il risultato è buono:

Fare un pulsante toggle

2019-03-22T23:31:00.001+01:00

I pulsati tipo toggle sono pulsanti che rimangono schiacciati finchè non li premete nuovamente. Ecco un esempio:

Per ottenere questo effetto, basta usare il seguente codice:

on MouseUp
   put the hilite2 of me into hitemp
   if hiTemp then
      set the hilite2 of me to false
   else
      set the hilite2 of me to true
   end if
end MouseUp

setprop hilite2 temp
set the hilite of me to temp
set the hilite2 of me to temp
end hilite2

Menu che si espandono

2019-02-22T20:17:00.003+01:00

Oggi vediamo come fare dei menu personalizzati che si espandono.
Negli esempi a seguire userò solo dei pulsanti, ma potete merrci dentro qualsiasi combinazione di oggetti.

Cominciamo dalla fine e vediamo cosa cerchiamo di ottenere:

Per realizzarlo useremo un sacco di gruppi, ecco la struttura che creeremo:

Prima di tutto create un pulsante e chiamatelo main, poi un altro pulsante e chiamatelo +. Ridimensionateli per ottenere questo:

Ora nel pulsante + mettete questo codice:

on mouseUp
   if the label of me is "+" then
      showMe
      set the label of me to "-"
   else
      hideMe
      set the label of me to "+"
   end if
end mouseUp

Raggruppate i due pulsanti insieme e chiamate il gruppo Main.
Ora create un altro pulsante e chiamatelo slider, ridimensionatelo e mettetelo sotto Main in questo modo:

Ora cliccate sul pulsante Slider e fatelo gruppo (si solo del pulsante slider) e chiamate il gruppo Slider.
Adesso raggruppate insieme il gruppo slider col gruppo Main e chiamatelo element 1.
Impostate la proprietà lockLocation del gruppo "element 1" su true.
Mettete questo codice nel gruppo element 1:

on showMe
   repeat while the top of group "Slider" of me < the bottom of group "Main" me - 4
      lock screen
      set the bottom of group "Slider" of me to the bottom of group "Slider" me + 4
      set the height of me to the height of me + 4
      layoutChanged the short name of me, 4
      unlock screen
      wait 10 milliseconds with messages
   end repeat
end showMe

on hideMe
   repeat while the bottom of group "Slider" of me > the bottom of group "Main" of me
      lock screen
      set the bottom of group "Slider" of me to the bottom of group "Slider" of me - 4
      set the height of me to the height of me - 4
      layoutChanged the short name of me, -4
      unlock screen
      wait 10 milliseconds with messages
   end repeat
end hideMe

Clonate il gruppo "element 1" 5 volte, per esempio. Numerati correttamente.
Mettete ogni clone sotto l'elemento precedente, ad esempio il 2 sotto l'uno e così via.
Raggruppateli e chiamate il gruppo List.
Impostate la proprietà lockLocation del gruppo List su true.
Mettete questo codice nel gruppo List:

on layoutChanged pGroup, pSize
   lock messages

   local tElementCount

   if pGroup is "Element Template" then exit layoutChanged

   put word 2 of pGroup into tElementCount
   add 1 to tElementCount -- look for the next one
   repeat while there is a group ("Element" && tElementCount)
      set the top of group ("Element" && tElementCount) to the top of group ("ElemenT" && tElementCount) + pSize--
      add 1 to tElementCount
   end repeat
   set the vscroll of me to the vscroll of me

   if the bottom of group pGroup of me > the bottom of me then
      set the scroll of me to the scroll of me + pSize
   end if
   set the vScrollBar of group "List" to the formattedHeight of group "List" > the height of group "List"
   set the vScroll of group "List" to the vScroll of group "List"
   unlock messages
end layoutChanged

FINITO!!!

Gestionale completo di fatturazione elettronica in italiano

2019-02-19T14:15:00.000+01:00

Ci credereste che sia possibile fare un gestionale completo con la fatturazione elettronica italiana con sole 900 righe di codice? Ebbene con livecode e la società italiana WhiteFly (http://www.borzini.it/) è stato già fatto.
C'è tutto quello che serve ad una azienda: dalle gestione delle anagrafiche, al carico e scarico di magazzino, alla fatturazione e a tutte quelle funzioni richieste da un applicazione del genere.

Per più informazioni scrivete a info@borzini.it

Software gestione negozi e registratori di cassa

2019-02-01T19:40:00.000+01:00

Ecco alcune schermate di un programma realizzato con Livecode per la gestione dei negozi di una catena, e per il software dei registratori di cassa.
Al momento non sono autorizzato a mostrarvi il codice, ma già dalle immagini potete capire che con livecode potete fare praticamente tutto:

Trovare la posizione del cursore in testo

2019-01-25T19:00:00.001+01:00

Se l'utente sta scrivendo un campo di testo (field) e vi serve sapere ad esempio dove si trova il cursore dovete usare il selectedChunk.
Ad esempio per sapere a che riga si trova il cursore potete usare questo codice:

put word 2 of the selectedChunk into temp
put the number of lines of char 1 to temp of field 1

DatePicker

2019-01-23T14:37:00.001+01:00

Datepicker è un plugin per Livecode per selezionare la data (giorno, mese e anno). Avete varie opzione per presentare il selettore della data:

Lo potete ottenere qui: http://www.flexiblelearning.com/datepicker/

Fare un oggetto comune a tutte le card

2019-01-21T12:36:00.001+01:00

Forse alcuni di voi sanno che è possibile fare un oggetto o degli oggetti comuni a tutte le card. Questo oggetto apparirà in tutte le card e se viene modificato un a card, è modificato in tutte.
Per fare ciò basta farne un gruppo, anche se è solo un oggetto, e impostare true le proprietà sharedBehaviour e backGroundBehaviour.
Una volta fatto ciò quando creerete delle nuove card, gli oggetti saranno copiati in automatico e agiranno come un background comune a tutte le card.
Ma se invece già avete delle card, dovete anche utilizzare il comando place group, che trovate anche nel menu Object, per piazzarle nelle card esistenti.

Task List

2019-01-18T14:15:00.000+01:00

Oggi vediamo un semplice programma per tenere conto delle cose da fare, lo potete scaricare da: http://livecodeshare.runrev.com/stack/71/Task-List

Come potete vedere dall'immagine, potete aggiungere le cose da fare, che appariranno nel primo riquadro, mettere la spunta a quelle fatte, che si sposteranno nel secondo riquadro. Potete anche eliminare le note o far sparire la parte col riquadro delle note fatte. Tutto fatto con semplici gruppi.

PreoneStack e OpenStack, come usarli

2019-01-16T06:58:00.000+01:00

Come sapete i messaggi PreOpenStack e OpenStack si attivano all'apertura di una finestra. Ora se mettete questi messaggi nello stack della finestra principale (mainstack), si attiveranno anche quando si aprono altre finestre del vostro programma (substack)che non hanno al loro interno i messaggi PreOpenStack e OpenStack.
Per evitare ciò, vi consiglio di scrivere il codice in questo modo:


on PreOpenStack
  if the owner of the target is me then
     -- code runs for this stack only
     answer "Sono il mainstack"
  else
     -- code runs for any stack that's opened other than this one
     answer "Sono un Substack"
  end if
end PreOpenStack

Shake alert Los Angeles

2019-01-11T04:26:00.003+01:00

Oggi presentiamo un app per iOS fatta con livecode: ShakeAlertLA.
E' un sistema che avvisa se ci sono terremoti a Los Angeles:

Potete scaricarla da qui: https://itunes.apple.com/us/app/shakealertla/id1445922632?mt=8

Fare il gioco snake

2018-12-24T18:10:00.000+01:00

Nel video seguente mostro come fare il gioco snake in soli 15 minuti:

Se volete altri esempi, fatemelo sapere.

Griglia sagonale

2018-12-21T18:32:00.002+01:00

Se volete costruire una griglia esagonale, potete usare questo script: https://forums.livecode.com/download/file.php?id=9687

Per più informazioni: https://forums.livecode.com/viewtopic.php?f=7&t=31220

XML con due voci con lo stesso nome

2018-12-12T19:08:00.000+01:00

Sembrerà ovvio a chi usa XML tutti i giorni, ma certe volte si può dimenticare.
Quando un XML ha una serie di voci identiche, tipo:


<casa>

  <indizzo>Via Roma 3</indirizzo>

  <CAP>00129</CAP>

</casa>
<casa>

 <indizzo>Via Milano 5</indirizzo>

 <CAP>00101</CAP>

</casa>

Allora livecode imposta i seguenti indirizzi nel percorso XML:

casa/indirizzo
casa[2]/indirizzo

Ora lo sapete.

Grafico a torta

2018-11-30T03:01:00.000+01:00

E' disponibile gratuitamente il grafico a torta (widget):

Per usarlo vi basta usare le seguenti proprietà:

sectorValues: mettete i numeri, il widget da solo fa i conti per fare il grafico
SectorLAbels: le etichette dei colori, se volete le etichette
ShowLabel: se volete le etichette o no

Si scarica da qui: https://livecode.com/extensions/pie-chart/1-0-0/

Testo ruotato

2018-11-29T02:45:00.000+01:00

E' disponibili gratuitamente il widget/plugin per il testo ruotato:

Scaricate il widget da qui:
https://livecode.com/extensions/rotated-text/1-0-0/
e poi lo installate premendo il tato + sul finestra dei Tools.

Grafica per Android e iOS

2018-11-28T02:34:00.000+01:00

Sono disponibili dei pacchetti con pulsanti e altri elementi in stile Android e iOS. Anche se potreste farveli da soli, questo pacchetto vi risparmia un sacco di tempo:

Disponibile al costo € 39, solo per le versioni a pagamento di Livecode

Livecode 9.0.2 rc1

2018-11-27T02:30:00.000+01:00

E' uscita la 9.0.2 RC1, disponibile su: https://downloads.livecode.com/livecode/

AnimationEngine open source

2018-11-26T02:26:00.001+01:00

Animation engine per livecode è diventato open source:
https://github.com/derbrill/animationEngine

Immagini scalate prospettivamente

2018-10-13T01:34:00.000+02:00

Oggi vediamo un programma per modificare prospetticamente le immagini:

Lo potete scaricare da qui: http://livecodeshare.runrev.com/stack/893
Vi basterà copiare il gruppo hhPoly nella vostra card ed usare il codice:

send ("setTarget " & the short name of image miaImmagine) to group "hhPoly"

Semplice no?

Libreria per Poker

2018-09-11T12:35:00.000+02:00

Ecco la mia libreria per il gioco del Poker:

on MouseUp
   #hand notation like:
   #1c,2d,3h,4s,13s
   put field "hand" into tHand
   put analPoint(thand) into field 2
end MouseUp

function analPoint tHand
   sort items of thand numeric by the char 1 to -2 of each
   repeat with i=1 to 5
      put item i of tHand into th[i]
   end repeat
   #we must go in order
   #https://www.pagat.com/poker/rules/ranking.html
   ######################
   #Straight Flush
   put true into testsuit
   repeat with i=2 to 5
      if the last char of th[i - 1] is not the last char of th[i] then put false into testsuit
   end repeat
   if testsuit then #they have the same suit
      if checkscale(th) then
         return "Straight Flush: " & maxcard(th,"Straight Flush")
      end if
   end if
   ##############################
   #Four of a kind
   put countDup(th) into duplist
   repeat for each key tKey in duplist
      if dupList[tKey] = 4 then return "Four of a kind: " & tKey
   end repeat
   ###############################
   #Full House
   repeat for each key tKey in duplist
      if dupList[tKey] = 3 then
         put tkey into FH3
         repeat for each key tKey2 in duplist
            if dupList[tKey2] = 2 then
               put tkey2 into FH2
               return "Full House: " & FH3 & "." & FH2
            end if
         end repeat
      end if
   end repeat
   ##############################################
   #Flush
   if testsuit then
      sort items of thand descending numeric by the char 1 to -2 of each
      repeat with i=1 to 5
         delete the last char of item i of thand
      end repeat
      return "Flush: " & thand
   end if
   #####################################################
   #Straight
   if checkscale(th) then
      return "Straight: " & maxcard(th,"Straight")
   end if
   #############################
   #Three of a Kind
   repeat for each key tKey in duplist
      if dupList[tKey] = 3 then
         put tkey into FH3
         return "Three of a Kind: " & FH3
      end if
   end repeat
   #############################
   #Two Pairs
   repeat for each key tKey in duplist
      if dupList[tKey] = 2 then
         put tkey into P1
         put 0 into dupList[tKey]
         repeat for each key tKey2 in duplist
            if dupList[tKey2] = 2 then
               put tkey2 into P2
               put P1 & comma & P2 into PT
               sort items of PT descending numeric
               return "Two Pairs: " & PT
            end if
         end repeat
      end if
   end repeat
   ###########################
   #Pair
   repeat for each key tKey in duplist
      if dupList[tKey] = 2 then
         return "Two Pairs: " & tKey
      end if
   end repeat
   #############################
   #Nothing
   return "Nothing: " & maxcard(th,"Nothing")
end analPoint

function countDup th
   repeat for each element tele in th
      add 1 to temp[char 1 to -2 of tele]
   end repeat
   return temp
end countDup

function checkScale th #check if it is a scale
   if checkace(th) and checkKing(th) then
      put th into th2 #backup
      put swapace(th) into th #now aces are 14 in value
   end if
   #we need to sort again
   put sortedArray(th) into th
   put true into test1
   repeat with i=2 to 5
      if ((char 1 to -2 of th[i-1]) + 1) is not (char 1 to -2 of th[i]) then put false into test1
   end repeat
   return test1
end checkscale

function checkAce th
   put false into test1
   repeat for each element tele in th
      delete the last char of tele
      if tele = 1 then put true into test1
   end repeat
   return test1
end checkace

function checkKing th
   put false into test1
   repeat for each element tele in th
      delete the last char of tele
      if tele = 13 then put true into test1
   end repeat
   return test1
end checkKing

function SwapAce th
   repeat with i=1 to 5
      if char 1 to -2 of th[i] = 1 then put 14 into char 1 to -2 of th[i]
   end repeat
   return th
end SwapAce

function sortedArray @pArray

   # fetch the keys and sort them using the array entry values
   get the keys of pArray
   sort lines of it numeric by char 1 to -2 of pArray[each]

   split it by return

   # create a new sorted array using the mapped keys
   put 1 into tNextIndex
   repeat for each element tIndex in it
      put pArray[tIndex] into tSortedArray[tNextIndex]
      add 1 to tNextIndex
   end repeat

   return tSortedArray
end sortedArray

function maxcard th, hType
   switch htype
      case "Straight"
      case "Straight Flush"
         if checkace(th) and checkKing(th) then
            return "ACE (14)"
         else
            return maxcard2(th)
         end if
         break
      case "Nothing"
         return maxcard2(th)
         break
   end switch
end maxcard

function maxcard2 th
   put 0 into temp
   repeat for each element tele in th
      if char 1 to -2 of tele > temp then put char 1 to -2 of tele into temp
   end repeat
   return temp
end maxcard2

Nuova versione

2018-09-10T11:39:00.000+02:00

Il 4 Settembre è stata rilasciata la versione 9.0.1 RC 3. La potete scaricare da qui: https://downloads.livecode.com/livecode/
Tra le novità abbiamo:

androidRequestPermission: permette di chiedere all'utente su Android dei permessi temporaneamente.
nuove funzione per il volume stereo su Mac
mobileSetFullScreenRectForOrientations
correzioni di vari bug

Video come creare un gioco i pochi minuti

2018-08-29T12:13:00.000+02:00

Ho appena realizzato un video dove mostro come ealizzare un gioco stile Breakout / Arkanoid in pochi minuti.
Lo potete vedere qui:

Lavorare in gruppo

2018-08-22T14:16:00.001+02:00

Come fanno le grandi aziende con grossi team ad usare Livecode?
Questa domanda nasce spontanea quando ci si rende conto che il sorgente livecode è un file binario che contiene tutto, immagini, suoni, codice, ecc.
I sistemi di controllo della versione usuali non gestiscono le differenze di questo tipo di file.
Esistono diverse soluzioni, ma tra le più collaudate c'è Levure, che potete scaricare qui:
https://github.com/trevordevore/levure/wiki
In pratica i programmi creati con Levure/Livecode hanno il codice messo a parte, in file di testo separati, ed è possibile quindi utilizzare qualunque sistema di controllo della versione, come GIT.
Chiaramente ha senso solo se state lavorando in tanti su un enorme progetto.