Oracle Forms

Agilizar la entrada de datos en campos de tipo DATE

2012-02-05T15:49:00.000+01:00

Si tenemos un campo de tipo DATE y que tiene la máscara DD/MM/YYYY el usuario puede introducir la fecha 05022012 y automáticamente se transforma en 05/02/2012, pero en muchos casos puede ser útil permitir al usuario lo siguiente:

Introducir 1 ó 2 dígitos, por ejemplo, teclear 5 y asumir el mes y año del SYSDATE transformando ese 5 tecleado por el usuario en la fecha 05/02/2012.
Introducir 4 dígitos, asumiendo los 2 primeros el día, los 2 dígitos siguientes el mes y el año obtenerlo del SYSDATE.
Introducir 6 dígitos y asumiendo los 2 primeros el día, los 2 siguientes el mes y los 2 últimos el año en formato de 2 dígitos, es decir, se le debe de sumar 2000, de forma que si el usuario teclea 050212 se asuma la fecha 05/02/2012.

Para hacerlo lo que haremos será capturar el error de conversión de máscara de formato FRM-50026 en el disparador ON-ERROR de la siguiente forma:

DECLARE

v_errtyp VARCHAR2(3):= ERROR_TYPE;

v_errnum NUMBER := ERROR_CODE;

v_errtxt VARCHAR2(1000) := ERROR_TEXT;

v_fecha DATE;

v_dia VARCHAR2(2);

v_mes VARCHAR2(2);

v_anho VARCHAR2(4);

v_error BOOLEAN := TRUE;

v_valor_campo VARCHAR2(30);

v_mascara VARCHAR2(30);

BEGIN

IF v_errtyp = 'FRM'

AND v_errnum = 50026

AND Get_Item_Property(:system.trigger_item, DATATYPE) = 'DATE'

AND UPPER(Get_Item_Property(:system.trigger_item, FORMAT_MASK)) = 'DD/MM/YYYY' THEN

-- Capturamos el FRM-50026 en campos de tipo DATE y con máscara DD/MM/YYYY

BEGIN

v_valor_campo := NAME_IN(:system.trigger_item);

IF LENGTH(v_valor_campo) = 1 THEN

-- El usuario sólo teclea un dígito

v_dia := v_valor_campo;

ELSIF LENGTH(v_valor_campo) IN (2, 4, 6) THEN

-- Obtenemos el día de lo que ha tecleado el usuario

v_dia := SUBSTR(v_valor_campo, 1, 2);

END IF;

IF LENGTH(v_valor_campo) IN (4, 6) THEN

-- Obtenemos el mes, sólo si el usuario ha tecleado algo de 4 ó 6 dígitos

v_mes := SUBSTR(v_valor_campo, 3, 2);

END IF;

IF LENGTH(v_valor_campo) = 6 THEN

-- Obtenemos el año, sólo si el usuario ha tecleado algo 6 dígitos

v_anho := TO_CHAR(TO_NUMBER(SUBSTR(v_valor_campo, 5, 2)) + 2000);

END IF;

-- Obtenemos el mes y el año de SYSDATE en caso de que haber sido tecleado por el usuario

v_mes := NVL(v_mes, TO_CHAR(SYSDATE, 'MM'));

v_anho := NVL(v_anho, TO_CHAR(SYSDATE, 'YYYY'));

v_fecha := TO_DATE(v_dia || '/' || v_mes || '/' || v_anho, 'DD/MM/YYYY');

-- El comando COPY únicamente está preparado para asignar un valor VARCHAR2,

-- con variables de tipo DATE debemos de asegurar la máscar de formato

-- con la que hará conversión.

v_mascara := Get_Application_Property(BUILTIN_DATE_FORMAT);

Set_Application_Property(BUILTIN_DATE_FORMAT, 'DD/MM/YYYY');

COPY(TO_CHAR(v_fecha, 'DD/MM/YYYY'), :system.trigger_item);

Set_Application_Property(BUILTIN_DATE_FORMAT, v_mascara);

v_error := FALSE;

EXCEPTION

WHEN OTHERS THEN

-- Ante cualquier error dejamos el mensaje original de error

NULL;

END;

END IF;

IF v_error THEN

-- No se ha podido transformar lo tecleado por el usuario en una fecha válida

MESSAGE(v_errtyp || '-' || TO_CHAR(v_errnum) || ': ' || v_errtxt);

RAISE Form_Trigger_Failure;

END IF;

END;

Cambiar icono de Java en Forms 10g y 11g

2011-05-12T09:09:00.000+02:00

Vía: http://blog.edisa.com/2011/05/cambiar-icono-de-java-en-forms-10g-y-11g/

Cuando se ejecuta una aplicación en Forms 10g ó 11g en una ventana independiente del navegador, es decir, con separateframe=true, el icono que se le asigna a la ventana en la barra de tareas es el de la taza de café de Java.

Este icono se puede modificar para poner uno personalizado. Ejemplo:

Para cambiar el icono hay que utilizar el procedimiento WebUtil_SeparateFrame.SetIcon de la librería WEBUTIL.PLL.

Ejemplo: WebUtil_SeparateFrame.SetIcon(‘/forms/java/libra_menu.gif’);

El icono que se indica por parámetro debe de tener formato GIF o JPG y debe de encontrarse en la carpeta en donde están los jar de Java ($ORACLE_HOME/forms/java). En caso de no encontrar el archivo en esa carpeta dará el siguiente error: “WUB-603: No se ha podido cargar la imagen del icono …..”

El icono quedará guardado en la caché de Java para futuras ejecuciones:

Maximizar Ventana MDI en Forms 11

2011-04-14T19:39:00.000+02:00

Fuente: http://blog.edisa.com/2011/04/maximizar-ventana-mdi-en-forms-11/

En Forms 11 una de las novedades es la integración con JavaScript y eso se puede aprovechar para forzar el maximizado completo de la ventana MDI cuando que ejecuta en una ventana separada del navegador, es decir, cuando se ejecuta con el parámetro separateframe=true
Al ejecutar SET_WINDOW_PROPERTY(forms_mdi_window, window_state, maximize); el maximizado no es completo, hace un ajuste según el tamaño de la pantalla, pero no es equivalente a que si el usuario pulsa el botón de maximizado.
Para que sea equivalente a que el usuario pulse el botón de maximizar hay que realizar lo siguiente:

En el archivo formsweb.cfg añadir la siguiente línea a la sección de la configuración (El nombre que se le asigne a la variable es indiferente, pero tiene que ser el mismo dos sitios que están resaltados en negrita):
- applet_name=OracleApplet
Desde Forms ejecutar:
- web.javascript_eval_expr(‘document.OracleApplet.getFrame().setExtendedState(6)’);

Ejemplo con SET_WINDOW_PROPERTY(forms_mdi_window, window_state, maximize);

Ejemplo ejecutando web.javascript_eval_expr(‘document.OracleApplet.getFrame().setExtendedState(6)’);

Otro ejemplo similar se puede ver en: http://blog.avanttic.com/2010/07/30/integracion-forms-11g-con-javascript-maximizar-forms_mdi_window/

Forms6: Cerrar Report Background por código

2010-04-17T20:35:00.000+02:00

Hace tiempo comenté aquí la forma de cerrar el Report Background Engine cada vez que se ejecuta un informe Forms6: Forzar cierre report background, en ese momento comenté que no me parecía muy optimo el cierre del Report Background Engine cada vez que se lanza un informe, pero alguna vez se me dio la necesidad de hacerlo por dos motivos:

El usuario tenía que ejecutar dos programas en Forms con distinta configuración de NLS_LANG, uno con SPANISH_SPAIN.UTF8 y otro con SPANISH_SPAIN.WE8ISO8859P15, de forma que al ejecutar un informe se abría el Report Background con la configuración de NLS_LANG del programa que lo llamaba y el otro programa al tener abierto el Report Background no cogía bien la configuración del NLS_LANG, en ese caso lo mejor es forzar que se cierre el Report Background por cada informe.

Conexiones remotas por Terminal Server con un programa publicado en Forms. Al lanzar un informe se abre el Report Background y queda abierto y al salir del programa se mantiene la conexión de Terminal Server por culpa del Report Background cuando en realidad ya no va a ser utilizado, en ese caso lo mejor sería forzar cerrar el Report Background al salir del programa, para ello podemos forzar que el Report Background se cierre ejecutando lo siguiente en el disparador KEY-EXIT del programa:

DECLARE

pl_id ParamList;

BEGIN

pl_id := Get_Parameter_List('CERRAR_RBE');

IF NOT Id_Null(pl_id) THEN

Destroy_Parameter_List( pl_id );

END IF;

pl_id := Create_Parameter_List('CERRAR_RBE');

Add_Parameter(pl_id, 'PARAMFORM', TEXT_PARAMETER, 'NO');

Add_Parameter(pl_id, 'ORACLE_SHUTDOWN', TEXT_PARAMETER, 'Yes');

Run_Product(REPORTS, 'cerrar_rbe', SYNCHRONOUS, RUNTIME, FILESYSTEM, pl_id, NULL);

Destroy_Parameter_List( pl_id );

END;

El informe 'cerrar_rbe' no es necesario que exista, simplemente se intenta ejecutar un informe pasándole el parámetro para forzar el cierre del Report Background.

¿Las claves foráneas producen bloqueos en Forms?

2010-01-19T22:56:00.000+01:00

La respuesta es que si no hacemos bien las cosas es SI. Vamos a verlo mejor con un ejemplo con las típicas tablas de formación que utiliza Oracle, DEPT y EMP:

CREATE TABLE dept (
  deptno NUMBER(2) NOT NULL CONSTRAINT dept_pk PRIMARY KEY,
  dname VARCHAR2(14),
  loc VARCHAR2(13));

CREATE TABLE emp (
  empno NUMBER(4) NOT NULL CONSTRAINT emp_pk PRIMARY KEY,
  ename VARCHAR2(10),
  job VARCHAR2(9),
  mgr NUMBER(4),
  hiredate DATE,
  sal NUMBER(7,2),
  comm NUMBER(7,2),
  deptno NUMBER(2) CONSTRAINT emp_ref_dept_fk
   REFERENCES dept(deptno));

Insertamos un departamento:

INSERT INTO dept (deptno, dname, loc)
  VALUES (23, 'CONTABILIDAD', 'VIGO');

COMMIT;

Ahora insertamos un empleado:

INSERT INTO emp (empno,ename,job,mgr,
   hiredate,
   sal,comm,deptno)
  VALUES (1234, 'MARIOBROS', 'FONTA', 10,
   TO_DATE('16/05/1975', 'DD/MM/YYYY'),
   50000, 2000, 23);

Antes de hacer el commit, al ver los bloqueos veremos que están la tabla EMP y la DEPT bloqueadas.

SELECT lk.sid, lk.TYPE lock_type, lk.lmode,
   (SELECT o.object_name
   FROM dba_objects o
   WHERE o.object_id = lk.id1) object_name
  FROM gv$lock lk
WHERE lk.TYPE IN ('TM', 'UL');

Lo que nos devolverá será esto:

   SID LO LMODE OBJECT_NAME
------ -- --------- ----------------
   311 TM 3 EMP
   311 TM 3 DEPT

El bloqueo de la tabla EMP es por el registro que acabamos de insertar pero que todavía no está commitado, pero la tabla DEPT se bloquea por la clave foránea, ya que en el momento de insertar el registro en EMP existía el departamento 23 en DEPT, pero como no hemos comitado el insert en EMP tiene que bloquear el registro del departamento 23 para evitar que otra sesión borre ese registro o modifique el código del departamento.

Hasta aquí todo normal, el problema viene cuando otra sesión quiere modificar el nombre del departamento:

UPDATE dept
   SET dname = 'FINANCIERO'
WHERE deptno = 23;

Con esta update nos dejará modificarlo sin problema, pero si en vez de hacer un update que únicamente modifica el nombre del departamento hacemos este otro (el resultado final de los datos en la tabla serán los mismos):

UPDATE dept
   SET deptno = 23,
   dname = 'FINANCIERO',
   loc = 'VIGO'
WHERE deptno = 23;

El registro quedaría con los mismos datos, pero ya tenemos el bloqueo montado ya que le estamos diciendo que actualice el campo DEPTNO, pero la modificación de ese campo afectaría a registros introducidos por otra sesión y que todavía no están comitados, por lo que se quedará bloqueado.

Esta es la explicación del motivo, pero ¿porqué ocurre en Forms?. La respuesta la encontramos en la propiedad "Actualizar Sólo Columnas Cambiadas" a nivel de bloque, por defecto esa propiedad está a "No" con lo que para hacer un update actualizará todos los campos, incluso los que no ha modificado el usuario.

Lo recomendable para evitar bloqueos es poner esa propiedad al valor "Si".

Inyección de código

2009-11-29T13:58:00.001+01:00

Voy a mostrar un ejemplo de como mediante inyección de código podemos consultar registros de una tabla distinta a la que tiene el bloque como origen de consulta.

Para ver el ejemplo hacemos un form asociado a la tabla DEPT (tabla típica de los ejemplos de Oracle):

SQL> DESC DEPT;
Nombre ¿Nulo? Tipo
------------------- -------- ------------------
DEPTNO NUMBER(2)
DNAME VARCHAR2(14)
LOC VARCHAR2(13)

Pantalla con los datos de la tabla:

Ahora vamos a ver como con ese bloque mostrar el contenido de USER_TAB_COLUMS, para ello entramos en modo de entrada consulta (pulsando F7) y en cualquiera de los campos ponemos ":" (dos puntos) y ejecutamos consulta, y tendremos la siguiente pantalla:

El objetivo de esa ventana es que el usuario pueda introducir una condición avanzada, como podría ser un AND EXISTS, un BETWEEN, ..., pero la consulta Oracle Forms la envía a la base de datos tal cual ha sido escrita por el usuario, por lo que podemos introducir lo siguiente:

1=2) UNION ALL SELECT rownum, table_name, column_name FROM user_tab_columns --

El 1=2 es para evitar los registros de la tabla DEPT, luego se añade una UNION ALL para sacar los registros de la tabla que queramos, y la consulta la terminamos con -- ya que Forms a la consulta que introduce el usuario la mete entre paréntesis, de esta forma comentamos el último parénteseis.

El resultado será el siguiente:

Este funcionamiento se puede deshabilitar, evitando que al introducir ":" en modo de entrada de consulta en un campo de forma que no se abra al ventana en donde introducir una condición adicional, para ello en Forms6 en cliente servidor se puede introducir la siguiente entrada en el regedit:

FORMS60_RESTRICT_ENTER_QUERY con el valor 1

En Forms 10g para activar o desactivarlo hay que editar el archivo al que apunta la variable envFile del archivo de configuración formsweb.cfg y modificar / añadir la variable:

FORMS_RESTRICT_ENTER_QUERY=TRUE

TRUE: Está desactivado (opción recomendable).
FALSE: Está activado, se puede inyectar código.

NOTA: Corregida esta entrada, estaba al revés

Para más información se puede consultar la nota 163305.1 del metalink. También en http://www.red-database-security.com/wp/sql_injection_forms_us.pdf se puede obtener más información.

Asignar una función la tecla escape en Forms10g

2009-11-28T20:59:00.004+01:00

Una utilidad de la tecla ESC (Escape) y muy utilizada en muchas aplicaciones es la de cerrar la ventana abierta. Esta operación se puede configurar en Forms 10g editando el archivo frmweb.res y añadiendo la siguiente línea:

27 : 0 : "Escape" : 32 : "Salir"

27: es el identificador "Java function number" asignado a la tecla escape.
0: Indica el "Java modifiers number" es decir, qué combinación de teclas más la Escape se pulsarán para ejecutar el evento, el 0 quiere decir que no se utilizará en conjunto con otra tecla, si se pusiese 1 para ejecutar el evento habría que pulsar Mayúsculas+Esc, con 2 haríamos referencia a la tecla "Control", con 8 a la tecla "Alt". .
"Escape": Es un texto asignado por el usuario, no afecta al funcionamiento.
32: es el identificador "Forms function number" que indentifica la operación que debe se debe de ejecutar en Forms. El 32 indica que se ejecutará KEY-EXIT.
"Salir": Es un texto asignado por el usuario, no afecta al funcionamiento.

El archivo fmrweb.res se encuentra en $ORACLE_HOME/forms/admin/resource/

En caso de configurar el servidor de aplicaciones en UTF8 se utiliza el archivo fmrweb_utf8.res.

Se considera que el servidor de aplicaciones está en UTF8 cuando en el archivo indicado en la entrada envFile del archivo formsweb.cfg tiene definida la siguiente variable:

NLS_LANG=Spanish_Spain.UTF8

Configurar Oracle XE para que conecte correctamente Forms 6i

2009-10-29T21:53:00.002+01:00

Por defecto Oracle XE se instala con el juego de caracteres AL32UTF8, con ese juego de caracteres el cliente de Oracle Forms 6i no conecta con la base de datos, para migrar ese juego de caracteres a UTF8 puro debemos de ejecutar lo siguiente:

sqlplus /nolog
SQL> connect / as sysdba
Conectado.
SQL> shutdown immediate
SQL> startup restrict
SQL> alter database character set internal_use UTF8;
SQL> shutdown immediate
SQL> startup

Hay ciertos índices que Oracle si existen no puede realizarse la conversión ya que dará el siguiente error:

ORA-00604: error occurred at recursive SQL level 1
ORA-54028: cannot change the HIDDEN/VISIBLE property of a virtual column

Podemos ver los índices incompatibles mediante esta SELECT:

SELECT owner, index_name, index_type, table_owner, table_name, status, funcidx_status

FROM all_indexes

WHERE index_type NOT IN ('NORMAL', 'BITMAP', 'IOT - TOP')

AND table_name IN (SELECT UNIQUE (table_name)

FROM dba_tab_columns

WHERE char_used = 'C');

Hay que borrarlos y luego volver a crearlos una vez convertido a UTF8.

Problemas de rendimiento de Forms10g con antivirus NOD32

2009-10-20T20:42:00.004+02:00

El antivirus NOD32 tiene activado por defecto la opción analizar todo el tráfico HTTP, lo que hace ralentizar tremendamente el funcionamiento de las aplicaciones en Forms 10g (por lo menos en la versión 4.0.314.0).

Para desactivar ese control hay que abrir NOD32, ir a Configuración, pinchar en "Muestra las opciones avanzadas de configuración" y en la sección "Antivirus y antiespía" -> "Protección del tráfico de Internet" -> "HTTP, HTTPS" y desactivar la check "Activar el análisis HTTP".

Evidentemente es un fallo de NOD32 ya que Forms10g por defecto usa el puerto 7778 y los puertos que en teoría analiza por defecto son los 80, 8080 y 3128. Además si configuramos excluir algunas direcciones no soluciona nada, la única opción es desactivar totalmente el análisis http.

Formas de cargar un List Item por código

2009-04-17T21:28:00.003+02:00

Directamente desde una sql

El proceso se basa en un grupo de registros que creamos en base a una sql dinámica "v_grupo := Create_Group_From_Query('RecorG', v_sql);", para cargar la lista de elementos en base al grupo usamos la instrucción "POPULATE_LIST".

Cuando creamos el ítem del bloque podemos dejarlo sin ningún valor, pero nos va a dar una advertencia de compilación un poco molesta, pero totalmente inocua. Si queremos que no nos dé, simplemente abrimos los elementos de lista y en el primer elemento le quitamos el campo "Valor de elemento de Lista" y como el valor por inicial es NULL y ese elemento es NULL no nos va a protestar.

Ejemplo:

DECLARE
v_sql VARCHAR2(200); -- Variable para construir la SELECT dinánica.
v_grupo RecordGroup; -- Variable en donde vamos a meter el grupo de registros temporalmente.
v_estado_empresa ESTADOS.CODIGO%TYPE := 'ESPA'; -- Variable que contiene el valor que queremos mostrar por defecto.
BEGIN
/*
Construimos la SELECT. En el primer campo sacamos
lo que queremos que muestre la lista y en el segundo
campo el valor correspondiente que va a devolver
por la selección (normalmente un código).*/

v_sql := 'SELECT INITCAP(nombre), codigo FROM estados ORDER BY nombre';

-- Asignamos el resultado de la select al grupo de registros.
v_grupo := Create_Group_From_Query('RecorG', v_sql);

-- Construimos la lista, siempre y cuando la select devolviese registros.
IF POPULATE_GROUP(v_grupo) = 0 THEN
POPULATE_LIST('B1.ESTADO', V_Grupo);
END IF;

-- Borramos el grupo, liberamos memoria que ya no nos hace falta.
DELETE_GROUP(v_grupo);

-- Asignamos el valor por defecto que queremos.
:b1.estado := v_estado_empresa;

-- Si el campo es obligatorio deberíamos de poner esto para que nos elimine el elemento en blanco.
Set_Item_Property('B1.ESTADO', REQUIRED, PROPERTY_TRUE);
END;

Elemento a elemento

Para limpiar un List-item se hace con la instrucción CLEAR_LIST('BLOQUE.CAMPO');

Para ir añadiendo elementos se hace con ADD_LIST_ELEMENT('BLOQUE.CAMPO', , , );

* : Será un número que identifica cada elemento, se comenzará a numerar en el 1.
* : Texto que visualizará en el desplegable el usuario.
* : Valor que toma el campo cuando se selecciona.

Ejemplo:

DECLARE
CURSOR cur_clientes IS
SELECT codigo_rapido, nombre
FROM clientes;

v_indice NUMBER;
v_primer_cliente CLIENTES.CODIGO_RAPIDO%TYPE;
BEGIN
Set_Item_Property('B1.CLIENTE', REQUIRED, PROPERTY_FALSE);
CLEAR_LIST('B1.CLIENTE');

FOR reg IN cur_clientes LOOP
v_indice := v_indice + 1;
Add_List_Element('B1.CLIENTE', v_indice, reg.nombre, reg.codigo_rapido);

IF v_primer_cliente IS NULL THEN
v_primer_cliente := reg.codigo_rapidol;
END IF;
END LOOP;
:b1.cliente := v_primer_cliente;
Set_Item_Property('B1.CLIENTE', REQUIRED, PROPERTY_TRUE);
END;

Instalar Forms6i para linux en Enterprise Linux 5.2

2009-04-17T21:25:00.001+02:00

En primer lugar hay que crear el grupo dba, oinstall y el usuario oracle:

groupadd dba # group of users to be granted SYSDBA system privilege
groupadd oinstall # group owner of Oracle files
useradd -c "Oracle software owner" -g oinstall -G dba oracle
chown -R oracle.oinstall /oracle

Añadir las siguientes líneas al archivo .bash_profile:

export ORACLE_HOME=/oracle/dev6i
export LD_LIBRARY_PATH=$ORACLE_HOME/lib:$ORACLE_HOME/network/jre11/lib/linux/native_threads/:/usr/X11R6/lib/
export ORACLE_AUTOREG=$ORACLE_HOME/guicommon6/tk60/admin
export PATH=$PATH:$HOME/bin:$ORACLE_HOME/bin

Instalar gcc: yum install gcc

Instalar los siguientes paquetes:

libXp-1.0.0-8.1.el5.i386.rpm
lesstif-0.95.0-15.el5.kb.i386.rpm
compat-glibc-7.x-2.2.4.32.6.i386.rpm
openmotif-devel-2.1.30-5_ICS.i386.rpm
openmotif-2.1.30-5_ICS.i386.rpm

Descomprimir el archivo d2k6irelease2.tar (por ejemplo en /oracle/software), pero no instalarlo.

descomprimir p3851446_600_LINUX.zip (por ejemplo en /oracle/parche) y ejecutar la instalación, para ello ejecutamos lo siguiente:

export D2K6I_R2_SHIPHOME=/oracle/software/
cd /oracle/parche/bug3851446
./d2k6ir2_install_wrapper.sh

Descomprimir el archivo p6194129_60828_LINUX (parche 19) en la carpeta /software/dev6i

Ejecutar en entorno gráfico lo siguiente:

cd /oracle/dev6i/developer6i_patch19
./patch_install.sh

Relincar:

cd $ORACLE_HOME/procbuilder60/lib; make -f ins_procbuilder.mk install
cd $ORACLE_HOME/forms60/lib; make -f ins_forms60w.mk install
cd $ORACLE_HOME/graphics60/lib; make -f ins_graphics60w.mk install
cd $ORACLE_HOME/reports60/lib; make -f ins_reports60w.mk install

Forms 6i para Windows sobre Linux

2008-11-30T12:37:00.003+01:00

En la versión 1.1.9 de wine (todavía versión de desarrollo) han solucionado el bug que provocaba que el runtime de forms diese un error de protección general.

Hay que decir que Forms6i tiene versión para Linux, pero los ejecutables (fmx) no son compatibles con los ejecutables de Windows, por lo que si desarrollamos en una plataforma Linux y los ejecutables los tenemos que distribuir para Windows esta es la única solución.

Lo he probado sobre Fedora 10 y la verdad es que me he quedado gratamente sorprendido por la agilidad con la que se mueve.

Seleccionar columnas de texto en editor PL/SQL

2008-09-22T18:43:00.002+02:00

En el editor PL/SQL si seleccionamos con el ratón manteniendo la tecla ALT pulsada podemos seleccionar columnas de texto en vez de líneas completas. Ejemplo:

Personalizar espacios al tabular en editor PL/SQL

2008-09-22T18:18:00.003+02:00

En el editor de PL/SQL de Forms al pulsar la tecla TAB por defecto introduce 2 espacios (a mi particularmente es lo que utilizo simpre), pero si queremos cambiarlo podemos modificar (o insertar en caso de no existir) la variable DE_PREFS_TABSIZE en el regedit en HKEY_LOCAL_MACHINE\Software\Oracle.

Si se utiliza un script para lanzar el builder con las varibles de entorno configuradadas (tal como explico en el post: Configurar varios entornos de desarrollo) en el script simplemente es añadir un nuevo set de la forma: set DE_PREFS_TABSIZE=valor

Oracle Forms 6i en Windows de 64 bits

2008-04-01T22:10:00.001+02:00

Oracle Forms para Windows no está certificado para ninguna versión de 64 bits (Windows Vista, Microsoft 2003/2008 Server). Qué no esté certificado no quiere decir que no funcione, simplemente que Oracle en caso de problema no va a proporcionar ningún tipo de soporte.

Windows Vista de 32 bits no está certificado pero a mi en concreto desde un principio me ha dado menos problemas que Forms10g, pero Oracle Forms 6i en 64 bits a partir del parche 4 no funcionan las llamadas a los reports que se realizan desde forms, tampoco funciona desde Forms Builder ejecutar el formulario que estamos diseñando.

Como he dicho antes el problema surge a partir de parche 4 de forms, con el parche 3 o anterior funciona perfectamente, pero hay casos como el mío en donde ya estaba usando el parche 17 donde no podemos plantear volver al 3 ya que nos fallarían muchas más cosas.

El problema en concreto se encuentra en las librerías nn60.dll y nnb60.dll que se encuentran en la carpeta BIN. Estas librerías creo que gestionan la comunicación entre aplicaciones de Forms, forms con reports, builder con debugger, etc.

En mi caso he instalado el parche 17 y he metido esas librerías del parche 3 y funciona todo correctamente.

En los siguientes enlaces dejo las librerías del parche 3, de forma que si teneis problemas simplemente renombrais las que teneis instaladas y copiais estas:

nn60.zip
nnb60.zip

NOTA 29/10/2009: PROBLEMAS DETECTADOS

Graphics no funciona
Los reports que tienen filtros con listas de valores no funcionan bien.

Parche 3 de Oracle Forms 10.1.2 (10.1.2.3)

2008-04-01T22:05:00.000+02:00

Desde el 19 de Marzo está disponible en el Metalink la actualización del servidor de aplicaciones IAS 10.1.2 en donde viene incluido Oracle Forms 10g. De momento solo está disponible para Microsoft Windows y Solaris, pero no creo que tarde mucho la de Linux.

En esta versión como principal novedad es la certificación de Windows Vista.

Más información en la página del OTN http://www.oracle.com/technology/products/forms/index.html

Developer Suite 10g en Windows Vista

2008-03-16T20:43:00.000+01:00

En primer lugar debemos de cambiar la memoria el modo de funcionamiento virtual de Windows Vista durante la instalación, luego la dejaremos como estaba.

Vamos a Inicio -> en el icono Equipo pulsamos con el botón derecho y vamos a propiedades. En la ventana que nos abre pulsamos en "Cambiar la configuración".

En la pestaña "Opciones avanzadas" pulsamos el botón "Configuración" de la sección "Rendimiento"

En la ventana que se abre vamos a la pestaña "Opciones avanzadas" y pulsamos en el botón "Cambiar" de la sección "Memoria Virtual".

En la ventana que se abre quitamos la check "Administrar automáticamente el tamaño del archivo de paginación para todas las unidades" y ponemos un tamaño para el archivo de paginación personalizado y luego pulsamos el botón "Establecer" y luego en "Aceptar".

Nos pedirá reiniciar, reiniciamos.

Para ejecutar la instalación de setup.exe, primero pulsamos con el botón derecho y en la pestaña "Compatibilidad" activamos "Ejecutar en modo de compatibilidad para: Windows XP (Service Pack 2)".

A partir de aquí instalamos de forma normal y una vez finalizada la instalación podemos volver a poner como estaba la configuración de la memoria virtual.

Forms6: Forzar cierre report background

2008-02-01T11:19:00.000+01:00

Puede no tener mucho sentido el cerrar el report background una vez se lanza un informe, ya que la siguiente vez que se intente lanzar otro informe tiene que volver a abrirse con la consiguiente pérdida de tiempo, pero hay casos en que puede ser util.

Para forzar el cierre del report background en cuando termine con el informe hay que añadir a la lista de parámetros que se le pasa al report el siguiente parámetro:

ADD_PARAMETER (, 'ORACLE_SHUTDOWN', TEXT_PARAMETER, 'Yes');

Abrir varias ventanas del Editor PL/SQL

2008-01-24T16:27:00.001+01:00

Cuando en el navegador de objetos hacemos doble click sobre una unidad de programa (paquete, función, disparador) nos cierra el Editor PL/SQL que teníamos abierto y abre el nuevo, para hacer que no cierre el lo que teníamos abierto y abra una nueva ventana simplemente al hacer doble click pulsamos la tecla MAYUSCULAS.

Forms 6 y Forms 10g: Generar archivo excel (XLS)

2007-10-05T22:06:00.002+02:00

En Jakarta hay un proyecto que consiste en un API para manipular y generar documentos de Office sin necesidad de tener Office instalado, luego los documentos resultantes se pueden abrir con cualquier suite ofimática, como por ejemplo OpenOffice.

http://poi.apache.org/trans/es/index.html

En el momento de escribir esto la última versión era la 3.0.1 y las clases necesarias se encuentran en el archivo poi-3.0.1-FINAL-20070705.jar

Para poder usar estas clases en un programa de forms tenemos que hacer los siguientes pasos:

Forms 10g:

En primer lugar añadir a la variable de entorno CLASSPATH el archivo poi-3.0.1-FINAL-20070705.jar (si se usa un archivo de comandos para lanzar el Forms Builder simplemente hay que añadir: set CLASSPATH=...)
Importar las clases, para ello en el navegador de objetos vamos al menú "Programa" y luego a "Importar Clases Java...".

En esta ventana seleccionamos las clases:

org.apache.poi.hssf.usermodel.HSSFWorkbook
org.apache.poi.hssf.usermodel.HSSFRow
org.apache.poi.hssf.usermodel.HSSFSheet
org.apache.poi.hssf.usermodel.HSSFCell
java.io.FileOutputStream (posiblemente tengamos que añadir al CLASSPATH el archivo rt.jar

Una vez importadas las clases nos crea paquetes PL/SQL para poder interactuar con ellas, por lo que ahora simplemente hay que escribir el código PL/SQL normal.

Para poder ejecutar el programa hay que añadir el archivo poi-3.0.1-FINAL-20070705.jar al CLASSPATH en el servidor. Para ello miramos en el archivo formsweb.cfg que se encuentra en $ORACLE_HOME/forms/server la variable envFile, y al archivo que apunta es donde tenemos que modificar la variable CLASSPATH.

Forms 6i:

Hay que usar una máquina virtual de Java versión 1.4.2 o superior, lo he probado con la 1.4.2_06 y con 1.6.0_02.
Añadir a la variable de entorno PATH las carpetas: (Sustituir c:\program files\java\jdk1.6.0_02 por la carpeta en que tengamos instalado el jdk, si no lo configuramos correctamente nos dará el error: "PDE-UJI001 Fallo al crear JVM." al intentar importar las clases)

C:\Program Files\Java\jdk1.6.0_02\bin
C:\Program Files\Java\jdk1.6.0_02\jre\bin
C:\Program Files\Java\jdk1.6.0_02\jre\bin\client

Al igual que en Forms 10g hay que añadir a la variable CLASSPATH el archivo poi-3.0.1-FINAL-20070705.jar
Añadir también al CLASSPATH el archivo importer.jar que se encuentra en $ORACLE_HOME\tools\common60\java
Al igual que en Forms 10g, en el programa que se quiera usar hay que importar las mismas clases Java que se indican en el apartado para Forms 10g (esas son necesarias para los ejemplos, pero seguramente que en un caso real tengamos que importar más), para ello vamos al menú "Programa" y luego a "Importar Clases Java...".

Ejemplos:

Ejemplo New Workbook de Jakarta POI

HSSFWorkbook wb = new HSSFWorkbook();
FileOutputStream fileOut = new FileOutputStream("workbook.xls");
wb.write(fileOut);
fileOut.close();

Equivalente en Forms

DECLARE
v_wb      ORA_JAVA.JOBJECT;
v_fileout ORA_JAVA.JOBJECT;
BEGIN
v_wb := hssfworkbook.new();
v_fileout := fileoutputstream.new('workbook.xls');
hssfworkbook.write(v_wb, v_fileout);
fileoutputstream.close(v_fileout);
END;

Ejemplo New Shet de Jakarta POI

HSSFWorkbook wb = new HSSFWorkbook();
HSSFSheet sheet1 = wb.createSheet("new sheet");
HSSFSheet sheet2 = wb.createSheet("second sheet");
FileOutputStream fileOut = new FileOutputStream("workbook.xls");
wb.write(fileOut);
fileOut.close();

Equivalente en Forms:

DECLARE
v_wb       ORA_JAVA.JOBJECT;
v_fileout  ORA_JAVA.JOBJECT;
v_sheet1   ORA_JAVA.JOBJECT;
v_sheet2   ORA_JAVA.JOBJECT;
BEGIN
v_wb := hssfworkbook.new();
v_sheet1 := hssfworkbook.createsheet(v_wb, 'new sheet');
v_sheet2 := hssfworkbook.createsheet(v_wb, 'second sheet');
v_fileout := fileoutputstream.new('workbook.xls');
hssfworkbook.write(v_wb, v_fileout);
fileoutputstream.close(v_fileout);
END;

Ejemplo Creating Cells de Jakarta POI

HSSFWorkbook wb = new HSSFWorkbook();
HSSFSheet sheet = wb.createSheet("new sheet");

// Create a row and put some cells in it. Rows are 0 based.
HSSFRow row = sheet.createRow((short)0);
// Create a cell and put a value in it.
HSSFCell cell = row.createCell((short)0);
cell.setCellValue(1);

// Or do it on one line.
row.createCell((short)1).setCellValue(1.2);
row.createCell((short)2).setCellValue("This is a string");
row.createCell((short)3).setCellValue(true);

// Write the output to a file
FileOutputStream fileOut = new FileOutputStream("workbook.xls");
wb.write(fileOut);
fileOut.close();

Equivalente en Forms:

DECLARE
v_wb         ORA_JAVA.JOBJECT;
v_fileout    ORA_JAVA.JOBJECT;
v_sheet      ORA_JAVA.JOBJECT;
v_row        ORA_JAVA.JOBJECT;
v_cell       ORA_JAVA.JOBJECT;
BEGIN
v_wb := hssfworkbook.new();
v_sheet := hssfworkbook.createsheet(v_wb, 'new sheet');
v_row := hssfsheet.createrow(v_sheet, 0);
v_cell := hssfrow.createcell(v_row, 0);
hssfcell.setcellvalue(v_cell, 1);
v_cell := hssfrow.createcell(v_row, 1);
hssfcell.setcellvalue(v_cell, 1.2);
v_cell := hssfrow.createcell(v_row, 2);
hssfcell.setcellvalue(v_cell, 'This is a string');
v_cell := hssfrow.createcell(v_row, 3);
hssfcell.setcellvalue(v_cell, TRUE);
v_fileout := fileoutputstream.new('workbook.xls');
hssfworkbook.write(v_wb, v_fileout);
fileoutputstream.close(v_fileout);
END;

Ejemplo para enviar el contenido de un bloque a una excel:

DECLARE
v_wb               ORA_JAVA.JOBJECT;
v_fileout          ORA_JAVA.JOBJECT;
v_sheet            ORA_JAVA.JOBJECT;
v_row              ORA_JAVA.JOBJECT;
v_cell             ORA_JAVA.JOBJECT;
v_fin              BOOLEAN := FALSE;
v_bloque           VARCHAR2(30) := :system.cursor_block;
v_record_anterior  NUMBER := :system.cursor_record;
v_item_anterior    VARCHAR2(61) := :system.cursor_item;
v_item             VARCHAR2(30);
v_num_celda        NUMBER;
v_num_fila         NUMBER;
BEGIN
v_wb := hssfworkbook.new();
v_sheet := hssfworkbook.createsheet(v_wb, 'new sheet');
v_num_fila := 0;

FIRST_RECORD;

WHILE NOT v_fin LOOP
v_row := hssfsheet.createrow(v_sheet, v_num_fila);
v_num_fila := v_num_fila + 1;
v_item := Get_Block_Property(v_bloque, FIRST_ITEM);
v_num_celda := 0;

WHILE v_item IS NOT NULL LOOP
v_cell := hssfrow.createcell(v_row, v_num_celda);
hssfcell.setcellvalue(v_cell, NAME_IN(v_bloque || '.' || v_item));
v_item := Get_Item_Property(v_bloque || '.' || v_item, NEXTITEM);
v_num_celda := v_num_celda + 1;
END LOOP;

IF :system.last_record = 'TRUE' THEN
v_fin := TRUE;
ELSE
NEXT_RECORD;
END IF;
END LOOP;

v_fileout := fileoutputstream.new('workbook.xls');
hssfworkbook.write(v_wb, v_fileout);
fileoutputstream.close(v_fileout);

GO_RECORD(v_record_anterior);
GO_ITEM(v_item_anterior);
END;

NOTA 15/12/2009: Las versiones recientes de las librerías de Jakarta POI están compiladas para usar una máquina virtual de java superior a la que tiene Forms 10g. Al importar en Forms10g sale este mensaje: "Se ha producido una excepción: java.lang.UnsupportedClassVersionError: org/apache/poi/hssf/usermodel/HSSFWorkbook (Unsupported major.minor version 49.0)". Con la versión 3.0.1 de las librerías funciona perfectamente. Esta versión se puede descargar de aqui: http://sites.google.com/site/elfeme/files/poi-3.0.2-FINAL-20080204.zip?attredirects=0&d=1

Forms10g: Modificar apariencia

2007-09-30T20:37:00.000+02:00

En el archivo formsweb.cfg se dispone del parámetro lookAndFeel para modificar la apariencia de la aplicación, los valores que puede tomar son:

generic: Apariencia típica de Windows
oracle: Apariencia por defecto definida por Oracle. Dentro de esta apariencia se puede usar el parámetro colorScheme para modificar el conjunto de colores usados. Los valores que puede tomar son:

teal
red
titanium
blue
khaki
olive
purple
blaf: Este en concreto no está soportado oficialmente por Oracle fuera de Oracle Applications.

Podemos modificar estos parámetros en el archivo formsweb.cfg o también a través de la url, por ejemplo: http://direccionequipo:8889/forms/frmservlet?config=prueba&lookandfeel=generic

Forms10g: clientDPI

2007-09-23T17:21:00.001+02:00

Se me ha dado el caso de una aplicación desarrollada en Forms10g sobre plataforma Windows, que al desplegarse en algún sistema Linux se veían las pantallas demasiado pequeñas.

Dependiendo de la aplicación, puede ser que parezca que es problema de las fuentes, en mi caso la aplicación al arrancar se maximizaba y ocupaba toda la pantalla y eso hacía que pareciese que el problema fuera con las fuentes.

El problema se encuentra en los puntos por pulgada que usa la máquina virtual de Java. La configuración de los puntos por pulgada se puede variar añadiendo el parámetro clientDPI en el archivo de configuración formsweb.cfg en la sección de nuestra aplicación, por ejemplo:

[prueba]
form=prueba.fmx
...
clientDPI=96

Para que el applet tenga en cuenta este parámetro tenemos que modificar los archivos webutiljpi.htm, webutiljini.htm, webutilbase.htm, basejpi.htm, basejini.htm y base.htm. En realidad solo sería necesario modificar los que terminan en jpi (Java plug-in) ya que en Linux no se puede instalar el Jinitiator por lo que nunca podríamos usar los que terminan en jini (Jinitiator), pero podría ser que en ordenadores Windows con Jinitiator quisiesemos alterar este valor, por lo que modificarlos todos no está más.

La modificación que hay que hacer es la siguiente (para el webutiljpi.htm):

Después de la línea: <param name="WebUtilMaxTransferSize" value="%WebUtilMaxTransferSize%">

Añadir:

<param name="clientDPI" value="%clientDPI%">

Después de la línea: WebUtilMaxTransferSize="%WebUtilMaxTransferSize%"

Añadir la línea:

clientDPI="%clientDPI%"

Ejemplo del formulario de prueba a 96 dpi:

Ejemplo del formulario de prueba a 50 dpi:

Para hacer pruebas para encontrar el valor que mejor se nos ajuste, no hace falta estar modificando el archivo de configuración formsweb.cfg, podemos alterar el valor añadiendo el parámetro clientDPI a la url, por ejemplo: http://equipo:8889/forms/frmservlet?config=pru&form=test&clientDPI=50

Para más detalles consultar la nota 1071248.6 en el metalink.

Configurar varios entornos de desarrollo

2007-09-22T11:09:00.001+02:00

Muchas veces se me ha dado el caso de tener que trabajar en varios proyectos, donde las librerías (plls) y librerías de objetos (olb) son distintas y se encuentran en varios directorios, la solución que solía hacer era modificar la variable FORMS60_PATH en el regedit, pero un día se me ocurrió una idea que consiste en lo siguiente:

Por cada entorno de ejecución me hice un script que inicializa las variables de entorno y luego arranca el Forms Builder, incluso ya arranca conectado con la base de datos que quiero.

Ejemplo: Nombre del script produccion.cmd

set FORMS60_PATH=L:\olb;L:\adaptaciones;L:\plls;L:\mmx;L:\fmxs
set UI_ICON=L:\iconos
set REPORTS60_PATH=L:\adaptaciones;L:\plls;L:\reps
set PATH=c:\oracle\dev6i\bin
set NLS_LANG=SPANISH_SPAIN.WE8ISO8859P15
set NLS_DATE_FORMAT=DD/MM/YYYY
set NLS_NUMERIC_CHARACTERS=,.
set NLS_SORT=BINARY
set REPORTS60_TMP=c:\temp
start ifbld60 userid=usuario/password@cadenaconexion

Ejecutando el script primero inicializa las variables y luego arranca el Forms Builder. Si tenemos otro proyecto y las librerías están en otros directorios hacemos otro script de forma similar.

En caso de Forms10g es muy similar solo hay que cambiar los nombres de las variables de entorno, por ejemplo no es FORMS60_PATH, sería FORMS_PATH y el ejecutable no es ifbld60, sería frmbld

Forms 6: Enviar correo con adjunto a través de Outlook

2007-09-13T22:32:00.000+02:00

Con este código nos permite añadir un mensaje en la bandeja de salida y luego enviarlo o mostrar el mensaje para ser enviado luego por el usuario.

DECLARE
v_outlookapp ole2.obj_type;
v_namespace ole2.obj_type;
v_mailitem ole2.obj_type;
v_oleparam ole2.list_type;
v_attachments ole2.obj_type;
BEGIN
v_outlookapp := ole2.create_obj('Outlook.Application');
v_oleparam := ole2.create_arglist;
ole2.add_arg(v_oleparam, 'MAPI');
v_namespace := ole2.invoke_obj(v_outlookapp, 'GetNameSpace', v_oleparam);
ole2.destroy_arglist(v_oleparam);
v_oleparam := ole2.create_arglist;
ole2.add_arg(v_oleparam, 0);
v_mailitem := ole2.invoke_obj(v_outlookapp, 'CreateItem', v_oleparam);
ole2.destroy_arglist(v_oleparam);
ole2.set_property(v_mailitem, 'To', 'xxxx@xxxmail.com');
ole2.set_property(v_mailitem, 'Subject', 'Asunto');
ole2.set_property(v_mailitem, 'Body', 'Texto del mensaje');

-- Añadimos el adjunto
v_attachments := ole2.get_obj_property(v_mailitem, 'Attachments');
v_oleparam := ole2.create_arglist;
ole2.add_arg(v_oleparam, 'C:\Temp\prueba.pdf');
ole2.invoke(v_attachments, 'add', v_oleparam);
ole2.destroy_arglist(v_oleparam);

-- Con esta línea invocamos el envío, si queremos
-- simplemente abrir el Outlook para que pueda revisar
-- el correo cambiamos 'Send' por 'Display'
ole2.invoke(v_mailitem, 'Send');

ole2.RELEASE_OBJ(v_mailitem);
ole2.RELEASE_OBJ(v_namespace);
ole2.RELEASE_OBJ(v_outlookapp);
END;

Sin adjunto sería parecido pero con menos código, ahí va el ejemplo:

DECLARE
v_outlookapp ole2.obj_type;
v_namespace ole2.obj_type;
v_mailitem ole2.obj_type;
v_oleparam ole2.list_type;
BEGIN
v_outlookapp := ole2.create_obj('Outlook.Application');
v_oleparam := ole2.create_arglist;
ole2.add_arg(v_oleparam, 'MAPI');
v_namespace := ole2.invoke_obj(v_outlookapp, 'GetNameSpace', v_oleparam);
ole2.destroy_arglist(v_oleparam);
v_oleparam := ole2.create_arglist;
ole2.add_arg(v_oleparam, 0);
v_mailitem := ole2.invoke_obj(v_outlookapp, 'CreateItem', v_oleparam);
ole2.destroy_arglist(v_oleparam);
ole2.set_property(v_mailitem, 'To', 'xxxx@xxxmail.com');
ole2.set_property(v_mailitem, 'Subject', 'Asunto');
ole2.set_property(v_mailitem, 'Body', 'Texto del mensaje sin adjunto');

-- Con esta línea invocamos el envío, si queremos
-- simplemente abrir el Outlook para que pueda revisar
-- el correo cambiamos 'Send' por 'Display'
ole2.invoke(v_mailitem, 'Send');

ole2.RELEASE_OBJ(v_mailitem);
ole2.RELEASE_OBJ(v_namespace);
ole2.RELEASE_OBJ(v_outlookapp);
END;

Tetris en Forms

2007-09-12T00:02:00.000+02:00

Hace tiempo me encontré el juego del Tetris programado en Forms, en concreto en la versión 6. Me llamó la atención la forma en que captura las pulsaciones de las teclas, ya que Oracle Forms no tiene forma de manejar las pulsaciones de teclado de forma nativa (se podría hacer usando Java), por lo que hay que usar trucos.

En concreto el truco que han usado aqui es, para la tecla arriba y abajo capturan los eventos KEY-UP y KEY-DOWN respectivamente y para capturar las pulsaciones de las techas derecha e izquierda usan un campo de tipo radio-button oculto a la vista, es decir alto y ancho cero, entonces cuando se pulsa la techa derecha se lanza el evento WHEN-RADIO-CHANGED y a la izquierda lo mismo.

tetris.fmb en content-type.com
tetris.fmb en www.oraclehome.co.uk

Conclusión: No es matar moscas a cañonazos, es lo contrario, es como ir a la guerra usando alfileres como arma, pero es muy interesante lo que se puede llegar a hacer con un entorno de desarrollo 4gl que no está pensado precisamente para juegos.