COBOLプログラミング入門

定数の種類

admin — Wed, 02 May 2012 02:22:25 +0000

COBOLでは、プログラム中に記述したデータを定数と呼びます。

定数は、数値定数、文字定数、表意定数の3つに分けることができます。

数値定数

プログラム中に記述した数値データを「数値定数」と言います。
数値定数は、符号(+/-)、数字(0～9)、小数点(.)を組み合わせて記述します。
ただし、プラス値を表すときは符号(+)を省略できます。

000010 IDENTIFICATION                   DIVISION.
000020 PROGRAM-ID.                      SAMPLE-14.
000030*
000040 ENVIRONMENT                      DIVISION.
000050*
000060 DATA                             DIVISION.
000070 WORKING-STORAGE                  SECTION.
000080 01 WRK-NUMBER    PIC 9(5).
000090 01 WRK-PAI       PIC 9V9(4).
000100 01 WRK-MINUS     PIC S9(5).
000110*
000120 PROCEDURE DIVISION.
000130 MAIN.
000140     MOVE 12345    TO WRK-NUMBER.
000150     MOVE 3.1415   TO WRK-PAI.
000160     MOVE -12345   TO WRK-MINUS.
000170*
000180     DISPLAY "WRK-NUMBER[" WRK-NUMBER "]".
000190     DISPLAY "WRK-PAI[" WRK-PAI "]".
000200     DISPLAY "WRK-MINUS[" WRK-MINUS "]".
000210     STOP RUN.

実行結果

WRK-NUMBER[12345]
WRK-PAI[3.1415]
WRK-MINUS[-12345]

なお、数値定数の最大桁数は18桁(整数部・小数部の合計)と決められています。

文字定数

プログラム中に記述した文字データを「文字定数」と言います。
文字定数を記述するときは、前後をダブルクォーテーション(“)もしくはシングルクォーテーション(‘)で括ります。

000010 IDENTIFICATION                   DIVISION.
000020 PROGRAM-ID.                      SAMPLE-15.
000030*
000040 ENVIRONMENT                      DIVISION.
000050*
000060 DATA                             DIVISION.
000070 WORKING-STORAGE                  SECTION.
000080 01 WRK-STRING      PIC X(5).
000090 01 WRK-NUMSTRING   PIC X(5).
000100 01 WRK-HEXASCII    PIC X(3).
000110*
000120 PROCEDURE DIVISION.
000130 MAIN.
000140     MOVE "ABCDE"    TO WRK-STRING.
000150     MOVE "12345"    TO WRK-NUMSTRING.
000160     MOVE X"414243"  TO WRK-HEXASCII.
000170*
000180     DISPLAY "WRK-STRING[" WRK-STRING "]".
000190     DISPLAY "WRK-NUMSTRING[" WRK-NUMSTRING "]".
000200     DISPLAY "WRK-HEXASCII[" WRK-HEXASCII "]".
000210     STOP RUN.

実行結果

WRK-STRING[ABCDE]
WRK-NUMSTRING[12345]
WRK-HEXASCII[ABC]

内容が数値だとしても、ダブルクォーテーション（もしくはシングルクォーテーション）で括れば、文字定数として扱われます。
また、文字を16進文字コードで記述することもできます。
その場合は、ダブルクォーテーションの前に「X」を記述します。

なお、文字定数の最大長は160文字(160バイト)となります。

表意定数

COBOLには、数値のゼロや文字のスペースなどを表す特殊な定数があります。
それらを「表意定数」と言います。

表意定数の種類

値	意味	形式
ZERO,ZEROS,ZEROES	n個の0を意味する	数値
SPACE,SPACES	n個の空白を意味する	文字
QUOTE,QUOTES	領域全体を引用符(“)で埋める	文字
HIGH-VALUE,HIGH-VALUES	領域全体をFFで埋める	文字
LOW-VALUE,LOW-VALUES	領域全体を00で埋める	文字
ALL定数	指定した文字定数を領域全体に埋める	文字

000010 IDENTIFICATION                   DIVISION.
000020 PROGRAM-ID.                      SAMPLE-16.
000030*
000040 ENVIRONMENT                      DIVISION.
000050*
000060 DATA                             DIVISION.
000070 WORKING-STORAGE                  SECTION.
000080 01 WRK-NUMBER      PIC 9(5).
000090 01 WRK-STRING      PIC X(5).
000100 01 WRK-ASTRING     PIC X(5).
000110*
000120 PROCEDURE DIVISION.
000130 MAIN.
000140     MOVE ZERO      TO WRK-NUMBER.
000160     MOVE SPACE     TO WRK-STRING.
000160     MOVE ALL "A"   TO WRK-ASTRING.
000170*
000180     DISPLAY "WRK-NUMBER[" WRK-NUMBER "]".
000190     DISPLAY "WRK-STRING[" WRK-STRING "]".
000200     DISPLAY "WRK-ASTRING[" WRK-ASTRING "]".
000210     STOP RUN.

WRK-NUMBER[00000]
WRK-STRING[     ]
WRK-ASTRING[AAAAA]

データ項目の初期値を定義する

上記サンプルではMOVE文による定数の転記方法を紹介していますが、データ定義時に各データ項目に初期値を設定することも可能です。

000010 IDENTIFICATION                   DIVISION.
000020 PROGRAM-ID.                      SAMPLE-17.
000030*
000040 ENVIRONMENT                      DIVISION.
000050*
000060 DATA                             DIVISION.
000070 WORKING-STORAGE                  SECTION.
000080 01 WRK-NUMBER      PIC 9(5) VALUE 12345.
000090 01 WRK-STRING      PIC X(5) VALUE "ABCDE".
000100*
000110 01 WRK-DATA       VALUE "12345ABDCE".
000120    03 WRK-ITEM1    PIC 9(5).
000130    03 WRK-ITEM2    PIC X(5).
000140*
000150 PROCEDURE DIVISION.
000160 MAIN.
000170     DISPLAY "WRK-NUMBER[" WRK-NUMBER "]".
000180     DISPLAY "WRK-STRING[" WRK-STRING "]".
000190*
000200     DISPLAY "WRK-ITEM1[" WRK-ITEM1 "]".
000210     DISPLAY "WRK-ITEM2[" WRK-ITEM2 "]".
000220     STOP RUN.

実行結果

WRK-NUMBER[12345]
WRK-STRING[ABCDE]
WRK-ITEM1[12345]
WRK-ITEM2[ABDCE]

データ項目に初期値を設定するにはVALUE句を使用します。
VALUE句を使用した初期値の設定は、プログラム内で値が常に同じである場合は非常に便利な方法です。

VALUE句は基本項目だけでなく集団項目にも指定できます。
その場合、その集団項目配下の集団項目や基本項目にはVALUE句を指定できません。
また、初期値の長さは集団項目配下の全基本項目以下にする必要があります。

データ項目の定義方法(PICTURE句)

admin — Tue, 01 May 2012 13:49:29 +0000

前回までの記事でCOBOLプログラム上でのデータ定義の基本について見てきました。
今回はサンプルソースとその実行結果からデータ定義について見ていきます。

データ定義はデータ部（DATA DIVISION）の作業場所節（WORKING-STORAGE SECTION）で行います。

000010 IDENTIFICATION                   DIVISION.
000020 PROGRAM-ID.                      SAMPLE-13.
000030*
000040 ENVIRONMENT                      DIVISION.
000050*
000060 DATA                             DIVISION.
000070 WORKING-STORAGE                  SECTION.
000080 01 A PICTURE 9(5).
000090 01 B PICTURE ZZZZ9.
000110 01 C PICTURE S9(5).
000120 01 D PICTURE X(5). 
000130*
000140 PROCEDURE DIVISION.
000150 MAIN.
000160     MOVE 100 TO A B C.
000170     MOVE "00100" TO D.
000180     DISPLAY "A[" A "]". 
000190     DISPLAY "B[" B "]".
000200     DISPLAY "C[" C "]".
000210     DISPLAY "D[" D "]".
000220     STOP RUN.

実行結果

A[00100]
B[  100]
C[+00100]
D[00100]

データ項目のデータ型と長さ（桁数）を指定するには、データ項目名に続けてPICTURE句で行います。

PICTURE句書式: レベル番号データ項目名 PICTURE 符号・データ型・長さ・小数.

・符号　　　数値形式で符号が必要な場合は、Sを記述。
・データ型　X、9、Nなどのタイプ識別子を指定
・長さ　　　タイプ識別子を桁数分続けて記述するか、タイプ名の後に括弧で括って長さを指定
・小数　　　数値項目で小数を扱う場合は、Vに続けて小数部の桁数を指定

※PICTUREをPICと省略して記述することもできます。

PICTURE句を使用してデータ型や長さを指定するのは「基本項目」に限ります。
集団項目には使用しません。

データ型の種類

admin — Mon, 30 Apr 2012 06:08:47 +0000

前回までの記事で、COBOLプログラム上で使用するデータを定義するときの概念やルールについて見てきました。
今回は、データ型について見ていきます。

データ項目（変数）を定義する際、名前やレベル番号の他に、データ型とデータ項目の長さ（桁数）も指定します。

COBOLで扱えるデータ型は、数値形式、英数字形式、書式編集形式の3つに大別できます。

数値形式

タイプ識別子	内容
9	数字１桁
S	符号付きの値（S指定のない項目は正の値として扱う）
V	小数点の位置

記述例	バイト数	意味
9(5)	5バイト	数字5文字で十進5けたの符号なし整数を表す
9(5)V99	7バイト	数字7文字で十進整数部5けた、小数部2けたの符号なし数を表す
S9(5)	5バイト	十進5けたの符号あり整数を表す

※9(5)と99999は同じ意味。

英数字形式

タイプ識別子	内容
X	任意の文字( 英字、数字、空白含む)

記述例	バイト数	意味
X(50)	50バイト	英数字50文字

書式編集形式

タイプ識別子	内容
Z	ゼロサプレス。指定した桁数に満たない場合、その部分を空白に置き換える
，	カンマが挿入される文字位置
.	位置合わせ用の小数点を表す
\	通貨記号。ゼロサプレスと同等

記述例	バイト数	意味
ZZZ,ZZ9	7バイト	整数部3けた（ゼロサプレス）＋カンマ＋整数部3けた（ゼロサプレス）
ZZZZZ9.999	11バイト	整数部6けた（ゼロサプレス）＋小数点のピリオド＋小数部3けた

データ型の指定とあわせて、データ項目の長さ（桁数）を指定するのがCOBOLの特徴です。

命名規則と特殊なデータ定義

admin — Fri, 27 Apr 2012 23:41:51 +0000

データ項目を定義する際、任意の名前を決めることになりますが、命名規則に従って名前を決める必要があります。

COBOLの規格により違いはありますが、代表的な命名規則を下記に示します。

使用できる文字
　・半角英数字
　・半角ハイフン(-)とアンダーバー(_)
　・日本語、全角文字（JIS-COBOLに限る）

データ項目名の長さ
　・最大30文字まで

その他の規則
　・予約語（MOVEなど）は使えない
　・半角記号（ハイフン、アンダーバー）で始まる、または半角記号で終わる名前は使えない
　・最低1文字の英字を含めないといけない（半角英数で作成する場合）
　・日本語と半角文字を混ぜてはならない

特殊なデータ項目「FILLER」

FILLERとは、「無名の項目」を意味し、データ項目名を省略するときに指定されます。

FILLERの定義方法: レベル番号 FILLER PIC 型.

FILLERはデータ項目を拡張する場合に備えて、予備として使われることが多いです。

特殊なレベル

レベル番号はデータ項目の階層や従属関係を定義するための番号のことであり、1～49の範囲で表されますが、その範囲以外に「66」「77」「88」と言った特殊なレベルも存在します。

77	どの集団項目にも属さない単独のデータ項目を定義するときに使用。他のデータ項目とは従属関係を持たない。
88	条件名条件を定義する場合に使用。
66	RENAMES（再命名）記述項を示すために使用。

COBOLのデータ定義

admin — Wed, 25 Apr 2012 07:21:38 +0000

プログラム上で使用するデータを定義するとき、COBOLでは集団項目・基本項目・レベル番号と言われる概念を用います。

データ項目

プログラムは、何らかのデータの「入力」があり、そのデータを使い、とある計算を行い、その結果を「出力」する、というのが基本的な流れとなります。

その流れの中で、入力されたデータや計算過程のデータなどを保存しておく「場所」が必要です。
ですので、プログラミングを行う際、命令文を記述していく前に、まずその「場所」を定義してあげる必要があります。

COBOLではその「場所」に名前を付けたものをデータ項目と呼びます。
（つまりデータ項目とは、C言語など他の言語でいう変数のことです。）

集団項目と基本項目

データ項目は基本項目と、1つ以上の基本項目が複合した構造を持つ集団項目とに分類されます。

例えば、「日付」というデータ項目について考えてみます。
日付は「年」「月」「日」に分類できます。
この場合、「日付」が集団項目となり、「年」「月」「日」がデータ項目となります。

レベル番号

レベル番号とはデータ項目の階層や従属関係を定義するための番号のことです。
1から49までの範囲で表され、1が最上位の階層となり、数字が増えるほど下位の階層となります。

下記に集団項目の定義例を示します。

01  従業員.
    03  従業員コード  PIC 9(6).
    03  従業員名  PIC  X(30).
    03  入社日付.
        05  年  PIC 9999.
        05  月  PIC 99.
        05  日  PIC 99.

レベル番号は連番とするのではなく、ある程度、番号をあけて繰り上げていくのが通例となっています。
例えば1の次は3、3の次は5と定義していきます。
これは、後に階層構造が変わり、新たな集団項目を間に組み込みたいときなどのための対策となります。

また、数字は「01」「03」のように2桁で記述するのが一般的となっています。
（ただし、2桁である必要はなく、「1」「3」と記述してもまったく問題ありません。）

PERFORM TIMESによる繰り返し

admin — Sat, 21 Apr 2012 00:00:13 +0000

繰り返す回数があらかじめ明確になっている場合は、PERFORM TIMESが便利です。

下記は、繰り返しを10回行う処理のサンプルソースです。

000010 IDENTIFICATION                   DIVISION.
000020 PROGRAM-ID.                      SAMPLE-11.
000030*
000040 ENVIRONMENT                      DIVISION.
000050*
000060 DATA                             DIVISION.
000070 WORKING-STORAGE                  SECTION.
000080 77 WRK-COUNTER                   PIC 9(3).
000090*
000100 PROCEDURE DIVISION.
000110 MAIN.
000120     MOVE  1                      TO  WRK-COUNTER.
000130     PERFORM  10 TIMES
000140         DISPLAY  "WRK-COUNTERは " WRK-COUNTER   UPON  CONSOLE
000150          ADD  1                   TO  WRK-COUNTER
000160     END-PERFORM.
000170     STOP RUN.

PERFORM TIMES 書式: PERFORM 回数 TIMES
      :
    命令文1
    命令文2
      :
END-PERFORM.

※回数は数値定数か数値形式のデータ項目で指定する。
※EXIT PERFORM文を実行すると、そのタイミングで繰り返し処理から抜ける。
※PERFORMからEND-PERFORMまでの間に記述する命令文にはピリオド不要。

PERFORM VARYING UNTILによる繰り返し

admin — Wed, 18 Apr 2012 13:26:34 +0000

PERFORM VARYING UNTILで繰り返しを行う場合のサンプルソースです。
VARYINGを使うことで処理を繰り返すごとにカウンタが自動的にカウントアップしていきます。（C言語でのfor文に相当します）

000010 IDENTIFICATION                   DIVISION.
000020 PROGRAM-ID.                      SAMPLE-10.
000030*
000040 ENVIRONMENT                      DIVISION.
000050*
000060 DATA                             DIVISION.
000070 WORKING-STORAGE                  SECTION.
000080 77 WRK-COUNTER                   PIC 9(3).
000090*
000100 PROCEDURE DIVISION.
000110 MAIN.
000120     PERFORM  VARYING  WRK-COUNTER  FROM  1  BY  1
000130                         UNTIL  WRK-COUNTER  >  10
000140         DISPLAY  "WRK-COUNTERは " WRK-COUNTER   UPON  CONSOLE
000150     END-PERFORM.
000160     STOP RUN.

PERFORM VARYING UNTIL 書式

PERFORM VARYING カウンタ FROM 初期値 BY 増分値
                [WITH TEST 判定のタイミング] UNTIL 論理式
      :
    命令文1
    命令文2
      :
END-PERFORM.

※EXIT PERFORM文を実行すると、そのタイミングで繰り返し処理から抜ける。
※PERFORMからEND-PERFORMまでの間に記述する命令文にはピリオド不要。

判定のタイミング

BEFORE	PERFORMを実行する前に論理式の条件を判定する（前判定型） C言語でのwhile文に相当
AFTER	PERFORMを実行した後に論理式の条件を判定する（後判定型） C言語でのdo-while文に相当

※WITH TESTを省略した場合、BEFOREが指定されたものとみなされる。

PERFORM UNTILによる繰り返し

admin — Sun, 15 Apr 2012 03:16:51 +0000

繰り返し処理を行いたい場合は、PERFORM文を使用します。

下記はPERFORM UNTILにより繰り返しを行うサンプルソースです。

000010 IDENTIFICATION                   DIVISION.
000020 PROGRAM-ID.                      SAMPLE-09.
000030*
000040 ENVIRONMENT                      DIVISION.
000050*
000060 DATA                             DIVISION.
000070 WORKING-STORAGE                  SECTION.
000080 77 WRK-COUNTER                   PIC 9(3).
000090*
000100 PROCEDURE DIVISION.
000110 MAIN.
000120     MOVE  1                      TO  WRK-COUNTER.
000130     PERFORM  UNTIL  WRK-COUNTER  >  10
000140         DISPLAY  "WRK-COUNTERは " WRK-COUNTER   UPON  CONSOLE
000150         ADD  1                   TO  WRK-COUNTER
000160     END-PERFORM.
000170     STOP RUN.

UNTILに指定した「WRK-COUNTERが10より大きくなるまで」という条件が成立するまで、END-PERFORMまでの範囲に記述した命令文が繰り返し実行されます。

PERFORM UNTIL 書式

PERFORM [WITH TEST 判定のタイミング] UNTIL 論理式
      :
    命令文1
    命令文2
      :
END-PERFORM.

※EXIT PERFORM文を実行すると、そのタイミングで繰り返し処理から抜ける。
※PERFORMからEND-PERFORMまでの間に記述する命令文にはピリオド不要。

判定のタイミング

BEFORE	PERFORMを実行する前に論理式の条件を判定する（前判定型） C言語でのwhile文に相当
AFTER	PERFORMを実行した後に論理式の条件を判定する（後判定型） C言語でのdo-while文に相当

※WITH TESTを省略した場合、BEFOREが指定されたものとみなされる。

PERFORM文では、上記サンプルのようにUNTILで指定した条件になるまで繰り返す方法以外に、カウンタを用いた方法もあります。

EVALUATE文による多岐選択

admin — Thu, 12 Apr 2012 13:06:37 +0000

複数の異なった処理の中から、条件にあった処理を行いたい場合、EVALUATE文を使います。

下記はEVALUATE文を使用したプログラムのサンプルソースです。

000010 IDENTIFICATION                   DIVISION.
000020 PROGRAM-ID.                      SAMPLE-08.
000030*
000040 ENVIRONMENT                      DIVISION.
000050*
000060 DATA                             DIVISION.
000070 WORKING-STORAGE                  SECTION.
000080 77 WRK-FRUITNUM                  PIC 9(3).
000090*
000100 PROCEDURE DIVISION.
000110 MAIN.
000120     ACCEPT    WRK-FRUITNUM       FROM  CONSOLE.
000130*
000140     EVALUATE  WRK-FRUITNUM
000150         WHEN  100
000160               DISPLAY  "アップル"   UPON  CONSOLE
000170*
000180         WHEN  200
000190               DISPLAY  "オレンジ"   UPON  CONSOLE
000200*
000210         WHEN  300
000220               DISPLAY  "メロン"     UPON  CONSOLE
000230*
000240         WHEN  OTHER
000250               DISPLAY  "その他"     UPON  CONSOLE
000260*
000270     END-EVALUATE.
000280     STOP RUN.

EVALUATE文書式１

EVALUATE 評価対象
    WHEN 値
        命令文
      :
    WHEN 値1 THRU 値2
        命令文
      :
    WHEN 値
    WHEN 値
        命令文
      :
    WHEN OTHER
        命令文
      :
END-EVALUATE.

WHENの書式

WHEN 値	単一で評価する。複数の値を「または」で評価するときは、WHENを連続して記述する。
WHEN 値1 THRU 値2	値の範囲を評価する。値1から値2の範囲内であれば条件は成立する。
WHEN OTHER	どのWHENにも該当しなかったとき実行される。

評価対象が複数ある場合でもEVALUATE文を使用できます。

000010 IDENTIFICATION                   DIVISION.
000020 PROGRAM-ID.                      SAMPLE-043.
000030*
000040 ENVIRONMENT                      DIVISION.
000050*
000060 DATA                             DIVISION.
000070 WORKING-STORAGE                  SECTION.
000080 77 WRK-FRUITNUM                  PIC 9(3).
000080 77 WRK-KAKOKIND                  PIC 9(3).
000090*
000100 PROCEDURE DIVISION.
000110 MAIN.
000120     ACCEPT    WRK-FRUITNUM       FROM  CONSOLE.
000120     ACCEPT    WRK-KAKOKIND       FROM  CONSOLE.
000130*
000140     EVALUATE  WRK-FRUITNUM  ALSO  WRK-KAKOKIND
000150         WHEN  100  ALSO  100
000160               DISPLAY  "アップルジュース"       UPON  CONSOLE
000170*
000180         WHEN  100  ALSO  200
000190               DISPLAY  "アップルシャーベット"   UPON  CONSOLE
000200*
000210         WHEN  300  ALSO  ANY
000220               DISPLAY  "メロン"     UPON  CONSOLE
000230*
000240         WHEN  OTHER
000250               DISPLAY  "その他"     UPON  CONSOLE
000260*
000270     END-EVALUATE.
000280     STOP RUN.

EVALUATE文書式２: EVALUATE 評価対象1 ALSO 評価対象2 [ALSO 評価対象3…]
    WHEN 評価1 ALSO 評価2 [ALSO 評価3…]
        命令文
      :
END-EVALUATE.

※評価内容にANYを指定すると、その部分は評価されない。

IF～THEN文による多岐選択

admin — Tue, 10 Apr 2012 02:47:34 +0000

COBOLのIF～THEN文は1つの条件で2つの処理分岐を実現するものです。
しかし、下記のように3つ以上の条件で3つ以上の処理分岐を実現したい場合も少なくありません。

「１が入力されたら（条件１）　　　　処理１
　２が入力されたら（条件２）　　　　処理２
　３から５が入力されたら（条件３）　処理３
　それ以外なら（条件４）　　　　　　処理４」

このような処理に対して、例えばC言語のIF文であれば多岐条件文（ELSE IF文）が用意されていますが、COBOLではそれがありません。
そのため3つ以上の処理分岐を実現させたい場合は、IF～THEN文を入れ子にしてやる必要があります。

000010 IDENTIFICATION                   DIVISION.
000020 PROGRAM-ID.                      SAMPLE-07.
000030*
000040 ENVIRONMENT                      DIVISION.
000050*
000060 DATA                             DIVISION.
000070 WORKING-STORAGE                  SECTION.
000080 77 NUM                           PIC 9(3).
000090*
000100 PROCEDURE DIVISION.
000110 MAIN.
000120     ACCEPT    NUM                FROM  CONSOLE.
000130     IF  NUM  = 1 THEN
000140         DISPLAY  "1が入力された" UPON  CONSOLE
000150     ELSE
000160         IF  NUM = 2 THEN
000170             DISPLAY  "2が入力された" UPON  CONSOLE
000180         ELSE            
000190             IF  NUM >= 3 AND NUM <= 5 THEN
000200                 DISPLAY  "3から5の間が入力された" UPON  CONSOLE
000210*
000220             ELSE
000230                 DISPLAY  "それ以外"               UPON  CONSOLE
000240*                 
000250             END-IF
000260*        
000270         END-IF
000280*
000290     END-IF.
000300     STOP RUN.

上記のように記述すれば、一応要件を満たすことができますが、ご覧のとおり入れ子が深くなりソースコードが非常に読みづらくなります。
条件が増えれば、なおさらです。

そのため、読みやすいよう下記のような工夫を行ってコーディングする人もいます。

000130     IF  NUM  = 1 THEN
000140         DISPLAY  "1が入力された" UPON  CONSOLE
000150*
000160     ELSE IF  NUM = 2 THEN
000170         DISPLAY  "2が入力された" UPON  CONSOLE
000180*        
000190     ELSE IF  NUM >= 3 AND NUM <= 5 THEN
000200         DISPLAY  "3から5の間が入力された" UPON  CONSOLE
000210*        
000220     ELSE
000230         DISPLAY  "それ以外"      UPON  CONSOLE
000240*
000250     END-IF
000260     END-IF
000270     END-IF.

上記サンプルは、ELSE以降に新たなIF～THEN文を記述する方法です。
「ELSE IF」という文があるわけではありません。