Blog Vadakuma

Quiz Constructor

2016-01-16T09:51:00.000-08:00

Quiz Constructor is a tool for create simple quizzes. You will not to write a code because all settings it has in special inspector window as a Unity editor extension. There are many settings about start screen, question settings by questions type, result screen, UI, timers. Simply add a new question in a question list, setup it and play. Questions can be different types. At the moment the tool give 3 question types:

Standart question: the text or image question.
Category question: to combine the phrases or images by categories.
Comparison question: compare a description with a image or a name.

Web Player
Web GL
Apk demo

Asset Store Page

Video tutorial

Features:

- 3 types of question: Standart/Category/Comparison.
- Many settings for each of the questions type.
- Flexible settings of the quiz mode.
- Full source code.
- Free demo quiz example in the package.
- The Documentation and video tutorial.
- Mobile/WebPlayer/PC/WebGL support.

PS. Last version 1.0.5.

Documentation

Swipe SlideShow. Tutorial

2015-08-12T01:17:00.000-07:00

With this script you can quickly make simple presentation from slides of any subject. The endless swipe system allow to moving the slides in any direction (left|right or up|down) without limits.

Features:

Infinity swiping to any direction.
Easy swipe settings.
Auto-resize in depends of display resolution.
PC/android/ios/webplayer platforms
Example demo scene included
Autosliding.
Image loading by one button.
Horizontal|Verical swipe mode.
No events back timer available.
Sound control

WEB DEMO
Asset Store Page

Video demostartion:

Last version: 1.3.1

Instruction below.

Show Room for 3D models. Tutorial

2015-08-09T05:38:00.000-07:00

1 Introduction

The represented tool allowing to show the arts/models showcase for the 3D artist with web Unity player and also to create the demonstration presentations on any subjects.

The tool have a wide set of settings which it will be necessary to will be modified as required and inquiries.
In a package there is already adjusted scenes ready to use, remains only to add the models following the applied instruction.

Web Player Demo

Asset Store Page

Feachers
- Splitting objects into categories
- Playing of animation from the list
- The rotating camera with different settings
- Automatic adding objects in prefabs by Tag
- Automatic camera rotation
- Automatic switching of objects
- Simple settings for a scene
- Draw description of 3d model
- A choice of several scenes directly during viewing (3 simple scenes)
- Customisable UI scene elements
- Usage tutorial and video

Result we can see on this video:

See tutorial below

2 Usage guide

Firstly, add unitypackage in the project.

Open ShowRoom scene from Scenes folder.

Select "RootEmpty" prefab in the "Prefabs/Roots" folder project. Make copy for own scene and drag to the scene. You will see the Primary and the BaseGUI scripts.

Primary (Script)

Main parametr in this script is Obj Categories. It is a list of all objects splitted on categories.
At start we should add own object|3d models or prefabs in the project.
If some objects are available animation, add to them "Animation" component and add in animations array your animation clips.

When they are added you can modify Obj Categories.

1) Add all objects to the scene and create your own Tag for them.

2) Select all objects and set created Tag.

3) Select Root object and open Primary component. You will see some buttons. But previosly you should set your objects tag in Objects Tag submenu.

Set Destroy objects after addition trigger to true if you want to automatic delete all objects from scene when they added to the list.

4) Click on Add Objects to Category by Tag button.

Script create Asset/Prefabs/MyTag_Prefabs folder and save all taging objects as prefabs. Now taging objects from scene aren't necessary any more.

In Obj Categories created special category of object with your Tag.

5) Now you can add/change description/name/animation for all objects in selected category.

6) Click to Aplly button for save root prefab. (It is important)

Save this scene as MyShowRoom.scene, for example. Now you can play and see result.

BaseGUI (Script)

BaseGUI controlling all UI action in show room. At the moment you can change only 4 special UI groups.
Prev Next Group - draw two button for switching object
Description Group - draw name and description text about current object

Anims Group - draw animations list for current object and button play/stop
Category Group - draw categories list.

You can change position/size/drawing/content position/content size to all 4 UI group.

Main Scene Light - add there scene light to controlling light intecity in game.

Draw Debug GUI Layers - need for tests where was click|touch in game. If on gui layer - we will not rotate the camera. For reposition and resizing set Draw Debug GUI Layers trigger to true.

Show Scenes - add your scenes to this array and you can switching them in game from SceneSettings UI group.

CameraOrbit (Script)

Camera Orbit script component is in MainCamera object, but you can add this script on other object. Script automaticaly find Camera.main object.

Previosly, create new special emptyObject or use CameraPoint object in RootEmpty prefab and set to Target.

Target - center of rotation of the camera.

Use Auto Rotation Mode - if this mode active you can not rotate camera.
Use Auto Rotation Mode On Idle - automatic camera rotation activationg when no touches.

3 Video instructions

See also the video tutorial how to add models in show room:

See the video tutorial how to modify UI groups in show room:

4 Additional Info

See also my other asset packs:
Camera Pack
Transform Randomizer

Contact details below:

vadakuma@gmail.com

2015.

Скрипт для Unity. "Transform Randomizer"

2015-08-02T13:44:00.000-07:00

Функциональность скрипта довольно простая. По заданному тэгу или имени скрипт случайно изменяет выбранные параметры transform в указанных диапазонах для всех найденных на сцене объектов. Тем самым можно случайно задать расположение, направление, размер по отдельности, или все вместе. Также, ввиде эксперимента тот же механизм применен для изменения выбранного параметра в материле(точнее цвет материла). Т.е. можно изменить цвет/оттенок в материале из указанной палитры.

AssetStore

Демонстрация работы:

Скрипт Камеры на Unity

2015-08-02T13:27:00.000-07:00

Собрал в одну кучу часть наработок по камере и оформил в более менее приемлемом виде. Теперь можно просто добавить в проект настроить по своему усмотрению. Имеется несколько режимом работы, ингейм переключение между режимами, а также довольно широкий список регулируемых параметров для каждого режима.

Ссылка на страницу asset store:

Скриншоты из демки

Сама демка: DEMO

Возможно кого-нибудь заинтересует :)

Проверка актуальности udk

2013-08-12T10:46:00.001-07:00

По стечению обстоятельств, на данный момент большую часть времени работаю с unity. Не сказал бы, что сильно этим огорчен, все таки кодинг там куда удобнее, чем на udk.

Но так или иначе, даже при более подробном знакомстве с столь нынче популярным unity, мне все также приятнее работать с udk, и желания бросать движок окончательно, не появляется.
Причины конечно исключительно субъективны, да и движки уж больно разного профиля, чтобы их всерьез сравнивать, но все же :)
Вот небольшой пример, что можно сделать на udk, по сути в одиночку(да,да, левел-диз из меня никудышный, да и анимации нету, я по большей части программист, ну и конечно статус у проекта "в разработке" :))

В ролике, расположенном ниже, присутствует жестокость, выражающаяся в причинении вымышленным существам разного рода физического вреда, также можно наблюдать намеренное отсутствие баланса(для тестов "далеких" перков) в геймплее и бессмертие вооруженного параллелепипеда(для быстрого снятия видео) и не рекомендуется смотреть тем, кто смотреть не хочет на то, каким порой бывает жестоким параллелепипед. :)

Думаю и на unity конечно можно сделать отлично, но примеров мощных проектов ААА класса пока маловато(но похоже вскоре ситуация изменится, что не может ни радовать)
Но particle system в udk зачетная...

PS. Быть может, руки дойдут, будет и баланс в этой техно демке, и анимации, и много чего еще .(пока только полноценная перковая прокачка до 60lvl, разное оружие, бонусы, да с пятОк фич)

Делаем hud health status в udk

2013-04-29T13:05:00.000-07:00

Расскажу, как можно заменить стандартную иконку с жизнями на свою собственную, с помощью flash и с минимумом знаний обо всем этом. Основой служили вот эти уроки и скрипты (они также рекомендованы к просмотру), к слову все дальнейшие манипуляции я делаю в September(2010) версии.

Первым делом нам следует заготовить swf файл. (на примере работы с adobe flash cs). Создаем проект как Action Script 2.0(в новых версиях udk уже имеется поддержка as3.0), выставляем разрешение 1024x768(не обязательно такое).

Нюансы:
1) В настройках импортируемых картинок нужно обязательно убирать расширение. Не выполнение этого условия приведет к аварийному завершению UDK. Также ставим галочки как на скриншоте.(Наводим на загруженную текстуру в библиотеке проекта > правой кнопкой мыши > свойства)

2) Текущее значение жизни будем передавать как параметр типа string, назначаем ему соответствующее имя экземпляра, дабы потом правильно к нему обращаться через uscript.
Создаем textField, пишем там 100, еще создаем textField- пишем %.
Объект textField, где написано 100, присваиваем имя player_health. Оно нам пригодится (используется при обращении в скриптах).

Есть вероятность, что могут быть проблемы со шрифтами. Для устранения этих проблем, в библиотеку исходников создаваемой флешки добавим используемые шрифты.

Для примера добавлен простой фон под 100%, дизайн же вывода текущих жизней ограничивается лишь вашей фантазией, все на ваше усмотрение, а в данном случае осталось только вставить немного кода в новом слое.
Итак выделяем новый слой, жмем F9 и вставляем такой код:

import gfx.motion.Tween;
_global.gfxExtensions = true;

Первая строка добавляет библиотеку Tween(не думаю что это здесь обязательно, по крайней мере, пример очень простой и эту библиотеку вряд ли использует. Библиотека добавляет возможность анимации муверов, с контролем из uscript), вторая строка разрешает вести диалог между action script и unreal script, при помощи чего и будут передаваться параметр, вызываться функции. За хорошим примером, чего можно добиться этой связкой, далеко идти не надо - тоже меню в udk как раз эффективно показывает возможности взаимодействия scaleform и unreal script.

После того, как опубликовали и создали все нужные файлы, загружаем их в UDK. Создадим простой тип игры для примера.

Прописываем в своем Test_InfoGame собственный контроллер и hud. Остальные настройки по умолчанию.

class Test_InfoGame extends  UTDeathmatch; 

DefaultProperties
{
    //Indentify your GameInfo
    Acronym="ST"

    PlayerControllerClass=class'FlashHealthGame.Test_PlayerController'
    HUDType=class'FlashHealthGame.THUD'
    //DefaultPawnClass=class'UTGame.UTPawn'
 
    //This variable was created by Epic Games to allow back compatability with UIScenes
    bUseClassicHUD=true

    bDelayedStart=false
    bRestartLevel=false
    Name="Test_GameInfo"
}

Просто балванка контроллера.

class Test_PlayerController extends UTPlayerController;

DefaultProperties
{
    bForceBehindView=false
    Name="Test_PlayerController"
}

Этот класс отвечает за отработку hud элементов. В конкретном случае, просто рождаем класс, который ответственен за работу scaleform компонента.

class THUD extends UTHUDBase;

//Reference the actual SWF container (STGFxHUD created later)
var STGFXHUD HudMovie;

//Called when this is destroyed
singular event Destroyed()
{
    if (HudMovie != none) 
    {
        //Get rid of the memory usage of HudMovie
        HudMovie.Close(true);
        HudMovie = none;
    }

    super.Destroy();
}

//Called after game loaded - initialise things
simulated function PostBeginPlay() 
{
    super.PostBeginPlay();

    //Create a STGFxHUD for HudMovie
    HudMovie = new class'STGFXHUD';
 
    //Set the timing mode to TM_Real - otherwide things get paused in menus
    HudMovie.SetTimingMode(TM_Real);
 
    //Call HudMovie's Initialise function
    HudMovie.Init(class'Engine'.static.GetEngine().GamePlayers[HudMovie.LocalPlayerOwnerIndex]);
}

//Called every tick the HUD should be updated
event PostRender() {
    HudMovie.TickHUD();
}

DefaultProperties
{
}

Отвечает за общение с флешкой и передачи параметров.

class STGFXHUD extends GFxMoviePlayer;

//Create a Health Cache variable
var float LastHealthpc;

//Create variables to hold references to the Flash MovieClips and Text Fields that will be modified
var GFxObject HealthTF;


function Init(optional LocalPlayer player) 
{
    //Start and load the SWF Movie
    Start();
    Advance(0.f);

    //Set the cahce value so that it will get updated on the first Tick
    LastHealthpc = -1337;

    //Load the references with pointers to the movieClips and text fields in the .swf
    HealthTF = GetVariableObject("_root.player_health");
}

//Called every update Tick
function TickHUD()
{
    local UTPawn UTP;
    local PlayerController PC;
 
    PC = GetPC();
    //We need to talk to the Pawn, so create a reference and check the Pawn exists
    UTP = UTPawn(PC.Pawn);
 
    //If the cached value for Health percentage isn't equal to the current...
    if (LastHealthpc != UTP.Health)
    {
        // update the text field
        HealthTF.SetText(UTP.Health);
        //...Make it so...
        LastHealthpc = UTP.Health;
    }
    else if (LastHealthpc <= 0)
    {
        HealthTF.SetText(0);
        close();
    }
}


DefaultProperties
{
    //this is the HUD. If the HUD is off, then this should be off
    bDisplayWithHudOff=false
    //Местонахождение флешки
    MovieInfo=SwfMovie'Test_flash.Test.Test_flash'
}

Не забудьте правильно прописать путь к флешке в DefaultProperties, которую загрузили в UDK. Создаем, компилируем, запускаем UDK, загружаем тестовый уровень, ставим нужный тип игры в настройках, радуемся.

Исходники

Cсылки по теме:
http://noexp.wordpress.com/scaleform-hud-tutorial/
http://forecourse.com/unreal-tutorials/
http://www.youtube.com/user/scaleformpress#p/u/16/_nsOOSBBbdg

Подгружаем уровни (level streaming)

2013-04-14T04:50:00.001-07:00

Очевидно, что игры частенько состоят из нескольких больших или не очень, уровней. По задумки создателя или иным причинам, порой бывает необходимо создать несколько игровых уровней, которые должны будут подгружаться лишь по надобности. Такая возможность имеется и в UDK и реализуется довольно просто.

Часто получается так, что требуется загрузить огроменную локацию, которая будет претендовать на приличный кусок ресурсов компьютера. Если позволяет дизайн, в такие моменты очень удобно использовать подгружаемые уровни. Т.е. вся локация будет разбита на куски - игрок находится только в определенной части карты, а в нужным момент подгружается необходимая часть, в то время как уже не нужная - выгружается. Если все сделано аккуратно(а кто ж сомневается в обратном?), для игрока это практически не заметно, а разработчикам и компьютеру проще работается.

На самом деле можно просто загрузить другой уровень с помощью kismet, но на это уходит побольше времени(если уровень велик) и в случаях, когда приходится часто скакать с одного уровня на другой, долгая загрузка будет раздражать игрока(и не только его).

На всякий случай расскажу, как можно загрузить уровень из другого уровня.

Создав простейший уровень, ставим на него, для примера, триггер (при касании триггера будет загружаться другой уровень), в редакторе жмем правую кнопку мыши и выбираем Add Actor > Add Trigger. Выделяем его и идем в Kismet.

Делаем как на скриншоте:
New Action > Misc > Console Command
New Event Using Trigger_1 > Touch
New Variable > Player > Player

Соединяем. Выделяем Console Command и в строке Commands пишем "open DM-Deck" без кавычек. Это команда загрузки уровня DM-Deck. Есть небольшая особенность - если Вы хотите подгрузить свой уровень (куда ж без этого) то он должен находиться в папке: C:\UDK\UDK-2010-XX\UDKGame\Content\Maps

дабы UDK увидел ваш уровень.

И еще, уровень будет подгружаться, если вы запустите игру как Play on PC. По другому не заработает. И не забудьте поставить PlayerStart, и т.д. и т.п.

С этим разобрались. Теперь задача такая - подгружаем один уровень прямо в другой.

Создаем простейший уровень. Я создал несколько платформ. Все они немного соприкасаются друг с другом, но это не обязательно. Можно просто раскидать по разным углам - как Вам удобно. Сохраняем его (например map_full).
Теперь удаляем все платформы кроме первой и ребилдим (жмем кнопку Build Geometry for visible levels), сохраняем уровень (например map_01). Загружаем map_full и тем самым возвращаем уровни. Удаляем все платформы кроме второй - ребилдим и сохраняем (map_02). И так далее.

Загружаем map_01, ставим свет, точку старта для игрока - созраняем. теперь идем в Content Browser и переходим на вкладку levels. Выбираем Add Existing Level и добавляем туда map_02, map_03 и т.д.

Примечание : у меня получилось нормально добавить карты только после того как я их переместил в
C:\UDK\UDK-2010-XX\UDKGame\Content\Maps

Из других место они не добавлялись. Увы, с чем это связано пока не разобрался. Может кто подскажет?

В появившемся окошке выбираем Kismet (будем управлять подгрузкой через Kismet). AlwaysLoaded - тут понятно, постоянно загруженный, а с третьим еще не экспериментировал. Сохраняем. Если сейчас запустить уровень, то мы увидим только map_01, что вполне естественно - команды загружать остальные платформы не было.

Чтобы загружались остальные платформы через триггер, мы используем Kismet. Но сначала сделаем триггер, для этого выставляем размеры у builder brush и жмем правой кнопкой мыши по значку Add Volume, далее выбираем из списка TriggerVolume. Теперь у нас есть триггер. Нам нужно сделать так, чтобы при касании области триггера, подгружалась следующая платформа. Для этого идем в Kismet и делаем вот такую схемку:

Это у нас:
New Event Using TriggerVolume_1 > Touch
New Action > Level > Stream Level

Выделяем Stream Level и пишем там название подгружаемого уровня.Тоже самое проделываем с остальными уровнями. Вот в общем то и все, дальше уже сами экспериментируйте.

Creating a XP System

2013-04-14T04:48:00.000-07:00

Author: "mktwo"
Перевод: Vadakuma
Оригинал статьи, ее обсуждение

Прежде всего убедитесь, что Вы уже знаете как устанавливать эти коды, т.к. в этом титориале это не объясняется.Во вторых, я полагаю что Вы уже немного знакомы с UnrealScript. Например Вы должны знать как наследуемые классы работают и как делается свой тип игры, как сделать свой собственный HUD, PlayerController и т.д. Если Вы не знаете всего этого то можно некоторые вещи посмотреть на этом сайте(в дальнейшем тут будет намного больше информации о UnrealScript),также на других русских сайтах и естественно на заморских.например тут и тут.

HUD создан по этому тутору

Необходимый набор скриптов, для реализации задачи:

MyGame.uc
MyPlayerController.uc
SeqAct_GiveXP.uc (optional)
MyHUD.uс

MyGame.uc
Скрипт описывает созданный тип игры

class MyGame extends UTGame;

// Функция, которая выполняется после каждого убийства
function ScoreKill(Controller Killer, Controller Other)
{
     local MyPlayerController PC;
     
     super.ScoreKill(Killer, Other);
     
     PC = MyPlayerController(Killer); // Cast to the custom MyPlayerController class
     PC.GiveXP(100); //Позволяет изменять кол-во получаемого опыта
}

DefaultProperties
{
//    DefaultPawnClass = class'UTGame.UTPawn'
     PlayerControllerClass = class'MyGame.MyPlayerController'
     HUDType = class'MyGame.MyHUD'
}

MyPlayerController.uc
Получаем экспу, повышаем левел. Методы не находятся в MyPawn, для того чтобы опыт сохранялся после смерти.(хотя конечно можно и изловчиться)

class MyPlayerController extends UTPlayerController
 config(MyGame);

const MAX_LEVEL = 50;
const XP_INCREMENT = 500; // Кол-во опыта до следующего уровня
var int XP; // Общая сумма собранных XP
var int Level; // Current level
var int XPGatheredForNextLevel; // Количество XP собранных 
var int XPRequiredForNextLevel; // Количество необходимых XP до нового уровня

//При старте игры мы подсчитываем сколько нужно получить опыта чтобы перейти на новый уровень

simulated function PostBeginPlay()
{
    super.PostBeginPlay();
    // Обсчитываем свойства при старте игры
    CalculateLevelProgress();
}

//Здесь мы объявляем функцию,которая позволяет поменять кол-во опыта нужного для следующего  уровня через Kismet 
// Функция вызываемая из Kismet
public function AddXP(SeqAct_GiveXP action)
{
    GiveXP(action.Amount); // Количество опыта получаемого с учетом  установки в Kismete
}

//Функция добавления опыта
public function GiveXP(int amount)
{
     self.XP += amount;
     
     CalculateLevelProgress();
     
     while (self.XPGatheredForNextLevel >= self.XPRequiredForNextLevel && self.Level < MAX_LEVEL)
     {
         self.Level++;
         // Пересчитываем опыт после левел апа
         CalculateLevelProgress();
     }
}

//Дальше мы объявляем функцию которая считает, сколько нужно еще опыта для достижения следующего уровня.
private function CalculateLevelProgress()
{
    local int xpToCurrentLevel; // Текущее количество накопленного опыта
    
    xpToCurrentLevel = XP_INCREMENT * (self.Level - 1);
    self.XPGatheredForNextLevel = self.XP - xpToCurrentLevel;
    self.XPRequiredForNextLevel = self.Level * XP_INCREMENT;
}

DefaultProperties
{
     Level = 1;
     XP = 0;
}

SeqAct_GiveXP.uc (optional)
В этом скрипте мы создаем Sequence Action, который будем использовать в Kismet.

class SeqAct_GiveXP extends SequenceAction;
 
var() int Amount; // Amount of XP this action will give


//Добавляем немного инфы чтобы было удобнее использовать в kismete
DefaultProperties
{
     // Имя  функции в Kismet Editor
     ObjName="Add XP"
     // Имя  функции при использовании
     HandlerName="AddXP"
     Amount = 0
     // Показывает входы и выходы модуля в Kismetе
     VariableLinks(1)=(ExpectedType=class'SeqVar_Int', LinkDesc="Amount", bWriteable=true,   PropertyName=Amount)
}

MyHUD.uc
Скрипт рисует на экране шкалы со здоровьем, текущем уровнем и количеством опыта.

class MyHUD extends UTHUD;

function DrawBar(String  Title, float Value, float MaxValue,int X, int Y, int R, int G, int B) // Функция рисования шкал
{
     local int PosX; //объявляем переменную представляющую позицию откуда начинать рисовать
     local int BarSizeX; //Объявляем переменную регулирующую
     
     PosX = X; //Начальная точка, откуда начинаем рисовать прямоугольник
     BarSizeX = 300 * FMin(Value / MaxValue, 1); // размер активного прямоугольника (Увеличивайте 300 чтобы увеличить прямоугольник)
 
     //Рисуем закрашенный прямоугольник
     Canvas.SetPos(PosX,Y);
     Canvas.SetDrawColor(R, G, B, 200);
     Canvas.DrawRect(BarSizeX, 12);
 
     //Рисуем пустой прямоугольник
     Canvas.SetPos(BarSizeX+X,Y);
     Canvas.SetDrawColor(255, 255, 255, 80);
     Canvas.DrawRect(300 - BarSizeX, 12); //Увеличивайте 300 чтобы увеличить прямоугольник
 
     //Рисуем наше заглавие
     Canvas.SetPos(PosX+300+5, Y); //Change 300 to however big your bar is
     Canvas.SetDrawColor(R, G, B, 200);
     Canvas.Font = class'Engine'.static.GetSmallFont();
     Canvas.DrawText(Title);
} 


function DrawGameHud()
{
     local MyPlayerController PC; 
     PC = MyPlayerController(PlayerOwner);
     
     if ( !PlayerOwner.IsDead() && !UTPlayerOwner.IsInState('Spectating')) //If player is not dead or spectating... ( you could also //use DrawLivingHud() )
     {        
         DrawBar("Health:"@PlayerOwner.Pawn.Health@"%",PlayerOwner.Pawn.Health, PlayerOwner.Pawn.HealthMax,20,20,200,80,80); //...draw our health-bar
         DrawBar("Level:"@PC.Level, PC.Level, PC.MAX_LEVEL ,20,40,200,200,200); //...and our level-bar
         if ( PC.Level != PC.MAX_LEVEL ) //If our player hasn't reached the highest level...
         {
             DrawBar("XP:"@PC.XPGatheredForNextLevel$"/"$PC.XPRequiredForNextLevel, PC.XPGatheredForNextLevel, PC.XPRequiredForNextLevel, 20, 60, 80, 255, 80); //...draw our XP-bar
         }
     }
}

Используем Kismet для изменения системы получения опыта

Сначала Вы должны сделать триггер, жмем Add Actor > Add Trigger.

Дальше выбираем триггер и идем в kismet. Добавляем триггер New Event Using Trigger_0 > Touch. Добавляем Add XP-action.

Соединяем Touched с In.

Далeе New Variable > Player > Player и цепляем к target.

New Variable > Int > Int и пишем количество начисляемого опыта за одно убийство и цепляем к Amount

Сохраняем и наслаждаемся результатом!

Создание C++ DLL для получения списка допустимых разрешений экрана

2013-04-14T04:38:00.001-07:00

Автор: Spoof
Перевод: Vadakuma
ОРИГИНАЛ: Building a C++ DLL and script class to list graphics resolutions

Консольная команда SETRES предназначена для смены разрешения окна, а также для перехода в полноэкранный режим и обратно. Но, к сожалению, нет никакой информации, какие именно разрешения экрана поддерживает машина пользователя.

В этом уроке я покажу вам как создается Dynamic Link Library utility с помощью C++ и классы UnrealScript для взаимодействия с dll-кой, в итоге получим список поддерживаемых разрешений от пользовательской машины, а это очень полезная информация, к примеру, для корректного отображения UI.

Нет необходимости в глубоком понимании процесса, можно просто скопировать C++ код и скомпилировать проект. Я намеренно упростил код, переведя большую часть функциональности в UnrealScript часть.

Итог, потребуется сделать такие шаги:
1) Создать dll проект в Microsfot Visual C++ 2010 Express
2) Cкомпилировать код С++
3) Создать UnrealScript класс, для взаимодействие с полученной dll-кой. С помощью обращений к dll из этого класса будет составлен набор доступных разрешений.

Шаг 1 Создаем DLL проект

1) Можно использовать любой C++ IDE/compiler, но в этом уроке буду пользоваться именно Microsoft Visual C++ 2010 Express.
-Select File -> New -> Project... откроется окна с выбором, какой проект создать.
-Выберете Win32 from в списке слева, затем Win32 Console Application в центре.
-Чуть ниже введите название проекта DeviceInfo, создайте папку для проекта, если не устраивает адрес проживания по умолчанию.

2) Нажимаем на Ok, создавая тем самым пустой проект.
-Нажимаем Next &gt; доходим до окна с настройками.
-Тип приложение поставьте DLL.
-Под дополнительными опциями выберете Empty Project.

3) Жмем Finish и тем самым подтверждаем создание настроенного нами проекта.
-В главном меню выбираем Project -> Add New Item открется окно выбора, какого рода файл вы хотите создать. Будьте уверены, что выбрали именно "add" в вашем IDE.
-Выберете Code в настройках, и C++ File (.cpp) в центре.
-Введите имя файла DeviceInfo.cpp.
-Жмем на add(добавить).

4) Теперь в проекте должен появиться пустой C++ файл. Но перед тем как начнем его заполнять, необходимо сделать ряд обязательных настроек, для того чтобы наш dll файл мог работать с UDK.
-В окне Solution Explorer жмите правой кнопкой мыши по имени проекта и выбирайте Properties(свойства).

Замечание: проект должен находиться в корне древа папок и файлов. Если в следующем шаге возникнут проблемы, возможны вы открыли не те настройки.

-В окне настроек code generation : Configuration Properties -> C/C++ -> Code Generation
(Свойства конфигурации > С/С++ > Создание кода)
-Справа от строки Struct Member Alignment(Выравнивание членов структур) выберете опцию "4 byte (/Zp4)"

Эта опция гарантирует, что структуры, определенные в C++, будут иметь идентичное с UnrealScript байт выравнивание, кратное 4ем. Члены структуры между собой будут иметь расстояние, кратное 4 байтам , что позволит вытаскивать значения параметров по верному адресу.

Шаг 2 Пишем C++ код

Копируем этот кусок кода в DeviceInfo.cpp

/* Include the windows header file, which resolves references to DEVMODE and EnumDisplaySettings */

#include <windows.h> 
#define DLLExport __declspec(dllexport) 

/* Ensure compatibility between C and C++ code */ 
extern "C" 
{ 
    /* UDK_Resolution, a mirror of our UnrealScript struct Resolution.
     Both must have identical structure, and the C++ compiler should be set
     to pack on 4-byte boundaries (/Zp4)*/ 
    struct UDK_Resolution 
    {     
        int PixelWidth, PixelHeight;
    }; 

    /* DLLEnumDisplaySettings A wrapper for the Windows function EnumDisplaySettings. 
    UDK_Resolution * const udk_r This is a pointer to the local variable        
    'r' defined in our UnrealScript function, which allows us to modify it directly from the DLL.
    The names do not need to match with UnrealScript, and the prefix 'udk_' is only 
    to help define its role. The pointer is made const to add some safety. 
    Pointers are powerful and brutal. Learn C/C++ before tinkering with them.*/
    DLLExport int DLLEnumDisplaySettings( int modeNum, UDK_Resolution * const udk_r ) 
    {     
        DEVMODE dm;     
        dm.dmSize = sizeof(DEVMODE); 
        /* Each call to EnumDisplaySettings populates 'dm' with the width, height,
        bit-depth and refresh rate for the device mode specified by modeNum. 
        However, we're only concerned with resolution so we keep width and height,
        and discard the rest. The NULL value in the first parameter will query 
        the current display adaptor which should be fine for our purposes.*/
        if ( EnumDisplaySettings(NULL, modeNum, &amp;dm) )
        {         
            // copy the width and height properties of DEVMODE to         
            // UnrealScript's Resolution         
            udk_r-&gtPixelWidth = dm.dmPelsWidth;
            udk_r-&gtPixelHeight = dm.dmPelsHeight;

            return 1; 
        }     
        // EnumDisplaySettings returned false, meaning the specified modeNum     
        // does not exist     
        return 0;
     }
}

Компилируем проект нажав F7. Visual Studio автоматически сохранит файл cpp и начнет сборку проекта. Если в проекте все правильно, то компилирование закончится успешно, а также появится dll файл, который расположится в папке отладки(Debug) в DeviceInfo project. Если вы используете win7, то путь до файла будет примерно таким:

C:\Users\USERNAME\Documents\Visual Studio 2010\Projects\DeviceInfo\Debug\DeviceInfo.dll

Копируем DeviceInfo.dll в ваш udk проект UDK-version/Binaries/Win32/UserCode папку. У меня выглядит это так:

D:\UDK\UDK-2011-09\Binaries\Win32\UserCode\DeviceInfo.dll

ВАЖНО: DLL созданная нами, является win-32 версией. Если вы работаете над 64-ным проектом, вам необходимо скомпилировать библиотеку под 64-битную платформу. Для того чтобы наша созданная библиотека подключилась и работала, нужно запускать UDK в 32-битном режиме (из папки Win32).

Шаг 3 UnrealScript и тестирование

Создаем новый класс в вашем udk проекте с названием DeviceInfo.uc. Переносим туда следующий код и сохраняем.

class DLLDeviceInfo extends Object
 DLLBind(DeviceInfo);

/* Resolution, holds the width and height of a display resolution.
*/
struct Resolution
{
    var int PixelWidth, PixelHeight;
};

/* An array of Resolutions, listing all the unique display resolutions found
*/
var array<resolution> AllResolutions;

/* DLL import declaration, matching the call signature of the function defined in 
 our DLL
*/
dllimport final function int DLLEnumDisplaySettings(int modeNum, out Resolution r);

/* EnumDeviceModes, builds a list of graphics resolutions supported by the hardware.
 Each call to DLLEnumDisplaySettings may return a new resolution, or a duplicate 
 resolution with different bit-depth and refresh rate. For SETRES and our UI options
 we only require a list of the unique resolutions, so we'll filter out all the
 duplicates.
*/
function EnumDeviceModes()
{
    local Resolution r;
    local int modeNum;
    local int key;
    local array<int> keys;

    `log("Enumerating device modes...");
    // Start with mode 0
    modeNum = 0;
    // Query device mode 0, 1, 2, ... etc. DLLEnumDisplaySettings returns 0 
    //when all modes have been reported
    while( DLLEnumDisplaySettings(modeNum, r) != 0 )
    {
        // combine width and height into a single integer 'key'
        key = r.PixelWidth &lt;&lt; 16 | r.PixelHeight;
/* This simple trick filters out duplicate resolutions by creating a 
 unique key for each combination of width and height. If our key list
 doesn't yet contain an entry for this combo then we have a new
 resolution to add to our list of AllResolutions.
 
 Reduces hundreds of reported modes down to a handful of useable options.
 Which is nice.
 */
        // Already added this combination of width and height?
        if ( keys.Find(key) == INDEX_NONE )
        {
            // Add the new resolution
            AllResolutions.Additem(r);
            // Add the key
            keys.AddItem(key);
        }
 
        // next device mode
        modeNum++;
    }

    // Report some useful info...
    `log(AllResolutions.Length@"available resolutions from"@modeNum@"device modes");
    `log("The following resolutions are supported:");

    foreach AllResolutions(r)
    {
        `log(" " $ r.PixelWidth @ "x" @ r.PixelHeight);
    }
}

Чтобы воспользоваться возможностями класса, нужно создать его экземпляр и вызвать функцию EnumDeviceModes. В идеале все это делать во время инициализации игры, потому как вызвать нужно лишь один раз, а далее просто пользоваться полученными результатами.

Вместо предложенного способа, вы можете добавить представленный код, к примеру, в имеющийся UI менеджер, или куда вам заблагорассудится. Для тестирования добавим событие InitGame в дочернем классе от GameInfo.

var DLLDeviceInfo DeviceInfo;
event InitGame( string options, out string errorMessage )
{
    super.InitGame(options, errorMessage);
    DeviceInfo = new class'DLLDeviceInfo';
    DeviceInfo.EnumDeviceModes();
}

Наконец компилируем UDK проект и смотрим логи. Должно появиться нечто вроде:

[0002.60] ScriptLog: Enumerating device modes...
[0002.62] ScriptLog: 16 available resolutions from 225 device modes.
[0002.62] ScriptLog: The following resolutions are supported:
[0002.62] ScriptLog: 640 x 480
[0002.62] ScriptLog: 720 x 480
[0002.62] ScriptLog: 720 x 576
[0002.62] ScriptLog: 800 x 600
[0002.62] ScriptLog: 1024 x 768
[0002.62] ScriptLog: 1152 x 864
[0002.62] ScriptLog: 1280 x 720
[0002.62] ScriptLog: 1280 x 768
[0002.62] ScriptLog: 1280 x 800
[0002.62] ScriptLog: 1280 x 960
[0002.62] ScriptLog: 1280 x 1024
[0002.62] ScriptLog: 1360 x 768
[0002.62] ScriptLog: 1366 x 768
[0002.62] ScriptLog: 1600 x 900
[0002.62] ScriptLog: 1600 x 1024
[0002.62] ScriptLog: 1680 x 1050

Заключение

Вы можете вместо Debug версии сделать Releaze версию. Для этого в диспетчере конфигураций выберете Releaze и перекомпилируйте - появится папка Releaze с заветной dll-кой.

Дополнительная информация:

EnumDisplaySettings: http://msdn.microsoft.com/en-us/library/dd162611(v=VS.85).aspx
DLLBind: http://udn.epicgames.com/Three/DLLBind.html

UPDATE Вариант, в котором вытаскивается максимально возможное разрешения девайса(эт уже от себя). Функция EnumDeviceModes немного переписана:

function vector2d EnumDeviceModes()
{
    local Resolution r;
    local Vector2D BestRes;
    local int modeNum, BestmodeNum;
    local int key;
    local array<int> keys;

    `log("Enumerating device modes...");

    // Start with mode 0
    modeNum = 0;

    // Query device mode 0, 1, 2, ... etc. DLLEnumDisplaySettings
     //returns 0 when all modes have been reported
    while( DLLEnumDisplaySettings(modeNum, r) != 0 )
    {
        // combine width and height into a single integer 'key'
        key = r.PixelWidth << 16 | r.PixelHeight;
        // Already added this combination of width and height?
        if ( keys.Find(key) == INDEX_NONE )
        {
            // Add the new resolution
            AllResolutions.Additem(r);
            // Add the key
            keys.AddItem(key);
        }
        // next device mode
        modeNum++;
    }

    // Report some useful info...
    `log(AllResolutions.Length@"available resolutions from"@modeNum@"device modes");
    `log("The following resolutions are supported:");
    foreach AllResolutions(r)
    {
    `log(" " $ r.PixelWidth @ "x" @ r.PixelHeight);
    }

    // Start with mode 0
    modeNum = 0;
    while (modeNum < AllResolutions.Length)
    {
        if(AllResolutions[BestmodeNum].PixelWidth<AllResolutions[modeNum].PixelWidth)
        {
            BestmodeNum = modeNum;
        }
        else if(AllResolutions[BestmodeNum].PixelHeight<AllResolutions[modeNum].PixelHeight 
             && AllResolutions[BestmodeNum].PixelWidth == AllResolutions[modeNum].PixelWidth)  
        {
            BestmodeNum = modeNum;
        }
        // next device mode
        modeNum++;
    }
}

Т.е. теперь EnumDeviceModes будет возвращать вектор BestRes, в котором содержится максимально высокое значение разрешения девайса.

Мое приветствие android. Дописал аналог Hello world.

2013-04-07T14:23:00.000-07:00

Решил написать Hello world для android, иначе говоря, приложение фонарик, так сказать, ознакомиться с достопримечательностями платформы.

Эксперимент в целом удался, теоретически будет работать не только на моем относительно старом htc, но и на более современных моделях. Но так как подобных "hello world" сотни, далее развивать приложение буду лишь если выяснится, что оно не столь ужасно, как мне кажется, и имеет смысл допиливать до более качественного состояния :)

ps. Приложение с рекламой, но ее можно отключить в меню.

Управление Particle System с помощью unreal script

2013-04-07T10:52:00.001-07:00

Автор: Vadakuma

Используемые источники:
UDN: Distributions
UsingInstanceParameters
и исходники UT3.

Возможности UDK позволяют управлять отдельными параметрами системы частиц через скрипты, что бывает очень кстати.
В этой статье я покажу, как можно управлять количеством дыма и огня в зависимости от урона. Подразумевается, что читатель уже имеет как минимум базовые знания по UDK и unrealscript в частности, так как эта статья лишь показ идеи в целом, и некоторые простые шаги пропущены.

Буду использовать:
Particle: ParticleSystem'GenericFoliage01.Ruins.FX.P_UDK_TorchFire01'
SkeletalMesh: SkeletalMesh'FoliageDemo.Animated.SP_Bird1_SKMesh'

Часть 1

Шаг 1

Сначала необходимо настроить сам particle. Выбираем particle в ContentBrowser и открываем его в Cascade. Эффект обычно состоит из нескольких модулей, выберем сначала первый и в нем Initial Size.

В настройках жмем на треугольник напротив Distribution и выбираем DistributionVectorParticleParameter. Изменяемая нами величина будет вектором, т.е. эффект можно растягивать, расширять, или наоборот сужать размеры более гибким образом, нежели при использовании лишь одного числового параметра. (Учтите, если до этого параметр был настроен, то проделав описанную процедуру, все сбросится!)

Окно настроек изменится:

Шаг 2

1. Чтобы к этому параметру можно было обратиться из кода, необходимо задать Parameter Name.

2-3.Вписать необходимый диапазон изменения размеров эффекта.

4. Специально оставлено DPM_Normal. В таком режиме когда из кода приходит относительное значение от 0 до 1 (указано в MinInput/MaxInput), сам параметр будет меняться в диапазоне указанном в MinOutput/MaxOutput.

5. Какое относительное значение параметра будет использоваться по умолчанию при активации эффекта. (1 – берется максимальное значение)

Шаг 3

Туже процедуру необходимо проделать с оставшимися модулями. В них можно указать тот же Parameter Name что и в первом модуле, тогда изменение параметра Size будет происходить в нескольких модулях, т.е. можно управлять размером дыма даже если он состоит из составных частей.
Все тоже самое проделать с модулями, отвечающими за огонь, разве что сменить Parameter Name на соответствующее имя, если есть потребность управлять огнем отдельно от дыма.

Примечание: процедура была выполнена с векторным параметром, из кода тоже будет приходить векторный параметр. Если управляемый параметр не векторный, ничего не меняется, изменится лишь тип. К примеру, если параметр - это просто значение с плавающей запятой, тогда тип - float, и выбирать надо будет DistributionFloatParticleParameter.

Часть 2

Шаг 4

Теперь разберемся в коде. Алгоритм управления взят из исходников UT3, здесь есть отличия, но сама суть остается неизменной.

Для примера создадим класс Pawn, который будет загораться, при нанесении достаточного урона и огонь с дымом будут увеличиваться при большем уроне. При нанесении урона (событие TakeDamage) срабатывает функция CheckDamageSmoke(), которая проверяет, на сколько мало отношение Жизнь/МаксЖизнь, и если порог DamageSmokeThreshold пройден, активируется и аттачится к сокету BirdHead эффект пожара(по тегу DamageSmoke) в CreatePawnEffect(), далее количество огня корректируется через SetPawnEffectParms() при каждом последующим получении урона.

class CPSAnotherPawn extends GamePawn;

// порог после прохождения которого начнется возгорание.
var float DamageSmokeThreshold;

/**************************************************************************
 Pawn Effects
************************************************************************ */

/** Структура содержащая необходимые параметры для управления*/
struct  PawnEffect
{
    /** Тег для активации эффекта */
    var() name EffectStartTag;
    /** Тег для выключения эффекта */
    var() name EffectEndTag;
    /** Если необходимо перезапустить particle */
    var() bool bRestartRunning;
    /** Template to use */
    var() ParticleSystem EffectTemplate;
    /** Названия сокета для присоединения */
    var() name EffectSocket;
    /** The Actual PSC */
    var ParticleSystemComponent EffectRef;

    structdefaultproperties
    {
        bRestartRunning=true;
    }
};
/** массив с эффектами и данными необходимыми для управления */
var(Effects) array<pawneffect>PawnEffects;

/**
* Проверка достаточно ли поврежден pawn для того чтобы начать гореть.
*/
simulated function CheckDamageSmoke()
{
    Local float Pct;

    Pct = (float(Health) / float(HealthMax); 
    // для примера, если наша птичка убита, дым отключится.
    PawnEvent( Pct &lt; DamageSmokeThreshold &amp;&amp; Health &gt; 0) ? 'DamageSmoke' : 'NoDamageSmoke');
}


/**
* An interface for causing various events on the vehicle.
*/
simulated function PawnEvent(name EventTag)
{
    // Включаем или выключаем эффекты
    TriggerPawnEffect(EventTag);

    // Play any animations
    //PlayPawnAnimation(EventTag);
    //PlayPawnSound(EventTag);
}


/**
* Активирует или деактивирует эффекты
* param    EventTag    тег указывающий на конкретный эффект
*/
simulated function TriggerPawnEffect(name EventTag)
{
    local int i;

    for (i = 0; i &lt; PawnEffects.length; i++)
    {
        // находим эффект по тегу, с которым надо отработать
        if (PawnEffects[i].EffectStartTag == EventTag) 
        {
            if (PawnEffects[i].EffectRef == None)  // если не создан, создаем
            {
                CreatePawnEffect(i);
            }
            if (PawnEffects[i].bRestartRunning)  // если надо, перезапускаем
            {
                PawnEffects[i].EffectRef.KillParticlesForced();
                PawnEffects[i].EffectRef.ActivateSystem();
            }
            else if (!PawnEffects[i].EffectRef.bIsActive) // если не активен, включаем
            {
                PawnEffects[i].EffectRef.ActivateSystem();
            }
            // начинаем менять параметры
            SetPawnEffectParms(EventTag, PawnEffects[i].EffectRef);
        }
        // Если эффект действует, а тэг стоит на выключении - выключаем
        else if (PawnEffects[i].EffectRef != None &amp;&amp; PawnEffects[i].EffectEndTag == EventTag)
        {
            PawnEffects[i].EffectRef.DeActivateSystem();
        }
    }
}


/**
* После активации какого-либо эффекта, вызывается эта функция, для корректировки 
* параметров.
* @param    TriggerName   тег говорящий, какой именно эффект был активирован
* @param    PSC     Particle System component связанный с эффектом
*/
simulated function SetPawnEffectParms(name TriggerName, ParticleSystemComponent PSC)
{
    local float Pct;
    local vector ratioVect;

    if (TriggerName == 'DamageSmoke')
    {
        /* домножено на DamageSmokeThreshold, чтобы Pct изменялся от 1 до 0. ||1 -  
        небольшой пожар. 0-максимально возможный. Без умножения  Pct изменялся от 
        DamageSmokeThreshold до 0, т.е. эффект начинает работать не с минимального 
        значения*/
        Pct = float(Health) / (float(HealthMax)*DamageSmokeThreshold);  

        ratioVect.X = (1 - Pct);
        ratioVect.Y = (1 - Pct);
        ratioVect.Z = (1 - Pct);

        PSC.SetVectorParameter('smokeamount', ratioVect);
        PSC.SetVectorParameter('fireamount', ratioVect);
    }
}


/**
* Создаем новый эффект
*/
simulated function CreatePawnEffect(int EffectIndex)
{
    PawnEffects[EffectIndex].EffectRef = new(self) class'UDKParticleSystemComponent';
    PawnEffects[EffectIndex].EffectRef.SetTemplate(PawnEffects[EffectIndex].EffectTemplate);

    // присоединяем созданный эффект к мешу павна
    if(PawnEffects[EffectIndex].EffectSocket != 'None')
        Mesh.AttachComponentToSocket(PawnEffects[EffectIndex].EffectRef, PawnEffects[EffectIndex].EffectSocket);
}


/**
* @See Actor.TakeDamage()
*/
simulated event TakeDamage(
                           int Damage,
                           Controller EventInstigator,
                           vector HitLocation,
                           vector Momentum, 
                           class<damagetype> DamageType,
                           optional TraceHitInfo HitInfo, 
                           optional Actor DamageCauser
                           )
{
    Super.TakeDamage(Damage, EventInstigator, HitLocation, Momentum, DamageType, HitInfo, DamageCauser);

    CheckDamageSmoke();
}


defaultproperties
{
    DamageSmokeThreshold = 0.85

    Begin Object Class=SkeletalMeshComponent Name=InitialSkeletalMesh 
        CastShadow=true
        bCastDynamicShadow=true
        bOwnerNoSee=false
        BlockRigidBody=true;
        CollideActors=true;
        BlockZeroExtent=true;
        BlockNonZeroExtent=TRUE
        bIgnoreControllersWhenNotRendered=TRUE
        bUpdateSkelWhenNotRendered=FALSE
        SkeletalMesh=SkeletalMesh'FoliageDemo.Animated.SP_Bird1_SKMesh'
    End Object
    Mesh=InitialSkeletalMesh;
    Components.Add(InitialSkeletalMesh);


    // Вписываем набор эффектов
    PawnEffects.Empty
    PawnEffects(0)=(
         EffectStartTag=DamageSmoke,
         EffectEndTag=NoDamageSmoke,
         bRestartRunning=false,
         EffectTemplate=ParticleSystem'GenericFoliage01.Ruins.FX.P_UDK_TorchFire01',
         EffectSocket=BirdHead
                       )
}

В функции SetPawnEffectParms() передача текущего значения настроенным в редакторе эффектов параметрам происходит через указание их имен, в нашем случае это smokeamount и fireamount.
Чем меньше соотношение Жизнь/МаксЖизнь, тем большее значение (в нашем до 1.0) отсылается в particlesystem, тем самым вызывая увеличение дыма и огня.

Примечание: отмечу, что использовался skeletal mesh птички с созданным одним сокетом, с названием BirdHead. По умолчанию у этого скелетал меша нет сокетов!

Видео с полученным результатом:

В исходниках реализована простая проверка контроля:

class CPSPlayerController extends GamePlayerController;

var Pawn SP;

exec function SpawnBird()
{
    SP = spawn(class'CPSAnotherPawn',,,Location + vect(350,350, 250));
}


exec function BirdStrike()
{
    local  class<damagetype> DamageType;

    DamageType = class'DamageType';
    SP.TakeDamage(10, self, SP.Location, SP.Location,DamageType,,);
    ClientMessage("Bird Health:"@SP.Health);
}

defaultproperties 
{

}

В классе CPSPlayerController прописаны exec функции, которые можно вызвать через консоль. SpawnBird - рождается птичка. BirdStrike - "бъем" по созданной птичке нанося урон.
Так же в архиве находится пакет с измененным эффектом и птичкой с добавленным сокетом.

Исходники

PS. Пишите, если в предложенном материале обнаружили ошибки, недочеты, и т.д. - исправлю.

Меняем персонажа в процессе игры в UDK

2013-04-07T10:44:00.001-07:00

По упомянутой просьбе на сайте решил немного поизучать вопрос переключения у игрока стандартного меша.
В играх, где есть несколько персонажей и необходимо переключаться между ними, или же на каждый уровень приходится свой персонаж, придется озаботится этим вопросом.
К делу. В итоге скопилось целых три способа(и скорее всего еще столько же можно придумать(найти)) и все как обычно: легкий,легкий и ... легкий. Начнем для разминки с легкого...
Здесь представлены только собственные классы SM_PlayerController, потому как основные добавления происходят в этих классах. Полные версии скриптов, готовые для компиляции находятся в архиве, который можно скачать по ссылке в конце статьи.

Простая замена меша игрока во время игры.

Суть заключается в том, что у игрока по триггеру заменяется меш, материал, анимсэты, и анимтемплейт. Причем, если между старым и новым видом разница только в самом меше и материалах(т.е. анимация и анимтемплейт у них одинаковы),значит нужно будет просто заменить сам меш и материалы.

При этом не меняется сам класс Pawn, что пожалуй не есть гуд. Конечно можно напихать различных функций также переключающихся между собой, если какие-то свойства координально отличаются от старого персонажа...
Для примера создал спец блок для кисмета, при срабатывании которого и будет происходить, столь вожделенные события. Напомню, что все на достаточно примитивном уровне, без изысков и спецэффектов - быстрая спартанская смена меша. При достаточной сноровке переходный процесс можно или спрятать или скрасить. Конечно же можно назначить смену pawn на какую нибудь кнопку, действие и т.д. алгоритм в целом не поменяется.

класс SM_PlayerController:

class SM_PlayerController extends GamePlayerController;

var SkeletalMesh Changemesh;
var MaterialInterface ChangeMaterial0;
var AnimTree ChangeAnimTree;
var array<animset> ChangeAnimSet;
var AnimNodeSequence ChangeAnimSeq;
var PhysicsAsset ChangePhysicsAsset;
var bool SwitchMesh;


simulated event PostBeginPlay()

{
    super.PostBeginPlay();
    //`log("SM_PlayerController");
}

// вызывается из кисмета и  поменяет перса.
function SwitchPerson(bool Allowed)
{
    SwitchMesh = Allowed;
    if(SwitchMesh)   
    {
        SwitchMesh = FALSE        // Сначала  прописываем на какой именно меш будем менять, для примера взять      
     // стандартный  меш IronGuard
        ChangeMesh=SkeletalMesh'CH_IronGuard_Male.Mes h.SK_CH_IronGuard_MaleA'
        ChangeAnimTree=AnimTree'CH_AnimHuman_Tree.AT_ CH_Human';
        ChangeAnimSet[0]=AnimSet'CH_AnimHuman.Anims.K_AnimHuman_AimOffset';
        ChangeAnimSet[1]=AnimSet'CH_AnimHuman.Anims.K_AnimHuman_BaseMale';
        ChangePhysicsAsset=PhysicsAsset'CH_AnimCorrup t.Mesh.SK_CH_Corrupt_Male_Physics';
        // Затем поочередно применяем 
        self.Pawn.Mesh.SetSkeletalMesh(ChangeMesh);
        self.Pawn.Mesh.SetMaterial(0,MaterialInstanceConstant'CH_IronGuard_Male.Materials.MI_CH_IronG_MHead01_V01');
        self.Pawn.Mesh.SetMaterial(1,MaterialInstanceConstant'CH_IronGuard_Male.Materials.MI_CH_IronG_Mbody01_V01');
        /* !! Понадобится если будете менять на перса у которого другая анимация  и физика */
        //self.Pawn.Mesh.SetPhysicsAsset(ChangePhysicsAsset);
        //self.Pawn.Mesh.AnimSets=ChangeAnimSet;
        //self.Pawn.Mesh.SetAnimTreeTemplate(ChangeAnimTree);
    }
}

defaultproperties 
{
    SwitchMesh = FALSE
}

Полная замена pawn на другой, только что вызванный.

Принцип в этот раз несколько другой. По пунктам: отключаем pawn от контроллера игрока - удаляем его - вызываем новый pawn - подключаем к нему контроллер игрока. Здесь сделано так же, так что это дело происходит по спец. блоку из кисмета, например, по триггеру.

класс SM2_PlayerController:

class SM2_PlayerController extends GamePlayerController
var bool SwitchPawn;

simulated event PostBeginPlay()
{
    super.PostBeginPlay();
    //`log("SM2_PlayerController");
}

// вызывается из кисмета и  поменяет перса.
function SwitchPerson(bool Allowed)
{
    Local Pawn ReserveBeef;
    Local vector Loc;
    SwitchPawn = Allowed;
    if(SwitchPawn)
    {
         SwitchPawn = FALSE;
         //Запоминаем текущий pawn
         ReserveBeef = Pawn;
         // Запоминаем его расположение
         Loc = Pawn.Location;
         // отсоединяем текущий pawn
         UnPossess();
         // Уничтожаем отсоединенный pawn
         ReserveBeef.Destroy();
         //Вызываем новый pawn
         ReserveBeef = Spawn(class'SM2_AnotherPawn', ,, Loc + vect(50,0,50));
         // Присоединяем новый pawn
         Possess(ReserveBeef,false);
    }
     
}


defaultproperties 
{
    SwitchPawn = FALSE 
}

Переключение между двумя различными pawn

На уровне появляются сразу два меша, один под котролем AI. По спец блоку из кисмета происходит обмен между ними мешами - переключение котроллеров.
По принципу этот способ такой же как и предыдущий. Его пункты таковы: отключаем меши от контроллеров - переназначаем котроллеры другим мешам.

класс SM3_PlayerController:

class SM3_PlayerController extends GamePlayerController;
var   bool    SwitchPawn;
var   Pawn   ReserveBeef;

simulated event PostBeginPlay()
{
    // Вызываем другой pawn, по умолсчанию он под AI Controller 
    ReserveBeef = Spawn(Class'SM3_AnotherPawn',,, Location - vect(100,0,0) , Rotation);
    super.PostBeginPlay();
}

// Вызывается из кисмета и говорит что можно поменять перса.
function SwitchPerson(bool Allowed)
{
    Local Controller Cont;
    Local Pawn OldPawn;
    SwitchPawn = Allowed;
    if(SwitchPawn == TRUE)
    {
        SwitchPawn = FALSE;
        //Запоминаем текущий pawn 
        OldPawn = Pawn;
        //Запоминаем AI Controller  того  pawn куда переселимся
        Cont = ReserveBeef.Controller;
        //Отсоединяем наш старый  pawn
        UnPossess();
        //Отсоединяем новый  pawn от AI Controller
        Cont.UnPossess();
        //Присоединяемся
        Possess(ReserveBeef, false);
        //Старый pawn ставим под контроль AI Controller 
        Cont.Possess(OldPawn, false);
    }
}

defaultproperties 
{
    SwitchPawn = FALSE
}

Результат на видео:

Скачать все три способа

Все три способа можно неплохо довести до ума, например сделать взаимно обратной переключения по клавише между двумя героями. Так что все в ваши руках.

PS. Все делалось в мартовской версии UDK(2011).

Делаем меню как в Mass Effect

2013-04-07T10:40:00.000-07:00

Хотел по началу написать полностью свою статью, но поискав в просторах интернета информацию об этом деле, обнаружил что все расписано как надо и нет смысла изобретать велосипед второй раз. Поэтому решил перевести одну из подобных статей, которая должна, по идее, многим помочь в ходе изучения scaleform и flash.

Перевод: Vadakuma
Источник: Mass Effect style iteraction system

"Я создал на флеше систему меню, по стилю, как меню в игре Mass Effect. В случае, если вам требуется добавить интерактивную менюшку в игру, можете использовать эту систему. Всего 3 класса которые необходимо создать :

1) GFxUI_Interaction – добавляет параметры SWF movie, определяет какие параметры были задействованы.
2) SeqAction_BeginInteraction – активирует через Kismet меню, с шестью интерактивными кнопками.
3) SeqEvent_OptionSelected – события происходящие при нажатии на кнопку.

В архиве написаны эти скрипты, и все что вам осталось сделать, это переместить их по адресу :

Development\YourGame\Classes\

прокомпилировать, и запустить редактор.

Для начала стоит убрать HUD и видео, запускающиеся при старте обычного типа игры, также вам следует создать sub-sequence(отдельное "окошко" в kismet, специально для этой системы меню, чтобы отделить ее от всего остального), поскольку так будет проще управлять системой взаимодействия.

Внутри sub-sequence создайте a Sequence Activated node и как-нибудь его назовите. Далее следует создать Begin Interaction node (находится в New Action > Interaction > BeginInteraction).

Добавьте переменную Player и новую (именованную) объектную переменную для Movie, как показано на скриншоте. После проигрывания первого действия, вы можете подключить новый Matine с новым действием. Следуя этому, вы можете создать неактивное зацикливание (пока ожидается нажатие кнопки ) подобно меню из Mass Effect.

Внутри Begin Interaction node, вы должны лишь заполнить поле Interaction ID и шесть полей (название кнопок кажись). В принципе, эти поля являются дополнительными.
Примечание: Я обозвал каждую кнопку как в Mass Effect, вы можете назвать их по своему, только используйте сокращенные названия. На самом деле ограничения по длине похоже нету. Заполните поля как скриншоте:

Кнопки 0-2 справа, а кнопки 3-5 слева. Вы можете оставить поля пустыми, тогда кнопки не будут активными. Нет никакой надобности использовать все шесть кнопок. Если вы захотите сделать три кнопки справа, то полей interaction options тоже будет три.

Следующая вещь, которой стоит заняться, это определить какие события будут происходить при нажатии той или иной кнопки. Создадим шесть событий (‘New Event > Interaction > InteractionOptionSelected’).

В каждом событии потребуется настроить два параметра - ID события (идентификатор, который вы написали в узле ‘BeginInteraction’), и номер кнопки, при нажатии на которую будет происходить это событие. Настроить следует так, как показано на скриншоте:

Заключительные комментарий

Каждое из событий должно уметь завершать/останавливать видео или анимацию(персонажей, или самого меню), которые показывались до выбора следующего пункта меню. Блок, находящейся слева от блоков событий, как раз отвечает за это.

В итоге к каждому из блоков событий можно прикрепить любые действия, какие вы только захотите, после чего все должно прийти в конечный узел - ‘Finished Sequence’ node, который может быть полезен, если вы захотите создать систему взаимодействий между опциями.

Также вы можете подключиться к конечному блоку ‘Finished Sequence’ node сразу после того как опция была выбрана и дальше открыть новую последовательность опций (кнопок) – подобно тому как сделано в Mass Effect. Аналогично, вы можете добавить опцию ‘Return’, чтобы возвратиться к предыдущему меню.

Чтобы создать новое подменю, необходимо всего лишь скопировать подпоследовательность sub-sequence и изменить ID кнопок на новое значение. ID можно менять сразу для группы кнопок и опций.

Используя эти исходники вы можете легко создавать системы меню не хуже чем меню в игре Mass Effect. Скриншот для примера возможностей :

В архиве находятся необходимые скрипты, флеш меню и простенькая карта, для проверки работоспособности. Все было сделано в майской версии UDK(2010).

PS. Если у Вас установлена июньская версия(2010), то необходимо удалить строку 'bGammaCorrection=false' из DefaultProperties в скриптах GFxUI_Interaction.uc и SeqAction_BeginInteraction.uc

Спасибо за внимание. "

Огнестрельное оружие в UDK - Основы

2013-04-07T10:39:00.000-07:00

Автор: Mougli
Перевод: Vadakuma
Оригинал: Оружие - Основы

Вступление

Сегодня мы будем говорить о базовых знаниях и настройках касающиеся создания оружия.
UDN Weapon System Technical Guide (которую я называю WSTG) дает нам некоторые понятия: как работает механизм переключения оружия, как работает блок отвечающий за режим огня (даже по сети), в чем разница между функциями в классе Weapon и его дочерних классов.

Страничка Setting Up Weapons рассказывает нам как смоделировать и импортировать оружие, и какой код надо написать... для UTWeapons.

И все же, после прочтения всего этого, мы до сих пор не знаем некоторые вещи:

• Как добавить оружие в стандартный инвентарь.
• Установить различные виды выстрелов для оружия.
• Какие функции необходимо переписать чтобы управлять некоторыми характеристиками оружия.
• Как работает система урона.

Говоря о системе урона, думаю, эта тема заслуживает отдельного учебника (вместе с огнестрельными снарядами), поэтому я не буду затрагивать этот вопрос здесь.

Исходная точка: InventoryManager

Как мы уже говорили, этот класс, находящийся в папке Engine ( а там уже нет GameInventoryManager или UDKInventoryManager начиная с Октября 2010 (возможно от них не было толку)) следит за всем тем, что наш игрок имеет в "сумке".

Примечание: InventoryManager завязан на Pawn, а не на PlayerController.

Еще одна важная вещь которую мы должны знать о классе InventoryManager, это то что он просто отслеживает статус текущего оружия: значения PendingFire, о котором мы читали в WSTG. Хотя этот массив инициализируется не в InventoryManager. Другими словами, база InventoryManager не позволяет стрелять с помощью него (наделаете забавных ошибок, если попытаетесь так сделать).По умолчанию для класса UDKPawn инвентарем заправляет как раз InventoryManager, поэтому нам надо создать подкласс от последнего, для того чтобы научиться стрелять.

class SandboxInventoryManager extends InventoryManager;

DefaultProperties
{
    PendingFire(0)=0
    PendingFire(1)=0
}

А вот и он. Крутатенюшка. Сначала вы добавляете PendingFire столько, сколько хотите режимов выстрела в своей игре. Если вы не хотите альтернативного вида выстрела, вы можете забыть о второй ячейки массива. И если же вы хотите больше чем два альтернативных выстрела, отлично, можно сделать столько сколько нужно.

Пр. переводчика: PendingFire - массив, содержащий количество и статус альтернативных режимов выстрела одного и того же оружия. К примеру, PendingFire(0)=0-означает что оружие не стреляет, PendingFire(0)=1 - оружие в режиме огня.По умолчанию, Режим выстрела(Fire mode) 0 активируется по ЛКМ, а Режим выстрела(Fire mode) 1,по ПКМ.

Как я отметил ранее, InventoryManager связан с Pawn, поэтому нам необходимо сказать нашему pawn,чтобы он использовал наш собственный InventoryManager:

class SandboxPawn extends UDKPawn;

DefaultProperties
{
    InventoryManagerClass=class'Sandbox.SandboxInventoryManager'
}

Лепим оружие (скрипты)

Мы можем создать собственное оружие двумя путями: во-первых мы можем сначала написать поведение оружия( эффекты выстрела, снаряды) и лишь потом сделать для него внешний вид. Пример physics gun как раз демонстрирует, что оружие не особо нуждается в модели, для того чтобы полноценно функционировать. Для примера создадим paintball gun.

Шаг 0: несколько подсказок о настройке оружия

Статья WSTG дает нам целый набор настроек для Weapon и UDKWeapon классов. Некоторые более важные, некоторые менее. Среди них есть массивы , значения которых определяют настройки для каждого режимы огня:

•FiringStatesArray (array): задается через имя. Которое говорит о статусе оружия в руках и о режиме огня. По умолчанию не используется. Вы можете назначить любое значение, которое пожелаете, если не хотите заново изобретать велосипед. (Пр. Переводчика: этого параметра уже нет в скриптах)

•WeaponFireType (array): задается через EWeaponFireType. Говорит, к какому типу принадлежит оружие. Мы доберемся до него чуть позже.

•WeaponProjectiles (array): задается через подкласс снарядов. Если соответствующий режим огня устанавливается на выстрелы определенными снарядами, вы должны знать какой класс снарядов должен вызываться для данного оружия.

•FireInterval (array): задается через float. Указывает сколько времени занимает выстрел в данном режиме огня. Другими словами – темп стрельбы.

•Spread (array): задает погрешность в направлении выстрела (как бы "разброс"). Иначе, все пули(снаряды) будут лететь всегда точно в цель. Что не правдоподобно.

•WeaponRange: задается через a float. Определяет максимальную дальность выстрела, урон, время жизни снаряда. Обратите внимание, что это значение является общим для всех режимов огня.

Шаг 0.5 : добавляем наше оружие в инвентарь

Мы сделаем это так, что бы легко было проследить за сутью реализации кода.
Когда player перезапускается (т.е. начало игры, рестарт игры, воскрешение игрока), класс Pawn создается из GameInfo и прикрепляется к PlayerController, и GameInfo вызывает функцию AddDefaultInventory, принимая новый Pawn как параметр.
По умолчанию не делается ничего кроме вызова функции AddDefaultInventory в классе Pawn. И это хорошо по многим причинам. Тем не менее, имеется базовый класс игры. И скорее всего вы будете иметь еще подкласс от класса Pawn (для персонажа). AddDefaultInventory из класса GameInfo можно переписать, если у вас есть какие то общие параметры, настройки для всех классов(например, для ножа).

Итак, в нашем собственном Pawn классе, переписываем функцию AddDefaultInventory вот так :

function AddDefaultInventory() 
{
    //InvManager is the pawn's InventoryManager 
    InvManager.CreateInventory(class'Sandbox.SandboxPaintballGun');
}

Все просто. Функция имеет и второй необязательный параметр, если его значение TRUE, то будет предотвращаться немедленная экипировка оружия. Теперь, если мы запустим игру, мы ничего не увидим, ввиду того что у оружия нету собственного меша. И все же, если написать в консоли волшебную команду "showdebug weapon", мы увидим следующее в верхнем левом углу экрана:

Зеленая часть текста говорит нам о оружии которое сейчас держит игрок, и подтверждает что наша пушка готова к использованию!

Шаг 1: Параметры оружия

Статья WSTG рассказывает нам как обрабатываются выстрелы( в том числе и в сетевом режиме). Скорее всего мы так и не коснемся упомянутых функций, за исключением , пожалуй BeginFire, к которой мы обратимся чуть позднее. Давайте начнем разбираться что же у нас происходит в блоке WeaponFiring. ???

Рассмотрим блок WeaponFiring, в функции BeginState, мы вызываем FireAmmunition, затем еще TimeWeaponFiring, которые будут вызывать задержку стрельбы соответствующего режима огня, определяющуюся в массиве FireInterval. Если по какой-либо причине, нужна задержкаыстрелов при стрельбе, переписать эту часть функции будет правильным решением.

Когда отведенное время закончится, сработает RefireCheckTimer. Он проверяет две вещи:

1. Была ли команда перестать стрелять оружие. Если да, то происходит выполнение команды.
2. Если команды перестать оружия не было, происходит запрос функции ShouldRefire. Если возвращается TRUE, сразу вызывается FireAmmunition без выхода из блока.

Если же ничего из перечисленного не случилось, означает что мы перестали стрелять, поэтому вызывается HandleFinishedFiring, который по умолчанию переводит управление оружием в блок Active.

Внимание: Как вы могли уже заметить, первый выстрел( или вызов FireAmmunition) работает несколько другим способом, нежели последующие выстрелы. Так, если вам нужно прописать какое то действие, срабатывающее перед выстрелом, правильнее всего сделать это в внутри функции FireAmmunition, а не в BeginState.

Функция ShouldRefire проверяет есть ли боеприпасы у оружия (функция HasAmmo по умолчанию всегда возвращает TRUE), если вам еще хочется пострелять. (функция StillFiring по умолчанию возвращает значение функции PendingFire).
WSTG показывает нам тело функции FireAmmunition (от старой версии UTWeapon, хотя все основные идеи сохранились и там). Сперва используются боеприпасы, (по умолчание ничего не происходит), а затем определяется режим огня, после чего, в соответствии с режимом, вызываются различные функции.
Другими словами, режим огня установленный на оружии, более или менее, говорит с какими функциями нам следует поработать:

EWFT_InstantHit: InstantFire() Скоротечный огонь
EWFT_Projectile: ProjectileFire() Огонь снарядами
EWFT_Custom: CustomFire() Что-то самодельное

Прежде чем двигаться дальше, давайте установим в нашем оружии конкретный режим огня.

class SandboxPaintBallGun extends UDKWeapon;
DefaultProperties
{
    FiringStatesArray(0)=WeaponFiring //We don't need to define a new state
    WeaponFireTypes(0)=EWFT_InstantHit FireInterval(0)=0.1 Spread(0)=0
}

Скоротечный огонь.(Instant Fire)

Если взглянуть на функцию InstantFire, то можно увидеть что в ее теле вызывается некая Trace, для того что бы найти, куда же мы направили наше оружие. Не очень хочется связываться с этим. В конце функции есть вызов ProcessInstantHit. Вот его то мы и перепишем.
В нашем случае, полностью меняем содержание этой функции, потому как мы просто хотим переместить decal в помеченную точку. Что получилось:

simulated function ProcessInstantHit(byte FiringMode, ImpactInfo Impact, optional int NumHits)
{
    WorldInfo.MyDecalManager.SpawnDecal (
        DecalMaterial'HU_Deck.Decals.M_Decal_GooLeak',// UMaterialInstance used for this decal. 
        Impact.HitLocation, // Decal spawned at the hit location. 
        rotator(-Impact.HitNormal), // Orient decal into the surface. 
        128,
        128, // Decal size in tangent/binormal directions.
        256, // Decal size in normal direction.
        false, // If TRUE, use "NoClip" codepath.
        FRand() * 360, // random rotation
        Impact.HitInfo.HitComponent // If non-NULL, consider this component only.    
    )
}

Все это нам дает следующий результат:

На видео показано как я использовал Decal Material. Кстати говоря, учтите что такая реализация специально выглядит не очень красиво, да и с точки зрения производительности нецелесообразно, а является лишь доказательством работоспособности данного подхода к написанию собственного вида оружия.

Кроме того, если вы заметили, по умолчанию получившееся оружие находится в режиме "full auto"(автоматическое). А что если необходим режим одиночного выстрела(тоесть нужно нажимать на кнопку каждыйраз когда надо выстрелить)?
Хорошо, пусть это будет вашим домашним заданием! Пара подсказок:

- PendingFire обнуляется лишь когда происходит вызов StopFire
- По умолчанию StillFiring предполагает что у PendingFire есть значение TRUE, поэтому оружие должно продолжить стрелять.

Шаг 2: Отображение оружия

У нас есть работающее оружие, пришло время придать ему форму. Для этого мы должны сделать две вещи: добавить меш оружия, и разместить его в правильном месте. Как и следовало ожидать есть разница между видом оружия от третьего лица и от первого. Мы все сделаем как надо для обоих видов. Но сперва, пропишем то, что необходимо для каждой из ситуаций: прикрепляем к оружию ее модель:

DefaultPropeties
{
     Begin Object class=SkeletalMeshComponent Name=GunMesh
         SkeletalMesh=SkeletalMesh'WP_LinkGun.Mesh.SK_WP_Linkgun_3P'
         HiddenGame=FALSE
         HiddenEditor=FALSE
     End Object
     Mesh=GunMesh
     Components.Add(GunMesh)
}

Я использую меш Link Gun для примера. Вообще используются различные виды модели одного и того же оружия в зависимости от вида камеры в игре. Если вы посмотрите в AnimSet Editor на оружие, то заметите, что оно смещено в сторону. Вероятнее всего это предварительное смещение, для адекватного позиционирования оружия.

Так же как и меш от pawn, меш оружия должен быть смещен по оси Х, иначе оружие будет иметь неправильную позицию ( И все же, в контенте UDK, модели Shock Rifle от 1-ого лица и link gun от 3-его выглядят неправильно повернутыми( хотя это неважно для меша который используется для вида от 3-его лица)). В итоге, вы имеете два решения : повернуть модель с помощью кода, или сказать своему 3д-артисту, что он плохой человек и ему следует повернуть модель в 3д редакторе. :)
С этим покончили, теперь оружие прорисовывается. Вам придется верить мне на слово, потому как на данный момент его нельзя увидеть, т.к. оно расположено где-то за "горизонтом" (Возможно в центре локации, но я не проверял).
Обратите внимание, что все настройки меша находятся в MeshComponent, это означает что ваша модель может быть как и static, так и skeletal. По умолчанию предполагается что оружие это skeletal меш( и настроен скелет для использования на оружии различной анимации), поэтому skeletal мешем пользуются в 99% случаев.
Единственный вариант, который я вижу, где уместно использовать static, это оружие ближнего боя при игре от 3-его лица. А physics gun вообще демонстрирует, что в некоторых случаях оружию просто не требуется меш.

Вид оружия с камерой от первого лица. (First Person perspective)

Класс UDKWeapon имеет в себе функцию SetPosition, она вызывается при каждой последующей прорисовке кадра. По умолчанию она ничего не делает, но ее можно переписать так чтобы она поместила модель оружия в правильное место, по образу и подобию как действует та же функция, только в UTPawn. Несколько грубоватое решение, но со своей задачей справляется.

simulated event SetPosition(UDKPawn Holder)
{ 
    local vector FinalLocation;
    local vector X,Y,Z;

    Holder.GetAxes(Holder.Controller.Rotation,X,Y,Z);
    FinalLocation= Holder.GetPawnViewLocation(); //this is in world space. 
    FinalLocation= FinalLocation- Y * 12 - Z * 32; // Rough position adjustment 
    SetHidden(False); 
    SetLocation(FinalLocation); 
    SetBase(Holder); 
    SetRotation(Holder.Controller.Rotation);
}

Если вы читали мои туторы про камеры, то возможно поняли, что именно я тут сделал.По некоторым причинам, вызовы SetHidden(false) и SetBase необходимы. Вот что получается в результате.

Вид оружия с камерой от третьего лица.(Third Person Perspective)

А вот это намного проще. И не требует знаний пространственной геометрии. :) Все что нам надо, так это прицепить модель оружия к соответствующему сокету.
Что бы сделать это, нужно использовать функцию AttacWeaponTo из класса UDKWeapon, которая присоединит SkeletalMeshComponent к соответствующему сокету. Но дело в том, что по умолчанию, эта функция не вызывается( наверно потому, что не знает куда присоединять оружие). Быстрый осмотр класса UTWeapon показал нам, что все это должно делаться в TimeWeaponEquipping, что в общем, имеет смысл. Перепишем эти функции:

simulated function TimeWeaponEquipping()
{ 
    AttachWeaponTo( Instigator.Mesh,'WeaponPoint' );
    super.TimeWeaponEquipping();
} 

simulated function AttachWeaponTo( SkeletalMeshComponent MeshCpnt, optional Name SocketName ) 
{
    MeshCpnt.AttachComponentToSocket(Mesh,SocketName); 
}

Не правда ли все просто!? А вот результат наших стараний:

Однако, мы только присоединили оружие к игроку, мы не трогали никаких настроек самого оружия,(такие как месторасположение оружия), что может привести к некоторым проблемам, например, при выстреле снаряда. Это означает, что нам надо сделать кое-что в функции SetPosition() :

simulated event SetPosition(UDKPawn Holder) 
{ 
    local SkeletalMeshComponent compo; 
    local SkeletalMeshSocket socket; 
    local Vector FinalLocation; 
    compo = Holder.Mesh; 
    if (compo != none) 
    { 
        socket = compo.GetSocketByName('WeaponPoint');
        if (socket != none) 
        { 
            FinalLocation = compo.GetBoneLocation(socket.BoneName);
        }
    } 
    //And we probably should do something similar for the rotation :) 
    SetLocation(FinalLocation);
}

Система диалогов для UDK

2013-04-07T10:29:00.000-07:00

Нашел вот здесь довольно полезный мод, который можно использовать при создании игр практически любого жанра - система диалогов.
В принципе все очень просто, а также, в прилагаемом файле есть описание на английском, поэтому я просто переведу документацию на русский(вольный перевод) и сделаю некоторые комментарии .

Автор: S ha D

Перевод: Vadakuma

"Добро пожаловать на страничку описания системы диалогов, которую я создал, чтобы помочь пользователям UDK скорее адаптироваться к движку. Здесь будет описано как установить модуль системы диалогов и какими функциями этот модуль обладает.

Установка

Если Вы уже немного знакомы с UnrealScript, Вы наверняка знаете как устанавливать прилагающиеся исходники.Вы также должны знать, что если вы хотите интегрировать этот диалоговый модуль в уже созданный свой, то Вам придется более тщательно проанализировать код для правильного внедрения.

Для начала извлеките скачанные файлы (папки Development и UDKGame) из архива в папку с UDK. Соглашайтесь на замену.

Теперь у Вас есть папка Dialogue в директории "~/Development/Src".
Необходимо показать движку, что мы добавили новый скрипты.
Поэтому идем в "~/UDKGame/Config" и открываем DefaultEngineUDK.ini .Там находим строку:
ModEditPackages=MyMod

и заменяем ее на:

ModEditPackages=Dialogue

ПРИМЕЧАНИЕ: Я поступил немного по другому. Так как я внедрял этот код в свой, то делал редактируемой папку в DefaultEngine.ini ,но в принципе суть не должна была поменяться.

И остался последний шаг : открываем UnrealFrontEnd и жмем Make > Full Recompile.

Дальше просто запускаем UDK загружаем тестовую карту DIA_ExampleMap и тестируем.

Применение

Во второй части я объясню, как можно создавать диалоги с помощью Kismet Editor. Для этого я опишу каждую доступную в моде функцию. В Kismet жмем правую кнопку мыши и идем в Action > Dialogue :

Нода BeginDialogue

Первый узел позволяет игроку войти в режим диалога. Это обязательный узел перед всеми последующими!

Связи :

Inputs	In : Начало диалога
Outputs	Out : переход к самому сообщению
Variables	Player : Игрок для которого начинается диалог

Настройки :

	Background Texture - текстура используемая на заднем плане
	Button Hovered Texture - текстура для активных кнопок выбора
	Button Texture - текстура для неактивных кнопок выбора
	Margin X - горизонтальное расположение "margin" окна с диалогом (смотрим картинку).
	Margin Y - вертикальное расположение "margin" окна с диалогом (смотрим картинку).
	Padding X - горизонтальное "padding" окна с диалогом (смотрим картинку).
	Padding Y - вертикальное "padding" окна с диалогом (смотрим картинку).
	Use Texture - Установите флажок, если вы хотите использовать текстуры остановленные выше. По умолчанию будет просто белый цвет.

Скриншот поможет вам правильно понять, что есть что:

Нода Message

Данная нода выводит сообщение.

Связи :

Inputs	In : активируем вывод сообщения.
Outputs	Out : следующее сообщение
Variables	Player : игрок которому будет показано это сообщение Camera : камера с которой будет показано сообщение Text : содержание Name : имя персонажа который говорит

Настройки :

	Dialogue Box Top - Ставим галочку если хотим, чтобы сообщение выводилось сверху.

Нода Choice

Эта нода позволяет выбрать четыре варианта ответа.

Связи :

Inputs	In : показывает варианты ответов.
Ouputs	Choice X : действие если игрок выберет ответ Х.
Variables	Player : игрок котором показываются варианты ответов. Camera : камера из которой мы смотрим. Text : содержание сообщения. Name : имя персонажа что говорит.

Настройки :

	Choice X - Ставим галочку если хотим активировать вариант Х. Запомните эти настройки! (кнопка1 : сверху слева, кнопка 2 : сверху справа, кнопка 3 : снизу слева, кнопка 4 : снизу справа)
	Choice Text X - Текст на кнопке Х, если кнопка активирована.
	Dialogue Box Top - Ставим галку если хотим что бы сообщение было вверху экрана. (кнопки будут расположены снизу экрана)

Нода EndDialogue

Эта нода завершает режим диалога и возвращает к игре.

Связи :

Inputs	In :конец диалога.
Outputs	Out: игрок выходит из режима диалога.
Variables	Player : игрок которого выпускают из режима диалога.

Пример

И наконец можно, к примеру, построить вот такую логическую цепочку:

Игрок касается триггера в входит в режим диалога.Сначала показывается просто сообщение, а далее надо будет выбрать один ответ из двух вариантов. В зависимости, какой Вы выбрали ответ, Вам покажут то или иное сообщение."
скачать исходники.

PS: Благодаря наличию исходников мода, можно реализовать сколь угодно гибкую систему диалогов, удовлетворяющую потребностям поставленной вами задачи.

Также можно почерпнуть много полезной информации о реализации HUD в UDK, к примеру, тут и тут

UPDATE

Ввиду того, что Эпики постоянно что-либо модернизируют и изменяют во внутренней структуре движка, в частности и в скриптах, некоторые старые решения перестают работать так, как следует.Вот и эти скрипты дожили до этого момента :)
Эпики полностью вырезали скрипты UIscene(устаревшая система создания меню), на основе которых происходила обработка данных получаемых с мышки. Поэтому мышь теперь надо двигать иным способом. Прикрепил обновленный вариант, где проблема с мышью исправлена.

Скачать

Все новое - хорошо забытое старое

2011-07-02T07:25:00.000-07:00

старое видео, старой задумки:

А времени чтобы развить из этого что-то более интересное так и не получилось выделить :(