DEFINE_START

Code execution within the DEFINE_START executes first with the main AXS program (followed by any AXI files included in order compiled). Any modules will execute DEFINE_START after the main AXS program (and I assume in order defined by the AXS).

DATA_EVENT (ONLINE)

Modules seem to generate ONLINE events first, followed by the main AXS program.

We can use this to our advantage in that a module can define the default configuration settings. Then the main AXS file can overwrite these settings with it’s own online event that follows. Of course that means that some of the module initialization may be lost due to a mismatch in configurations (i.e. baud rate). Therefore it’s a good idea to wait for a ‘REINIT’ command following an ONLINE event.

//-----------------------------------------------------
// Relative level ramping with bounds check.
//-----------------------------------------------------
DEFINE_FUNCTION levelStep (SINTEGER snValue, SINTEGER snStep, SINTEGER snMin, SINTEGER snMax)
{
  snValue = snValue + snStep

  IF(snStep > 0) {
    IF(snValue > snMax)
      snValue = snMax
  }
  ELSE {
    IF(snValue < snMin)
      snValue = snMin
  }
}

It’s also a good idea to have a function for discrete level setting:

//-----------------------------------------------------
// Absolute level set.
//-----------------------------------------------------
DEFINE_FUNCTION levelSet (INTEGER nChn, SINTEGER snValue)
{
  uLvl[nChn].snValue = snValue

  SWITCH(nChn) {
    CASE LVL_PGM : SEND_STRING dvMXR,"'LVL_PGM-',ITOA(snValue)"
    CASE LVL_MIC : SEND_STRING dvMXR,"'LVL_MIC-',ITOA(snValue)"
  }
}

Then it’s easy to implement with button events:

//-----------------------------------------------------
// Program volume (0-100).
//-----------------------------------------------------
BUTTON_EVENT[dvPNLs,24]     // Vol Up
BUTTON_EVENT[dvPNLs,25]     // Vol Down
BUTTON_EVENT[dvPNLs,26]     // Vol Mute
{
  PUSH :
  {
    SWITCH(BUTTON.INPUT.CHANNEL) {
      CASE 24  : {
        TO[BUTTON.INPUT]

        levelStep (uLvl[LVL_PGM].snValue, 1, 0, 100)
        levelSet  (LVL_PGM, uLvl[LVL_PGM].snValue)
      }
      CASE 25  : {
        TO[BUTTON.INPUT]

        levelStep (uLvl[LVL_PGM].snValue,-1, 0, 100)
        levelSet  (LVL_PGM, uLvl[LVL_PGM].snValue)
      }
      CASE 26  : {
      }
    }
  }
  HOLD[3,REPEAT] :
  {
    SWITCH(BUTTON.INPUT.CHANNEL) {
      CASE 24  : levelStep (uLvl[LVL_PGM].snValue, 5, 0, 100)
      CASE 25  : levelStep (uLvl[LVL_PGM].snValue,-5, 0, 100)
    }

    IF(BUTTON.INPUT.CHANNEL <> 26)
      levelSet  (LVL_PGM, uLvl[LVL_PGM].snValue)
  }
}

More investigating revealed that multi-edit keyboards with pre-loaded values are possible. Here’s the text field properties to use:

• Assign the button a type of “Text Input”. This allows it to be selected (focus) and have the text value editable.
• Assign the button a variable text value. This is used for pre-loading the value from Netlinx code.
• Assign the “Name” property a value to be pre-pended when the edit is done, as in KB_NAME-.
• Parse strings back from the touch panel and look for KB_NAME- to get the values. Be sure and look for an ABORT value, in case the person decides to cancel the edit.
• For some reason, this KB_NAME- is not displayed using netlinx diagnostics. Test code will reveal that it really does work though.

Original post on 09 April 2010

AMX touch panel keyboards and keypads allow editing of a single item. You can customize a system page template to allow editing of multiple items, such as a telephone speed-dial entry for a person’s name and number. It works, but with some drawbacks.

GUI Tweaks

First off, open up the system page template and copy the __keyboard popup into your touch panel file. You will want to rename it (otherwise any @AKB or AKEYB command will use the new multiple edit keyboard). I’ll rename the new popup to ‘kbSpdDialEditor’.

Open up the new popup and select the prompt at the top. We’ll need to change this to a static text label, say ‘Enter new name and number’. Unfortunately, we won’t be able to use the @AKB command.

Open up the new popup and select the text area button. Resize it, allowing room for a label next to it, like ‘Name:’. Reselect the text area again. It will have a variable text assignment as setup:multi-line text area.

With the button, we will assign the channel number for setup:text entry and modify the ON border color. This will enable highlighting of the current item being edited.

Next, we’ll modify the OFF text value to ‘KB_NAME’. The touch panel will use this value as the header with the value once the user presses DONE (i.e. KB_NAME-Chad Reynoldson).

Copy the label/button pair and paste it below. Rename the label and the OFF text value to ‘KB_NUMBER’.

Implementation

You can use either a send command (i.e. @PPN) or a pageflip assignment from a touch panel button to bring up the new kbSpdDialEditor popup. Each time the fields will be reset.

When the user presses DONE, you’ll see a string event with ‘KB_NAME-value’ and another with ‘KB_NUMBER-value’.

Drawbacks

It works well and moves this functionality into the touch panel file, which is where I prefer to off-load as much work as possible. Unfortunately it won’t allow us to pre-load the editable name and number with something we may have stored in netlinx code, something @AKB allows us to do. This presents a huge problem for the end-user.

We could overcome this with netlinx code, but that breaks the simplicity of off-loading the heavy lifting to the touch panel.

So this seems like an exercise to prove that it works. Unfortunately it has some drawbacks that takes us right back to where we started.

Hope you can find value in it and remember how easy this is in AMX!

(*---------------------------------------------------------*)
(* Inc/dec cTime by x number of seconds.                 --*)
(*---------------------------------------------------------*)
DEFINE_FUNCTION SLONG getTimeOffset (CHAR cTime[8], SLONG slOffsetSec)
STACK_VAR
  SLONG slHr
  SLONG slMin
  SLONG slSec
  SLONG slTotalSec
  CHAR  cTimeOffset[8]
{
(*-- Offset range limited to 24 hours --*)
  IF((slOffsetSec > 86400) || (slOffsetSec < -86400))
    RETURN(-1)

(*-- Get seconds total --*)
  slHr  = MAX_VALUE(0, TIME_TO_HOUR  (cTime))
  slMin = MAX_VALUE(0, TIME_TO_MINUTE(cTime))
  slSec = MAX_VALUE(0, TIME_TO_SECOND(cTime))

  slTotalSec = (slHr * 3600) + (slMin * 60) + slSec

  slTotalSec = slTotalSec + slOffsetSec

(*-- Need the time --*)
  slHr  = (slTotalSec / 60) / 60
  slMin = (slTotalSec -  (slHr*60*60)) / 60
  slSec =  slTotalSec - ((slHr*60*60) + (slMin*60))

  cTimeOffset = "RIGHT_STRING("'00',ITOA(slHr )",2),':',
                 RIGHT_STRING("'00',ITOA(slMin)",2),':',
                 RIGHT_STRING("'00',ITOA(slSec)",2)"

(*-- Only passback what they sent in (i.e. HH:MM:SS or HH:MM) --*)
  SET_LENGTH_STRING(cTimeOffset, LENGTH_STRING(cTime))

(*-- Passback --*)
  cTime = cTimeOffset
  RETURN(1)
}

Here’s a simple implementation of it:

BUTTON_EVENT[dvPnls1a,1] // Up
BUTTON_EVENT[dvPnls1a,2] // Down
{
  PUSH :
  {
    SWITCH(BUTTON.INPUT.CHANNEL)
    {
      CASE 1 : getTimeOffset (cThisTime, 900)   // Inc by 15 minutes
      CASE 2 : getTimeOffset (cThisTime,-900)   // Dec by 15 minutes
    }

    SEND_COMMAND dvPnls1a,"'TEXT1-',cThisTime"
  }
}