Jonathan Campos' Blog

ApplicationFinder.ane

jonbcampos — Mon, 07 Nov 2011 22:32:18 +0000

This is the first ANE that I made for my own project… hopefully my other ones can be released soon.

Anyways, let’s get right to it.

The ApplicationFinder ANE is something I created to help you find other Applications on your Android system. You can get information 2 ways.

isAppInstalled(package:String):PackageInfo

This method looks to see if a particular application (by app id) is installed. If the application is installed ApplicationFinder returns the name, package id, version number, and version name of the application. If the app isn’t installed you get null.

getInstalledApps():Array

This method just returns to you the entire list of installed apps. Go nuts, search and find what you need. Like the isAppInstalled you get the name, package id, version number, and version name of the application.

Later I’ll add things like also returning the app icon, possibly some app management methods (startup, shutdown, etc).

I’ve included my test app here so you can run it, and then the ANE also. Enjoy!

Test Application (FXP)
ApplicationFinder.ane

Queue Manager for Sony Tablets

jonbcampos — Fri, 28 Oct 2011 03:33:41 +0000

Today I am releasing a custom Queue Manager for the Sony Tablets and the Air App Challenge.

Thanks to Adobe AIR and Flex this process was extremely simple. Feel free to poke through if you have a Netflix account. This new version uses the newest versions of Flex and AIR.

Feel free to leave comments and let me know your thoughts.

Reflections on Adobe Max 2011

jonbcampos — Tue, 11 Oct 2011 17:00:55 +0000

Disclaimer:
First off, I’m not an Adobe employee and so all the thoughts presented are my own. I do however make a living off of Adobe products and use them daily… basically consistently. As such I feel that I have a good grasp of the possible pitfalls when using the tooling. Anyways, enough disclaimer.

Rather than just saying “I loved it” or “I hated it” I’m going to run you through my flow of emotions throughout the week to try and communicate my stream of consciousness – hopefully it doesn’t drive you too crazy.

PreMAX

The week started for me already on the road going to and coming from the Big Android BBQ in Austin. Being crushed with the stress of trying to finish up my Air App Challenge application and prepping for 8 presentations in the next few days I definitely wasn’t as social as I usually would have been. I took a train to Austin to give me some time to work and when I arrived the Android Guys were doing what they do well – drink heavily. It was fun to see friends from last year’s conference and many people immediately recognized me as the person that represented Adobe and AIR at last year’s conference – many of them telling me how well their Air for Android apps were doing.

I was extremely impressed the entire time in Austin how well the Android Community opened their arms to Adobe and Adobe is doing all they can to repay them in kind. Presentation 1 was a panel with Terry Ryan, Todd Sanders, Kevin Schmidt, and Liz Fredrick. The first question out of the gate was “what is up with html5 vs flash”. Interrupting the Adobe people there I got on my soap box that Adobe isn’t Flash, it is just one tool in the toolbox. Long story short – as I will talk about HTML5 vs Flash later – things went well and the Android folks asked great questions with very frank answers returned.

Crazy rush off to Max and sadly missed the BBQ itself.

Arriving in LA the festivities started and continued into the great community summit the next day. Community Summit is no secret but only available for community leaders. If you want to join then start leading a user group or become an ACP. Glazing over what happened at Summit presentation 2 went down pretty well.

Only thing that got me upset was having a phone robbed from me at the community summit. No I didn’t get my phone taken, but – listen up motorola guys! – I totally deserved that phone and had barely stepped out of the room. Robbed.

Festivities continue and we are now into Day 1 of Max.

Day 1
Day 1 started with the Keynote and I will say I was very happy to see this Keynote. Even as a developer I will say that the last few years Keynotes seemed a bit too Flex and Flash heavy. I was very happy to see the designers get some love and the new set of apps and Cloud services. Lack of Oprah moments aside I was very happy with it and rushed off to presentation 3 knowing that day 2 Keynote was supposed to be developer heavy. Seems fair to me.

During the Day 1 Keynote though the information dropped that Adobe bought PhoneGap. I was immediately very excited by this and happy for the purchase for both Adobe and Nitobi. Having worked with the PhoneGap guys previously for SXSW I was very happy because now Adobe seemed to have a very real mobile HTML story along with the Adobe AIR story. I felt there was a lot of “synergies” in this marriage and everyone should be happy. Having seen the PhoneGap cloud solutions at SXSW I felt between the different HTML mobile stories they were the most “complete” and have been nothing but impressed by their output. Again, great job Nitobi.

- SXSW Reminder -
Dedo Inc. was proudly picked to present at SXSW in Austin during the summer and brought together Adobe and Nitobi to each show off their multi-screen stories. With a few hundred people in attendance the presentation seemed to go pretty well. I already knew the AIR story by that point but while on the panel I even let Brian of Nitobi know how impressed I was by their solution. Even then I thought “if these two came together that would be awesome”.

I knocked Presentation 3 out and Presentation 4 by that evening and we got into the sponsor’s bash or whatever it’s called. Everything seemed to be going well and I was looking forward to a busy day 2, interested in the Day 2 Keynote.

Day 2
Day 2 keynote was a low point for me. Ben Forta did a great job, I don’t want to take that from him, but on the whole the pace was slow and we were walked through a giant horse and pony show of other people’s products when what I really wanted to see was what Adobe was bringing to the table.

Furthermore Adobe’s keynote was very focused on how they are supporting HTML5. Like day 1 I felt this very necessary and happy to hear but without a balanced message of the new Flash and AIR runtimes I felt that there was very little that spoke to me on the developer day. Walking away from the keynote I definitely felt that if I didn’t create games then the Flash Player was becoming not for me.

Nowholditrightthere!

I do know better. There is a lot of development in the pipe around Flex and AIR for many platforms. Even with just a little bit of my free time I’ve been able to create many application based on the same “core” that have received HUGE adoption numbers. These facts cannot be discounted.

Ultimately I think what happened was there was too much content and Flash/Flex got bumped for games and whatever-the-crap-that-tv-show-thing-was. The games are cool, totally cool, but how many people are creating triple A games and how many people are creating application for desktop and mobile for themselves or for clients. I left feeling that Adobe did a great job with the HTML segment and then completely talked to the >1% of high end game developers. The only thing that would have saved that is if Adobe spent all that time on games to lead up to and announced a third purchase of Unity. Then I would have completely understood the lead up.

I left the keynote pretty underwhelmed and now – except for sneaks – on the downward path towards the end of Max for 2011. No more surprises to be had.

I knocked out another presentation, missed one (sorry Ryan), gave the NerdRadio kings an interview, and finally joined in with Flash Jeopardy challenge. I’m very much hoping that a video of that is posted and soon because it was so much fun I hope others get to see it – even if I was robbed again at the end (Tony)!

Sneaks
Sneaks were awesome as always. Rainn Wilson knocked it out of the ballpark and as you probably know by now Adobe showed why they are leaders in the industry with showing off software that we only dream about.

MAX BASH
Awesome. Completely blew away last years. On par with the best ones I’ve been to. Again, great job Adobe.

Day 3
Day 3 ended strong with me starting off as a TA and ending with 2 back to back presentations. It was nice to close things up and talk with people finally and spend time in the community lounge – I barely got that time previously. I also had fun catching up with Jesse F over some breakfast between everything else – good times.

PS
Since Max many of the Evangelists have made posts saying that the message that came out was incomplete or miscommunicated. I do believe this is the truth, I just want to see the next few months to a year as proof of Adobe’s interest in application developers.

Requests

Keep the Flex and the AIR teams going the way they are.
Don’t side burner them or ship it (Flex, AIR) all overseas.
Continue to innovate with Flash and deliver stellar releases.
Support open source communities like Spoon. (SPPOOOOOONNNN!!)
Continue to use your own tools to create applications (great job with those tablet apps)
I’d like to see a cloud build system for Flex/AIR/Flash projects like PhoneGap has. (I’ve said that before and I’ll say it again)
I’d love to see “MovieClip” have it’s own file type. So designers could create animations and hand over just the “movieclip” segment to a developer to be included with a larger project. Rather than FLA files which don’t play well with repositories.

I have many more but it’s time to get back to work!

TourDeFlex – Rotten Tomatoes AS3 API

jonbcampos — Wed, 10 Aug 2011 14:18:12 +0000

Hey look at that!

I added into Tour De Flex an example of my Rotten Tomatoes AS3 API. If you are looking to pull movie details this API is VASTLY simpler to use compared to the Netflix AS3 API that I also keep up.

Hope you enjoy it! Feel free to let me know what you think!

Customizable Busy Indicator

jonbcampos — Fri, 05 Aug 2011 14:44:05 +0000

A good friend of mine, Antonio Holguin, inspired me to write this blog post when he wanted a good, customized busy indicator for a new application that he is creating – and he wanted to know what the heck I did with Queue Manager. If you’ve seen my Queue Manager application you’ve probably noticed that I have a custom busy indicator that looks like an “N” as it’s loading (Designed by Dimi Arhontidis).

In this post I’m going to show you a class that I made after studying the Flex “BusyIndicator” class. Adobe has spent a great amount of time creating a great Busy Indicator, however I didn’t feel that the BusyIndicator was easily customizable, so I changed that.

Below is my code and some implementations.

First, my custom class. The class is fairly straight forward and a slight modification of the Adobe provided BusyIndicator, however the thing that I did was add an easy way to override the shape creation function and give you two options to know where the loader is in progress, either through the selected index or the current rotation value. If you are using a circular loader then the “currentRotation” value may be better for you. For anything else the selectedIndex value may be better for you.

Use these values when you draw your symbols.

CustomizableBusyIndicator

package com.unitedmindset.components
{
import flash.display.Graphics;
import flash.events.Event;
import flash.events.TimerEvent;
import flash.utils.Timer;

import mx.core.DPIClassification;
import mx.core.DesignLayer;
import mx.core.FlexGlobals;
import mx.core.IUIComponent;
import mx.core.IVisualElement;
import mx.core.UIComponent;
import mx.events.FlexEvent;
import mx.events.PropertyChangeEvent;

/**
* The interval to delay, in milliseconds, between rotations of this
* component. Controls the speed at which this component spins.
*
* @default 50
*
* @langversion 3.0
* @playerversion AIR 2.5
* @productversion Flex 4.5
*
*/
[Style(name="rotationInterval", type="Number", format="Time", inherit="no")]

/**
* Color of the symbols of the spinner.
*
* @default 0x000000
*
* @langversion 3.0
* @playerversion AIR 2.5
* @productversion Flex 4.5
*/
[Style(name="symbolColor", type="uint", format="Color", inherit="yes", theme="spark,mobile")]

/**
* Busy Indicator with easy to customize symbols.
*
* Just override the drawSymbol() method to customize your symbols.
* Override the measure method to adjust the sizes of the
* busyindicator for different dpis. This is slightly modified code
* from the Flex framework to make the busy indicator easier to customize
* in my opinion while still being as lightweight as possible.
*
* @author jonbcampos
*
*/
public class CustomizableBusyIndicator extends UIComponent
{
//--------------------------------------------------------------------------
//
// Constructor
//
//--------------------------------------------------------------------------
public function CustomizableBusyIndicator()
{
super();

// Listen to added to stage and removed from stage.
// Start rotating when we are on the stage and stop
// when we are removed from the stage.
addEventListener(Event.ADDED_TO_STAGE, addedToStageHandler);
addEventListener(Event.REMOVED_FROM_STAGE, removedFromStageHandler);
}

//--------------------------------------------------------------------------
//
// Class constants
//
//--------------------------------------------------------------------------

/**
* @private
*/
static private const DEFAULT_ROTATION_INTERVAL:Number = 50;

/**
* @private
*/
static private const DEFAULT_MINIMUM_WIDTH_SIZE:Number = 28;
static private const DEFAULT_MINIMUM_HEIGHT_SIZE:Number = 38;

//--------------------------------------------------------------------------
//
// Variables
//
//--------------------------------------------------------------------------

/**
* @private
*/
private var effectiveVisibility:Boolean = false;

/**
* @private
*/
private var effectiveVisibilityChanged:Boolean = true;

/**
* @private
*/
private var oldUnscaledHeight:Number;

/**
* @private
*/
private var oldUnscaledWidth:Number;

/**
* @private
*/
private var rotationTimer:Timer;

/**
* Current rotation of this component in degrees.
*
* Mimicked by the selectedIndex, though in index form.
*/
protected var currentRotation:Number = 0;
/**
* Current selected index of the symbols.
*
* Mimicked by the currentRotation, though in degrees.
*/
protected var selectedIndex:int = 0;

private var _symbolQuantity:int = 1;
private var _symbolQuantityChanged:Boolean;
/**
* The fewer the symbols the less the drawing
* the faster the component.
*
* @return
*
*/
public function get symbolQuantity():int { return _symbolQuantity; }

public function set symbolQuantity(value:int):void
{
if (_symbolQuantity == value)
return;
if(value<1)
value = 1;
_symbolQuantity = value;
_symbolQuantityChanged = true;
invalidateProperties();
}

//--------------------------------------------------------------------------
//
// Private Properties
//
//--------------------------------------------------------------------------

/**
* @private
* Cache the last value of applicationDPI.
*/
private var _applicationDPI:Number;

/**
* @private
*
* Get the applicationDPI in use.
*/
private function get applicationDPI():Number
{
if (_applicationDPI)
return _applicationDPI;

var application:Object = FlexGlobals.topLevelApplication;

if ("applicationDPI" in application)
_applicationDPI = application["applicationDPI"];

return _applicationDPI;
}

//--------------------------------------------------------------------------
//
// Overridden properties: UIComponent
//
//--------------------------------------------------------------------------

/**
* @private
*/
override public function set designLayer(value:DesignLayer):void
{
super.designLayer = value;

effectiveVisibilityChanged = true;
invalidateProperties();
}

//--------------------------------------------------------------------------
//
// Overridden methods: UIComponent
//
//--------------------------------------------------------------------------

/**
* @private
*/
override protected function commitProperties():void
{
super.commitProperties();

if (effectiveVisibilityChanged)
{
// if visibility changed, re-compute them here
computeEffectiveVisibility();

if (canRotate())
startRotation();
else
stopRotation();

effectiveVisibilityChanged = false;
}

if(_symbolQuantityChanged)
{
_symbolQuantityChanged = false;
updateSymbols();
}
}

/**
* @private
*/
override protected function measure():void
{
super.measure();

// Set the default measured size depending on the
// applicationDPI
if (applicationDPI == DPIClassification.DPI_320)
{
//12x12
measuredWidth = 42;
measuredHeight = 42;
}
else if (applicationDPI == DPIClassification.DPI_240)
{
//10x10
measuredWidth = 34;
measuredHeight = 34;
}
else if (applicationDPI == DPIClassification.DPI_160)
{
//8x8
measuredWidth = 28;
measuredHeight = 28;
}
else
{
measuredWidth = DEFAULT_MINIMUM_WIDTH_SIZE;
measuredHeight = DEFAULT_MINIMUM_HEIGHT_SIZE;
}

measuredMinWidth = DEFAULT_MINIMUM_WIDTH_SIZE;
measuredMinHeight = DEFAULT_MINIMUM_HEIGHT_SIZE;
}

/**
* @private
* Override so we know when visibility is set. The initialized
* property calls setVisible() with noEvent == true
* so we wouldn't get a visibility event if we just listened
* for events.
*/
override public function setVisible(value:Boolean, noEvent:Boolean = false):void
{
super.setVisible(value, noEvent);

effectiveVisibilityChanged = true;
invalidateProperties();
}

/**
* @private
*/
override public function styleChanged(styleProp:String):void
{
super.styleChanged(styleProp);

var allStyles:Boolean = !styleName || styleName == "styleName";

// Check for skin/icon changes here.
// We could only throw out any skins that change,
// but since dynamic re-skinning is uncommon, we'll take
// the simpler approach of throwing out all skins.
if (allStyles || styleName == "rotationInterval")
{
// Update the timer if the rotation interval has changed.
if (isRotating())
{
stopRotation();
startRotation();
}
}

if (allStyles || styleName == "symbolColor")
{
updateSymbols();
}
}

/**
* @private
*/
override protected function updateDisplayList(unscaledWidth:Number, unscaledHeight:Number):void
{
super.updateDisplayList(unscaledWidth, unscaledHeight);

// If the size changed, then create a new spinner.
if (oldUnscaledWidth != unscaledWidth || oldUnscaledHeight != unscaledHeight)
{
var newDiameter:Number;

updateSymbols();

oldUnscaledWidth = unscaledWidth;
oldUnscaledHeight = unscaledHeight;

}
}

//--------------------------------------------------------------------------
//
// Methods
//
//--------------------------------------------------------------------------

/**
* @private
*
* Update the spinner properties and redraw.
*/
private function updateSymbols():void
{
var isRotating:Boolean = isRotating();

if (isRotating)
stopRotation();

drawSymbols();

if (isRotating)
startRotation();
}

/**
* Draw the spinner using the graphics property of this component.
*/
protected function drawSymbols():void
{
var g:Graphics = graphics;
g.clear();

var index:int = -1;
while(++index<symbolQuantity)
drawSymbol(index);
}

/**
* Draws the symbol, use the index to determine the position, color, etc.
*
* @param index
*
*/
protected function drawSymbol(index:int):void
{

}

/**
* @private
*/
private function startRotation():void
{
if (!rotationTimer)
{
var rotationInterval:Number = getStyle("rotationInterval");
if (isNaN(rotationInterval))
rotationInterval = DEFAULT_ROTATION_INTERVAL;

if (rotationInterval < 16.6)
rotationInterval = 16.6;

rotationTimer = new Timer(rotationInterval);
}

if (!rotationTimer.hasEventListener(TimerEvent.TIMER))
{
rotationTimer.addEventListener(TimerEvent.TIMER, timerHandler);
rotationTimer.start();
}

}

/**
* @private
*/
private function stopRotation():void
{
if (rotationTimer)
{
rotationTimer.removeEventListener(TimerEvent.TIMER, timerHandler);
rotationTimer.stop();
rotationTimer = null;
}
}

/**
* @private
*/
private function isRotating():Boolean
{
return rotationTimer != null;
}

/**
* The BusyIndicator can be rotated if it is both on the display list and
* visible.
*
* @returns true if the BusyIndicator can be rotated, false otherwise.
*/
private function canRotate():Boolean
{
if (effectiveVisibility && stage != null)
return true;

return false;
}

/**
* @private
*/
private function computeEffectiveVisibility():void
{

// Check our design layer first.
if (designLayer && !designLayer.effectiveVisibility)
{
effectiveVisibility = false;
return;
}

// Start out with true visibility and enablement
// then loop up parent-chain to see if any of them are false.
effectiveVisibility = true;
var current:IVisualElement = this;

while (current)
{
if (!current.visible)
{
if (!(current is IUIComponent) || !IUIComponent(current).isPopUp)
{
// Treat all pop ups as if they were visible. This is to
// fix a bug where the BusyIndicator does not spin when it
// is inside modal popup. The problem is in we do not get
// an event when the modal window is made visible in
// PopUpManagerImpl.fadeInEffectEndHandler(). When the modal
// window is made visible, setVisible() is passed "true" so
// as to not send an event. When do get events when the
// non-modal windows are popped up. Only modal windows are
// a problem.
// The downside of this fix is BusyIndicator components that are
// inside of hidden, non-modal, popup windows will paint themselves
// on a timer.
effectiveVisibility = false;
break;
}
}

current = current.parent as IVisualElement;
}
}

/**
* @private
* Add event listeners for SHOW and HIDE on all the ancestors up the parent chain.
* Adding weak event listeners just to be safe.
*/
private function addVisibilityListeners():void
{
var current:IVisualElement = this.parent as IVisualElement;
while (current)
{
// add visibility listeners to the parent
current.addEventListener(FlexEvent.HIDE, visibilityChangedHandler, false, 0, true);
current.addEventListener(FlexEvent.SHOW, visibilityChangedHandler, false, 0, true);

current = current.parent as IVisualElement;
}
}

/**
* @private
* Remove event listeners for SHOW and HIDE on all the ancestors up the parent chain.
*/
private function removeVisibilityListeners():void
{
var current:IVisualElement = this;
while (current)
{
current.removeEventListener(FlexEvent.HIDE, visibilityChangedHandler, false);
current.removeEventListener(FlexEvent.SHOW, visibilityChangedHandler, false);

current = current.parent as IVisualElement;
}
}

//--------------------------------------------------------------------------
//
// Overridden event handlers: UIComponent
//
//--------------------------------------------------------------------------

/**
* @private
*/
override protected function layer_PropertyChange(event:PropertyChangeEvent):void
{
super.layer_PropertyChange(event);

if (event.property == "effectiveVisibility")
{
effectiveVisibilityChanged = true;
invalidateProperties();
}
}

//--------------------------------------------------------------------------
//
// Event Handlers
//
//--------------------------------------------------------------------------

/**
* @private
*/
private function addedToStageHandler(event:Event):void
{
// Check our visibility here since we haven't added
// visibility listeners yet.
computeEffectiveVisibility();

if (canRotate())
startRotation();

addVisibilityListeners();
}

/**
* @private
*/
private function removedFromStageHandler(event:Event):void
{
stopRotation();

removeVisibilityListeners();
}

/**
* @private
* Event call back whenever the visibility of us or one of our ancestors
* changes
*/
private function visibilityChangedHandler(event:FlexEvent):void
{
effectiveVisibilityChanged = true;
invalidateProperties();
}

/**
* @private
*
* Rotate the spinner once for each timer event.
*/
private function timerHandler(event:TimerEvent):void
{
currentRotation += 360/symbolQuantity;
selectedIndex++;
if (currentRotation >= 360)
{
currentRotation = 0;
selectedIndex = 0;
}

drawSymbols();
event.updateAfterEvent();
}
}
}

Next we need to customize and subclass the CustomizableBusyIndicator by overriding the drawSymbol method. Below are two examples of the customized busy indicator. The first I modeled after the Nintendo DS Loader – I was just playing Zelda, it’s all I could come up with.

The second is modeled after another loader I’ve seen, can’t remember where.

Customizing is easy and best of all the loader has been performance optimized. So you can create something custom is with the mental security you’re not screwing anything up.

Busy Indicators

DS Loader

package com.unitedmindset.components
{
import flash.display.Graphics;

/**
* Busy Indicator modeled after the Nintendo DS Busy Indicator.
*
* @author jonbcampos
*
*/
public class DSBusyIndicator extends CustomizableBusyIndicator
{
public function DSBusyIndicator()
{
super();
//the quantity of symbols for this indicator.
//8 squares
symbolQuantity = 8;
}

private var _symbolPadding:Number = 2;
private var _symbolWidth:Number = 0;
private var _symbolHeight:Number = 0;

/**
* Measures and sets size based on DPI.
*/
override protected function measure():void
{
//use the default sizes.
//I could also make different
//sizes for my component by overriding.
super.measure();

//I only want to make this
//calculation when the measurement
//changes, but it isn't super
//necessary here. I would put it in the
//drawSymbols method.
_symbolHeight = (measuredHeight - (_symbolPadding*2)) / 3;
_symbolWidth = (measuredWidth - (_symbolPadding*2)) / 3;
}

/**
* Kick starts drawing all the individual symbols.
*/
override protected function drawSymbols():void
{
super.drawSymbols();

var symbolColor:uint = getStyle("symbolColor") as uint;

//make center square
var g:Graphics = graphics;
g.beginFill(symbolColor, 1);
var centerX:Number = (measuredWidth - _symbolWidth)/2;
var centerY:Number = (measuredHeight - _symbolHeight)/2;
g.drawRect(centerX, centerY, _symbolWidth, _symbolHeight);
g.endFill();
}

/**
* Draws one symbol.
*
* @param index The index shows which symbol in the matrix you are making.
* This value is arbitrary and you can layout your symbols however you want
* in whatever index order you want.
*
*/
override protected function drawSymbol(index:int):void
{
var _alpha:Number = 1;
var _posX:Number = 0;
var _posY:Number = 0;

var _alpha1:Number = 0.4;
var _alpha2:Number = 0.6;

switch(index)
{
case 0: //top left
//set alpha if it is the selected symbol
if(selectedIndex==0)
_alpha = _alpha1;
else if(selectedIndex==7)
_alpha = _alpha2;
else
_alpha = 1;
//position symbol
//default pos
break;
case 1: //top center
//set alpha if it is the selected symbol
if(selectedIndex==1)
_alpha = _alpha1;
else if(selectedIndex==0)
_alpha = _alpha2;
else
_alpha = 1;
//position symbol
_posX = _symbolWidth + _symbolPadding;
break;
case 2: //top right
//set alpha if it is the selected symbol
if(selectedIndex==2)
_alpha = _alpha1;
else if(selectedIndex==1)
_alpha = _alpha2;
else
_alpha = 1;
//position symbol
_posX = _symbolWidth*2 + _symbolPadding*2;
break;
case 3: //mid right
//set alpha if it is the selected symbol
if(selectedIndex==3)
_alpha = _alpha1;
else if(selectedIndex==2)
_alpha = _alpha2;
else
_alpha = 1;
//position symbol
_posX = _symbolWidth*2 + _symbolPadding*2;
_posY = _symbolHeight + _symbolPadding;
break;
case 4: //bottom right
//set alpha if it is the selected symbol
if(selectedIndex==4)
_alpha = _alpha1;
else if(selectedIndex==3)
_alpha = _alpha2;
else
_alpha = 1;
//position symbol
_posX = _symbolWidth*2 + _symbolPadding*2;
_posY = _symbolHeight*2 + _symbolPadding*2;
break;
case 5: //bottom center
//set alpha if it is the selected symbol
if(selectedIndex==5)
_alpha = _alpha1;
else if(selectedIndex==4)
_alpha = _alpha2;
else
_alpha = 1;
//position symbol
_posX = _symbolWidth + _symbolPadding;
_posY = _symbolHeight*2 + _symbolPadding*2;
break;
case 6: //bottom left
//set alpha if it is the selected symbol
if(selectedIndex==6)
_alpha = _alpha1;
else if(selectedIndex==5)
_alpha = _alpha2;
else
_alpha = 1;
//position symbol
_posY = _symbolHeight*2 + _symbolPadding*2;
break;
case 7: //mid left
//set alpha if it is the selected symbol
if(selectedIndex==7)
_alpha = _alpha1;
else if(selectedIndex==6)
_alpha = _alpha2;
else
_alpha = 1;
//position symbol
_posY = _symbolHeight + _symbolPadding;
break;
}
//get the symbol style color
var symbolColor:uint = getStyle("symbolColor") as uint;
//with all my positions determined,
//now actual draw the graphic
var g:Graphics = graphics;
g.beginFill(symbolColor, _alpha);
g.drawRect(_posX, _posY, _symbolWidth, _symbolHeight);
g.endFill();
}
}
}

Other Loader

package com.unitedmindset.components
{
import flash.display.Graphics;

/**
* Busy Indicator modeled after ?.
* @author jonbcampos
*
*/
public class CirclesBusyIndicator extends CustomizableBusyIndicator
{
public function CirclesBusyIndicator()
{
super();
//the quantity of symbols for this indicator.
//6 circles
symbolQuantity = 6;
//make it just a bit slower
//you could also adjust the
//speed by setting the style on
//the component instance.
setStyle("rotationInterval", 100);
}

private var _symbolWidth:Number = 0;
private var _symbolHeight:Number = 0;
private var _radius:Number = 0;

/**
* Measures and sets size based on DPI.
*/
override protected function measure():void
{
//use the default sizes.
//I could also make different
//sizes for my component by overriding.
super.measure();

//I only want to make this
//calculation when the measurement
//changes, but it isn't super
//necessary here. I would put it in the
//drawSymbols method.
_symbolHeight = measuredHeight/3;
_symbolWidth = measuredWidth/3;
_radius = measuredWidth / 7;
}

/**
* Draws one symbol.
*
* @param index The index shows which symbol in the matrix you are making.
* This value is arbitrary and you can layout your symbols however you want
* in whatever index order you want.
*
*/
override protected function drawSymbol(index:int):void
{
var _alpha:Number = 1;
var _posX:Number = 0;
var _posY:Number = 0;

//if the selected index
//is the index we are drawing
//set it's alpha lower
if(index==selectedIndex)
_alpha = 0.5;

switch(index)
{
case 0: //top left
_posX = measuredWidth / 3;
_posY = measuredHeight / 6;
break;
case 1: //top right
_posX = measuredWidth - _symbolWidth;
_posY = measuredHeight / 6;
break;
case 2: //mid right
_posX = (measuredWidth + measuredWidth/6) - _symbolWidth;
_posY = measuredHeight / 2;
break;
case 3: //bottom right
_posX = measuredWidth - _symbolWidth;
_posY = (measuredHeight + measuredHeight/6) - _symbolHeight;
break;
case 4: //bottom left
_posX = measuredWidth / 3;
_posY = (measuredHeight + measuredHeight/6) - _symbolHeight;
break;
case 5: //mid left
_posX = measuredWidth / 6;
_posY = measuredHeight / 2;
break;
}
//get the symbol style color
var symbolColor:uint = getStyle("symbolColor") as uint;
//with all my positions determined,
//now actual draw the graphic
var g:Graphics = graphics;
g.beginFill(symbolColor, _alpha);
g.drawCircle(_posX, _posY, _radius);
g.endFill();
}
}
}

Speaking at MAX 2011

jonbcampos — Thu, 28 Jul 2011 20:24:54 +0000

I’m excited to again be fortunate enough to present at Adobe Max 2011.

If you are interested in learning about Mobile Applications I will be giving a the first half of a 2 part lab in conjunction with Asfusion!

We will start with the application basics and go as far as using custom Native Extensions and Density Aware skins. It’s quite a learning event.

If you haven’t signed up for Adobe Max, do it now!

Make sure to sign up for the labs, they are filling up very quickly!
(First Presentation) Lab, Tuesday at 8am
(Second Presentation) Lab, Wednesday at 4pm

The same content will be shown at each of these labs. The 2nd half presentation presented by Asfusion hasn’t had it’s times set yet, keep watching out for it!

Queue Manager on iOS

jonbcampos — Fri, 15 Jul 2011 19:02:20 +0000

Today I’m releasing my Netflix Queue Manager for the iOS. Thanks to Adobe AIR the process to make this shift from other platforms was very simple. I’m excited to make this announcement and release.

Current State
If you are wondering if I feel the app is complete then the answer is NO! This is a work in progress and I hope you keep updating as I continue to make the app better. Right now I am trying to get through the bare minimum requirements, as I see them. Such as:
- viewing queues
- updating queues
- add/remove/view movies
- update movies queue positions

QueueManager on Nook

jonbcampos — Sat, 02 Jul 2011 22:07:38 +0000

Today I’m releasing my Netflix Queue Manager for the Nook. Thanks to Adobe AIR the process to make this shift from Android was very simple. I’m excited to make this announcement and release.

Making It Mobile – 360Flex Preso

jonbcampos — Mon, 18 Apr 2011 16:34:55 +0000

I was fortunate enough to present last week at 360Flex with good friend Antonio Holguin about how to make a mobile application. Our format of the back and forth designer/developer workflow was an experiment but one that most people seemed to enjoy.

Below are our slides, feel free to ask questions about the presentation.

Making it mobile_360_flex_jonathancampos_antonioholguin

View more presentations from AntonioHolguin

360Flex: Red Carpet Rumble

jonbcampos — Mon, 11 Apr 2011 07:00:05 +0000

This is the application created by Antonio Holguin and myself for our 360Flex presentation.

This app is a “semi” playable version of the game we are creating tentatively called “Red Carpet Rumble”.

If you have an Android device you can use this link to get the game.

Disclaimer: By no means do we feel that this application is completely done. Yes, we have the full intention of continuing to work on this game and get it out. If you have comments feel free to let us know.