perlめも

Perl Memo Index

2100-01-01T22:43:00.000+09:00

■変数
□ハッシュ関係のメモ
・配列からハッシュを作成する

□リファレンス
・リファレンスのメモ

■ファイル操作
・実行時スクリプトのパスを取得
⇒FindBin
・再帰的にパスを取得する
⇒File::FInd
・複数階層のファイルを作成、削除
⇒File::Path

■DB操作
・DBI

■日付操作
・日付全般の操作について
⇒Time::Piece

■文字列操作
・マルチバイと文字列の文字列操作のお話
⇒utf8, Encode, binmode

・形態素解析
⇒WebService::YahooJapan::WebMA

■設定ファイル
・Config::SImple
・リファレンス + do

■エラー処理
・エラー情報は、発生行？呼出し行 warn/die or carp/croak

■フレームワーク
・Mojolicious、 Mojolicious::Lite

■他
・perlの変更点が知りたい時
・ワンライナー
・特殊変数

DBI

2013-10-27T21:24:00.001+09:00

まずは、接続と切断から試してみる
SQLiteを使うので、DBIとDBD::SQLiteがインストールされていること
<参考>
DBI [ver1.628]
DBD::SQLite [ver1.40]

覚えること

No	メソッド	解説
1	connect	DBに接続
1	disconnect	DBと切断
2	do	SQLを実行
	prepare	SQLを準備
	execute	SQLを実行
	prepare_cached	準備した結果をcacheする
3	fetch	配列のリファレンスを返す
	fetchrow_arrayref	配列のリファレンスを返す
	fetchrow_hashref	列をキーに値をリファレンスで返す

■1.connect, disconnectメソッド

use strict;
use warnings;
use utf8;
use DBI;
use feature 'say';

my $database   = ':memory:';
my $connectStr = "dbi:SQLite:dbname=$database";
my $userName   = "";
my $passWord   = "";

#接続
my $dbh        = DBI->connect($connectStr,
                              $userName,
                              $passWord,
                              {RaiseError => 1,
                               PrintError => 0,
                               AutoCommit => 1});
#切断
$dbh->disconnect();

[第一引数]接続するための文字列は、

[SQLite]	dbi:SQLite:DB名
[MySQL]	dbi:mysql:DB名
[PostgreSQL]	dbi:pg:DB名
[Oracle]	dbi:oracle:DB名

尚、SQLiteはメモリ上にDBを作ることができ上記のように
:memory:と記載するとメモリ上に作成します。
当然ながら、プログラムが終了したら消えます。
サンプルコード等のお試しに最適です。

[第二引数]username
[第三引数]password
SQLiteではユーザー名、パスワードがないので、空文字のままにしています。
他のDBでは設定します。

[第四引数]オプション
ここは、いろいろあるのでDBIを参照するのがよいと思います。
http://search.cpan.org/search?query=DBI&mode=all

よく登場するオプションもメモ。
□RaiseError[デフォルト:偽]
エラーが発生すると自動的にdieして終了してくれます。
これを真にしないのであれば、各メソッド毎にエラー処理を書く必要があります。

□PrintError[デフォルト:真]
エラー時warnで出力してくれる機能。
デフォルトで真だけど、RaiseErrorを真にするのであれば
表示内容がかぶるのでこちらは偽にしておく。

□AutoCommti[デフォルト：真?]
全ての命令毎にCommitします。
ドライバによって、デフォルト値が異なるようですので明示的に指定した方がよいようです。

AutoCommitが真の時、
一つの命令毎にCommitされるため
トランザクションできなくなります。
トランザクションを行いたい時は、明示的に指示をします。

#ここまでAutoCommitエリア

#ここからトランザクション開始
$dbh->begin_work;
#何かしらの処理
$dbh->commit(); or $dbh->rollback();
#トランザクション区間終了

#ここからAutoCommitエリア

オプションに関しては、他にも必要とするのがあるのですが
まずは、DBの操作について話した後でないと検証ができないので
のちほどあらためて掲載します。

■2.do, prepare, execute, prepare_cached
□doメソッド

my $sql = "INSERT INTO sample (col1, col2) VALUES (?, ?)";
my @data = qw(data1 data2);
my $sth = $dbh->do($sql, undef, @data);

・ステートメントハンドルを作成しないため、SELECT文のように値を取得する場面では使えません。
・ステートメントハンドルを生成しない分、高速に動きます。
・INSERT, UPDATE, DELETEなどなど

□prepare, executeメソッド

my $sql = "SELECT * FROM sample WHERE col1 = ? AND col2 = ?";
my $sth = $dbh->prepare($sql);
my @data = qw(data1 data2);
my $rv = $sth->execute(@data);

・事前に準備(prepare)するため、何度もINSERTする際などループの外でprepareしておけば
その分高速に動きます。つまり、繰り返し同じSQLを実行する場合prepareしておけばよいということです。

□prepare_cachedメソッド
prepareした物を内部でハッシュに紐づけてキャッシュします。
ループ分のように連続して使用するのでなく、別の関数等で再び利用する場合
キャッシュしておけば、prepareの行為を省略できるのでその分だけ高速になります。
あちこちで同じSQLを使用するのであればキャッシュして使いましょう。

■3.fetch, fetchrow_arrayref, fetchrow_hashref
□fetch, fetchrow_arrayref

my $sql = "SELECT * FROM sample";
my $sth = $dbh->prepare($sql);
my $rv  = $sth->execute();

while (my $row = $sth->fetch()){
 my ($col1, $col2, col3) = @{$row};
 #処理
}

fetchとfetchrow_arrayrefは同じ結果となります。
つまり、配列のリファレンスを返してくれます。

□fetchrow_hashref

my $sql = "SELECT * FROM sample";
my $sth = $dbh->prepare($sql);
my $rv  = $sth->execute();

while (my $row = $sth->fetchrow_hashref()){
    say $row->{'col1'};
    say $row->{'col2'};
    say $row->{'col3'};
}

■DBI->connectのオプションについて
他のオプションについても紹介しときます。
□ShowErrorStatement
エラーとなったSQLを出力します。
通常、行数しか表示されないためその行まで移動しないと何が原因かわからないところを
SQLを表示するので何でエラーとなったか把握しやすくなります。

□DBから受け取る時、内部表現にしてくれる
MySQL→ mysql_enable_utf8
SQLite→ sqlite_unicode
PostgresSQL → pg_enable_utf8

出力時自動的に内部表現から戻す処理になっているのであれば
DBから受け取る際に内部表現にしとく必要がありますよね。。
その時に役立ちます。

■サンプルコード
地名を５つほど登録して出力するプログラムです。

use strict;
use warnings;
use utf8;
use DBI;
use feature 'say';
binmode STDOUT, ":utf8";

my $database   = ':memory:';
my $connectStr = "dbi:SQLite:dbname=$database";
my $userName   = "";
my $passWord   = "";
my $sql        = "";
my $dbh        = DBI->connect($connectStr,
         $userName,
         $passWord,
         {RaiseError => 1, 
          PrintError => 0, 
          AutoCommit => 1,
          sqlite_unicode => 1
         });
#CreateTable & InsertData
initialize($dbh);

$sql = "SELECT * FROM test";
my $sth = $dbh->prepare($sql);
my $rv  = $sth->execute();

#arrayrefで受け取る場合
#$sth->fetchrow_arrayref()
#$sth->fetch()は、同じメソッド
while (my $row = $sth->fetch()){
 my ($id, $area) = @{$row};
 say "$id:$area";
}

$sth->finish();
$dbh->disconnect();

sub initialize{
 my $dbh = shift;
    
    #テーブルを作成(idとstrの列のみ)
 my $sql = "CREATE TABLE IF NOT EXISTS test(id INTEGER PRIMARY KEY AUTOINCREMENT, area TEXT)";
 $dbh->do($sql);
 
    #str列に名前を登録
 my @list = qw(興部 椴法華村 音威子府 長万部 札幌);
 $sql = "INSERT INTO test (area) VALUES(?)";
 
 for my $area (@list){
  $dbh->do($sql, undef, $area);
 }
}

エラー情報は、発生行？呼出し行 warn/die or carp/croak

2013-08-18T01:00:00.001+09:00

まずは、Debugモジュールを作成し、Printするメソッドを定義します。
ただし、Printする文字列がない時つまり引数が渡されなかったらエラーで終了としましょう！

use strict;                                                                              
use warnings;
use utf8;
use feature 'say';
binmode STDOUT, ":utf8";
binmode STDERR, ":utf8";

my $obj = Debug->new();
say $obj->Print("abc");
say $obj->Print("def");
say $obj->Print();
say $obj->Print("ghi");

package Debug;

sub new{                                                                                  
    return bless {}, shift;
}

sub Print{
    my ($self, $str) = @_;
    if (@_!=2){ die("引数を一つだけ指定してください") };

    return $str;
}

これを実行するとエラーで落ちます。

abc
def
引数を一つだけ指定してください at sample.pl line 22.

確かにエラーが発生した行の情報が表示されていて
これはこれで正しいのですが、あちこちから呼ばれる、データがトリガーとなって
エラーとなるケースでは呼び出しもとがどこなのか知りたいですよね。
つまり、呼び出しもとの行数を知りたい。
そんな時は、Carpモジュール。

use strict;                                                                              
use warnings;
use utf8;
use feature 'say';
binmode STDOUT, ":utf8";
binmode STDERR, ":utf8";

my $obj = Debug->new();
say $obj->Print("abc");
say $obj->Print("def");
say $obj->Print();
say $obj->Print("ghi");

package Debug;
use Carp;

sub new{                                                                                  
    return bless {}, shift;
}

sub Print{
    my ($self, $str) = @_;
    if (@_!=2){ croak("引数を一つだけ指定してください") };

    return $str;
}

実行結果：

abc
def
引数を一つだけ指定してください at sample.pl line 11.

引数を一つだけ指定してください。といわれ11行を確認すると
say $obj->Print();
ならば修正するのも楽ですね。

warnの代わりはcarpで
dieの代わりはcroakとなっています。

ロジックに問題の可能性があればwarnやdieを使い
呼び出し元がトリガーとなる場合carpやcroakを適宜使い分ければよいと思います。

マルチバイと文字列の文字列操作のお話

2013-08-17T11:44:00.000+09:00

"abc"という文字列が何文字か調べてみましょう。

use strict;
use warnings;
use feature 'say';

my $str = "abc";
say $str. "は、". length($str). "文字です";

実行結果：

abcは、3文字です

問題ありませんね。
では、"あいうえお"が何文字か調べてみましょう。

use strict;
use warnings;
use feature 'say';

my $str = "abc";
say $str. "は、". length($str). "文字です";

実行結果：

あいうえおは、15文字です

はい、15文字ですn…
えぇぇぇぇぇ。それ困ります。

このようにマルチバイト文字列の場合見た目の文字数通りカウントできないため
文字列操作で文字数を絡める場合問題となります。
そのため、見た目の文字数と一致させるためには、
プログラム内部で使用する"内部文字列"という表現に変換してあげる必要があります。

use strict;
use warnings;
use feature 'say';
use utf8;

my $str = "あいうえお";
say $str. "は、". length($str). "文字です";

簡単です。use utf8;とつけただけです。

実行結果：

Wide character in say at t.pl line 7.
あいうえおは、5文字です

５文字と表示されているので正しくカウントされました。
ただ、Wide character in say 〜　としかられました。
これは、何かというと、プログラム内部で扱う文字表現のまま出力するとおこられるのです。
perlの場合互換性を大事にされているので昔のプログラムもそのまま動くように配慮されているため
バージョンがあがってから追加された機能はいろいろ一手間加えてあげないといけないわけです。

そんなわけで一手間加えてみます。

use strict;
use warnings;
use feature 'say';
use utf8;
binmode STDOUT, ":utf8";

my $str = "あいうえお";
say $str. "は、". length($str). "文字です";

binmode STDOUT, ":utf8";
を追加しました。
ターミナルへの出力(いわゆる標準出力)の際に問題となっているので
binmode STDOUTで標準出力を行うもの全てに対し処理が加えられます。
そして、ターミナルはutf8の文字列を受け付けているので:utf8として出力しています。
単純ですね。

内部文字列表現かそうじゃないかは、ぱっとみわからないので判断しづらいかもしれませんが
ともかく、perlに文字列を渡す時に内部文字列に変換して外に出す時に元に戻すということをすればよいわけです。

ここまでのまとめ

次。
エラー処理をしたい時warnやdieを使うと思いますが

use strict;
use warnings;
use feature 'say';
use utf8;
binmode STDOUT, ":utf8";

warn("警告");
die("すっごい致命的なんです");

実行結果：

Wide character in warn at t.pl line 7.
警告 at t.pl line 7.
Wide character in die at t.pl line 8.
すっごい致命的なんです at t.pl line 8.

出ました！！
エラー系は標準出力と異なるため、STDOUTでは太刀打ちできません。

use strict;
use warnings;
use feature 'say';
use utf8;
binmode STDOUT, ":utf8";
binmode STDERR, ":utf8";

warn("警告");
die("すっごい致命的なんです");

binmode STDERR, ":utf8";
標準エラーを追加しました。

実行結果：

警告 at t.pl line 8.
すっごい致命的なんです at t.pl line 9.

いい感じですね。
まとめです。

さて、他に考えられるI/Oは…
標準入力を考えてみましょう

se strict;
use warnings;
use feature 'say';
use utf8;
binmode STDOUT, ":utf8";
binmode STDERR, ":utf8";

chomp(my $input = );
say $input;

"あいうえお"って入力すると・・・

実行結果：

あいうえお
ãã

文字化けを起こしました。
何が起きているか確認してみましょう。

現時点で、外からやってきた文字列は内部の文字列表現になっていません。
それにもかかわらず、binmode STDOUT, ":utf8";があるため
文字列の出力の際に、内部表現だという前提で変換しているため、
おかしなことになったわけです。

もうすでに対策は薄々気づけそうですが

use strict;
use warnings;
use feature 'say';
use utf8;
binmode STDIN,  ":utf8";
binmode STDOUT, ":utf8";
binmode STDERR, ":utf8";

chomp(my $input = );
say $input;

binmode STDIN, ":utf8";
を追加しました

実行結果：

あいうえお
あいうえお

理由がわかれば、簡単ですね。

今度はファイルからのよみこみ書き込みを行ってみます。
まずは読み込み

use strict;
use warnings;
use feature 'say';
use utf8;
binmode STDIN,  ":utf8";
binmode STDOUT, ":utf8";
binmode STDERR, ":utf8";

open my $fh, '<', 'string.txt' or die "$!";
say <$fh>;
close $fh;

尚、string.txt には　あいうえお　と記載されているだけです。
１行取得して出力した結果は以下の通りです。

実行結果：

ãã

また文字化けです。
当然ながら、perlに渡す前に内部表現に変換していないからです。
対応してみます。

use strict;
use warnings;
use feature 'say';
use utf8;
binmode STDIN,  ":utf8";
binmode STDOUT, ":utf8";
binmode STDERR, ":utf8";

open my $fh, '<:encoding(utf8)', 'string.txt' or die "$!";
say <$fh>;
close $fh;

'<' から '<:encoding(utf8)' へ変更しています。 string.txt はutf8で保存されています。実行結果：



あいうえお

うまくいきました。
ファイルで書き込みを行う時も同じ操作になります。
'>:encoding(utf8)' と言った感じです。

残すは、他のソースコードとのやり取りですね。
つまり、他のモジュールへ文字列を渡したり受け取ったりする時です。
これは、モジュールごとに内部表現で渡すべきか、そうじゃないかは対応がまちまちなので
実際に試してみない限りなんとも言えません。
ケースバイケースで対応しましょ。
内部表現にしたい時は、use Encode; を使い decode_utf8('文字列')
内部表現からもとに戻す時は、use Enocde;を使いencode_utf8('文字列')
とすればよいです。

なお、encode_utf8 はenocde('utf8', '文字列') 別の書き方です。
違うエンコードの時は、encode('文字コード', '文字列')
decode('文字コード', '文字列')としてください。

最後のまとめです。
INとOUTで分けておきました。
これさえ注意すればなんとかなりますね。

基本的な考えとして、use utf8は必ずつける。
外から受け取る時は内部表現に変更する
外へ出す時は、内部表現をやめる
モジュール間でやりとりするときは、そのまま(内部表現)でやりとりする
という感じでよいのではないでしょうか？

リファレンス+do

2013-08-16T14:29:00.000+09:00

ただ読み込むだけのもっとも簡単な設定ファイルの仕組みが欲しいのであれば
ファイルに直接リファレンスを書き込みそれをdoしてperlとして解釈するのが一番簡単。

まずは設定ファイルを作成する
ファイル名：config

database = 'fizz'
user     = 'bazz'
pass     = 'fizzbazz'

ファイル名：Sample.pl

use strict;
use warnings;
use utf8;  
use feature 'say';
binmode STDOUT, ":utf8";
use Dumpvalue; my $d = Dumpvalue->new();

my $configFile = 'config';
my $config = do $configFile or die "$!";

say $config->{database};
say $config->{user};
say $config->{pass};

$d->dumpValue($config);

実行結果：

fizz
bazz
fizzbazz
'database' => 'fizz'
'pass' => 'fizzbazz'
'user' => 'bazz'

個人でさくっと読み込みのみの気軽な物が・・・
となるとこれが一番ですかね。

Config::Simple

2013-08-16T13:34:00.000+09:00

■簡単な設定ファイルを操作するモジュール

まずは設定ファイルを作成する
ファイル名：config

database = 'fizz'
user     = 'bazz'
pass     = 'fizzbazz'

ファイル名：Sample.pl

use strict;
use warnings;
use utf8;
use feature 'say';
use Config::Simple;
binmode STDOUT, ":utf8";

my $config = Config::Simple->new('./config');
say $config->param('database');
say $config->param('user');
say $config->param('pass');

実行結果：

fizz
bazz
fizzbazz

new する時に、ファイルパスを指定し、その後paramメソッドで値を取得することができるようです

ちょっとした物を記録しておき使うのであればこんな感じでよさそうですね。
ただ、同一のキー名を使用したい場合はセクションで区切ることで使い分けができます。
ファイル名：config

[001]
database = 'db001'
user     = 'user001'
pass     = 'pass001'

[002]
database = 'db002'
user     = 'user002'
pass     = 'pass002'

use strict;
use warnings;
use utf8;
use feature 'say';
use Config::Simple;
binmode STDOUT, ":utf8";

my $config = Config::Simple->new('./config');

say $config->param("001.database");
say $config->param("002.database");

実行結果：

db001
db002

今度は、paramメソッドで[セクション名].[キー名]を指定することで値にアクセスできます。

ちなみに、ハッシュ化することも可能で
オブジェクト->vars();　とすればできます。

use strict;
use warnings;
use utf8;  
use feature 'say';
use Config::Simple;
binmode STDOUT, ":utf8";
use Dumpvalue; my $d = Dumpvalue->new();

my $config = Config::Simple->new('./config01');
my $hash   = $config->vars();
$d->dumpValue($hash);

say $hash->{'001.user'};                                                           
say $hash->{'002.user'};

実行結果：

'001.database' => 'db001'
'001.pass' => 'pass001'
'001.user' => 'user001'
'002.database' => 'db002'
'002.pass' => 'pass002'
'002.user' => 'user002'
user001
user002

param関数とかじゃなくて、一発でハッシュに放り込んでくれると便利そうですね。
ということで他のConfig系のモジュールも探してみよう。

perlの変更点が知りたい時

2013-08-14T23:22:00.001+09:00

perldoc.jpに翻訳されたものがあるのでそちらを見るとよいと思います。

自分もあれって何のバージョンから変更されたっけ？？
となるので、たまに参照します。
ということで、おもだったとこのリンクでもはっておきます。

perl v5.18.0 での変更点
→5.16.0 リリースと 5.18.0 リリースの変更点

perl v5.16.0 での変更点
→5.14.0 リリースと 5.16.0 リリースの変更点

perl v5.14.0 での変更点
→5.12.0 リリースと 5.14.0 リリースの変更点

perl v5.12.0 での変更点
→5.10.0 リリースと 5.12.0 リリースの変更点

perl 5.10.0 での変更点
→5.8.8 リリースと 5.10.0 リリースとでの相異点

ラクダ本や、リャマ本を読んでようやく、スタートラインにたち、
ネットから最新情報を取得してがんばろう！
とした矢先に　あれ？この記述なんだ？？
みたいなことはよくあるものですよね。
おまけに、ググラビリティが低くて見つかりにくいのです…
そんなわけで、気になったものを簡単に羅列してみます。

■+{} 波括弧の前のプラス
波括弧には、
関数を囲うためとハッシュのリファレンスの２通り使われるため
perlにこれはハッシュのリファレンスのための波括弧なんですよ。
ってことを知らせるために、+{}としている

■use 5.010; or use feature ':5.10'; or use feature 'say'

print "値¥n";
とした場合、いちいち改行文字なんぞくっつけていたと思いますが
say "値";
say関数であれば、改行文字を自動的にくっつけてくれる便利さんなんです。
という話をどこかでみかけたと思います。
そして、say関数を使うにはどうすればよいの？
とあちこち眺めてみると上記の記述にでくわすわけです。

use feature 'say';
は、5.10で追加になったsayという関数のみ使えるようにする記述の仕方

use feature ':5.10';
は、5.10で追加になった機能すべて使えるようにする記述

use 5.0.10;
は、5.10で追加になった機能すべて使えるようにして
かつそれ未満のバージョンのperlで実行しようとしたらすぐにエラーとなり停止させれます。

つまり、明示的にsayって関数だけがつかいたいだけなんですよ！！
他、あるかしらんしー
sayだけあれば幸せだしー
という場合は、use feature 'say';
とかけば、他の人が読んでも他のものはつかっていないことがはっきりします。

ただ、5.12以降を指定すると use strictしたのと同等になり
いちいちuse strict;　と書かなくてすむので
use 5.0.12; のように記述するのを好む人もいると思います。

という感じですかね。

その２　ルートについて

2012-09-14T01:00:00.001+09:00

■ルートの指定
まずは、ヘルパースクリプトを使ってルートの確認

#!/usr/bin/env perl                                                                                       
use Mojolicious::Lite;

# Documentation browser under "/perldoc"                                                                  
plugin 'PODRenderer';

get '/' => sub {
  my $self = shift;
  $self->render('index');
};

app->start;
__DATA__

@@ index.html.ep
% layout 'default';
% title 'Welcome';
Welcome to the Mojolicious real-time web framework!

@@ layouts/default.html.ep


  <%= title %>
  <%= content %>

該当部分は、以下のコードですね
get '/' => sub{};

1.静的パス
get '/foo/bar/baz1' => sub {shift->render(text=>'/foo/bar/baz1'};
get '/foo/bar/baz2' => sub {shift->render(text=>'/foo/bar/baz2'};
get '/foo/bar/baz3' => sub {shift->render(text=>'/foo/bar/baz3'};

http://localhost:3000/foo/bar/baz1
http://localhost:3000/foo/bar/baz2
http://localhost:3000/foo/bar/baz3
それぞれにアクセスしたら
/foo/bar/baz1
/foo/bar/baz2
/foo/bar/baz3
と表示されます

2.動的パス
実際のところ、静的なパスより動的なパスの方が多いと思うので
一番最後のパスは動的に変わるとしたら…

get '/foo/bar/:baz' => sub{
  my $self = shift;
  my $baz  = $self->param('baz');
  $self->render(text => '/foo/bar/' . $baz);
};

:名前　は、ドットとスラッシュ以外の全てにマッチします。
そして、shift->param('名前')で値を取り出せます。

ただ、静的パスの例のようにbaz+数字にヒットさせたい場合
上記の方法では、それ以外のパターンもヒットするので困ります。
こういった場合、正規表現を指定することで解決できます。

get '/foo/bar/:baz' => [baz => qr/baz\d+/] => sub{                                                        
  my $self = shift;
  my $baz  = $self->param('baz'); #stashにも登録されている $self->stash('baz')
  $self->render(text => '/foo/bar/' . $baz);
};

ルートの指定についてはいろいろあり紹介しきれないので
こちらを参照するとよいと思います。
Mojolicious::Lite

■パラメータの取得
get/postどちらもparamメソッドを使えば取得できます。
[getの場合]
shift->param("Query名");
[postの場合]
shift->param("Name属性名");

getの参考例

get '/get' => sub{
  my $self = shift;
  my $date = $self->param("date");
  $self->render_text("Date:" . $date);
};

http://localhost:3000/get?date=20121203
にアクセスすると
Date:20121203
と表示されます。

チェックボックスの値など複数の値が帰ってくる場合は
配列変数で受け取ればよいです。
また、引数を省略すると全てのパラメータ名が帰ってきます。

Mojolicious::Liteへ戻る

Mojolicious

2012-09-13T22:58:00.001+09:00

■メモ。
その１　てっとり早く動かしてみる

その２　ルートについて

$self->app->log->debug()
$self->app->log->error()
$self->app->log->fatal()
$self->app->log->info()
$self->app->log->warn()

$self->app->render->paths

$self->helper() 

$self->req->param()

$self->res->code

$self->render() text,template

その１　てっとり早く動かしてみる

2012-09-13T22:54:00.005+09:00

雰囲気を味わうためにヘルパースクリプトを実行してみます。
何も考えずに実行してみます。
$mojo generate lite_app hello.pl

以下のようなコードが生成されます。

#!/usr/bin/env perl                                                                                       
use Mojolicious::Lite;

# Documentation browser under "/perldoc"                                                                  
plugin 'PODRenderer';

get '/' => sub {
  my $self = shift;
  $self->render('index');
};

app->start;
__DATA__

@@ index.html.ep
% layout 'default';
% title 'Welcome';
Welcome to the Mojolicious real-time web framework!

@@ layouts/default.html.ep


  <%= title %>
  <%= content %>

これまた、何も考えずに以下を実行します
$morbo hello.pl

すると以下メッセージが表示されるので、localhostの3000ポートにアクセスしてみます。
[Wed Sep 12 23:45:49 2012] [info] Listening at "http://*:3000".
Server available at http://127.0.0.1:3000.

Welcome to the Mojolicious real-time web framework!
と表示されました。

ここまでの補足。
・ヘルパーコマンドについて
$mojo generate help
でmojo generateのコマンドの簡単な説明が表示されます

---------------------------------------------------------------------------
These generators are currently available:
app Generate Mojolicious application directory structure.
lite_app Generate Mojolicious::Lite application.
makefile Generate "Makefile.PL".
plugin Generate Mojolicious plugin directory structure.
---------------------------------------------------------------------------

Mojolicious::Liteのひな形を作りたかったので
$mojo generate lite_app アプリ名　としたわけですね。

・開発用webサーバ
$morbo アプリ名
で、開発用webサーバが起動します。
ファイルを書きなおしても再度立ち上げ直す必要はありません。
Ctrl + cで終了。

・use Mojolicious::Lite
use strict; use warings;が有効になる

・plugin 'PODRenderer'
ヘルパーコマンドのソースには、Mojoliciousのガイドページが閲覧できるようになっています。
http://localhost:3000/perldoc　で見れます。

ひとまずここまで。
ルート、ビューについては後日メモ。

Mojolicious::Liteへ戻る

リファレンスのメモ

2012-04-09T01:49:00.002+09:00

変数の前に\をつけることでその変数に対する参照(リファレンス)でやり取りが可能になる。
そして、参照情報から実際の値を取り出すには、各変数のファニー文字(スカラー⇒$,
配列⇒@, ハッシュ⇒%)をつけてあげれば元の変数のように扱うことができる。

サンプルコード

#!/usr/bin/perl                                                                         
use feature 'say';
use strict;
use warnings;
use utf8;
use File::Find;

binmode STDIN,  ":utf8";
binmode STDOUT, ":utf8";

#配列、ハッシュ                                                                         
my @array = ("a", "b", "c");
my %hash  = (
             guu   => "rock",
             cyoki => "scissors",
             paa   => "paper",
            );

#リファレンス                                                                           
my $ref_array = \@array;
my $ref_hash  = \%hash;

                                                                                   
#表示                                                                                   
for(my $i = 0; $i < @{$ref_array}; $i++){
  say "${$ref_array}[$i]";
}


for my $key (keys %{$ref_hash}){ 
  say "key: $key / value: ${$ref_hash}{$key}";
}

実行結果：

a
b
c
key: paa / value: paper
key: cyoki / value: scissors
key: guu / value: rock

変数の頭に\をつけることをリファレンスと呼びその逆の行為をデリファレンスと呼ぶ。
デリファレンスした後
配列の場合　${$ref_array}[$i]
ハッシュの場合 ${$ref_hash}{$key}
とアクセスすることもできるが、アロー演算子による表記が用意されているので
以下のように書き換えることができる。

配列の場合　　$ref_array->[$i]
ハッシュの場合 $ref_hash->{$key}
サブルーチンの場合も同様にアロー演算子による表記が可能である。
まとめ。
配列　　　リファレンス->[要素]
ハッシュ　リファレンス->{キー}
関数　　　リファレンス->(引数)

上記の例では、配列とハッシュの変数に格納してからリファレンスを
扱っているが直接リファレンスを扱うこともできる。

配列の場合
(要素, 要素, 要素)から
[要素, 要素, 要素]に変えるだけ。

ハッシュの場合
(キー=>値, キー=>値)から
{キー=>値, キー=>値}に変えるだけ。

上記の例を書き直すとこうなる。

#!/usr/bin/perl                                                                         
use feature 'say';
use strict;
use warnings;
use utf8;
use File::Find;

binmode STDIN,  ":utf8";
binmode STDOUT, ":utf8";


#リファレンス                                                                           
my $ref_array = ["a", "b", "c"];
my $ref_hash  = {
                 guu   => "rock",
                 cyoki => "scissors",
                 paa   => "paper",
                };

                                                                                   
#表示                                                                                   
for(my $i = 0; $i < @{$ref_array}; $i++){
  say "${$ref_array}[$i]";
}


for my $key (keys %{$ref_hash}){ 
  say "key: $key / value: ${$ref_hash}{$key}";
}

簡単ですね！さて、今度は多次元配列を表現してみます。

#!/usr/bin/perl                                                                         
use feature 'say';
use strict;
use warnings;
use utf8;
use File::Find;

binmode STDIN,  ":utf8";
binmode STDOUT, ":utf8";


#リファレンス
my $ref_array = [
                 [1, 2],
                 [3, 4, 5],
                 [6, 7, 8, 9, 0],
                ];


for (my $x = 0; $x < @{$ref_array}; $x++){
  for (my $y = 0; $y < @{$ref_array->[$x]}; $y++){
    say $ref_array->[$x][$y];
  }
}

@{$ref_array} で [1, 2]と[3, 4, 5]と[6, 7, 8, 9, 0]の3要素であることを取得し
@{$ref_array->[$x]}で各要素
[1, 2] => 2要素
[3, 4, 5] => 3要素
[6, 7, 8, 9, 0] => 4要素
であることを取得しています。

File::Find

2012-04-08T22:23:00.003+09:00

■再帰的にディレクトリを移動して、ファイル/ディレクトリ名を取得する

.
├── 1
│   └── 2
│       └── 3.txt
├── a
│   └── b.txt
└── Sample.pl

上記構成を例に使用してみる。
■"1"ディレクトリの構成を調べる

#!/usr/bin/perl
use feature 'say';
use strict;
use warnings;
use utf8;
use File::Find;


find(\&wanted, '1');                                                                    

sub wanted{
  say "CurrentDirectory :", $File::Find::dir;
  say "Name             :", $_;
  say "FullPath         :", $File::Find::name;
  say "---";
}

実行結果：

CurrentDirectory :1
Name             :.
FullPath         :1
---
CurrentDirectory :1
Name             :2
FullPath         :1/2
---
CurrentDirectory :1/2
Name             :3.txt
FullPath         :1/2/3.txt
---

■複数のディレクトリを指定してみる

#!/usr/bin/perl
use feature 'say';
use strict;
use warnings;
use utf8;
use File::Find;


find(\&wanted, qw/1 a/); #配列で指定

sub wanted{
  say "CurrentDirectory :", $File::Find::dir;
  say "Name             :", $_;
  say "FullPath         :", $File::Find::name;
  say "---";
}

実行結果：

CurrentDirectory :1
Name             :.
FullPath         :1
---
CurrentDirectory :1
Name             :2
FullPath         :1/2
---
CurrentDirectory :1/2
Name             :3.txt
FullPath         :1/2/3.txt
---
CurrentDirectory :a
Name             :.
FullPath         :a
---
CurrentDirectory :a
Name             :b.txt
FullPath         :a/b.txt
---

■一番下の階層からスタートする

#!/usr/bin/perl
use feature 'say';
use strict;
use warnings;
use utf8;
use File::Find;


finddepth(\&wanted, '1');

sub wanted{
  say "CurrentDirectory :", $File::Find::dir;
  say "Name             :", $_;
  say "FullPath         :", $File::Find::name;
  say "---";
}

実行結果：

CurrentDirectory :1/2
Name             :3.txt
FullPath         :1/2/3.txt
---
CurrentDirectory :1
Name             :2
FullPath         :1/2
---
CurrentDirectory :1
Name             :.
FullPath         :1
---

FindBin

2012-04-08T21:28:00.001+09:00

実行スクリプトのディレクトリを取得するモジュール

#!/usr/bin/perl
use feature 'say';
use strict;
use warnings;
use utf8;
use FindBin;
                                                        
say $FindBin::Bin;

libモジュールのパス指定をする際に利用すると便利。
use lib "$FindBin::Bin/lib";

File::Path

2012-04-08T19:35:00.000+09:00

■ディレクトリの作成
カレントディレクトリにfoo/bar/bazなディレクトリ階層を作成したい時

下記構成
├── foo
│ └── bar
│ └── baz

#!/usr/bin/perl
use strict;
use warnings;
use utf8;

mkdir foo
mkdir foo/bar
mkdir foo/bar/baz

のように上位ディレクトリから順に作成していくことになる。

File::Pathを使うと１行ですむ。

#!/usr/bin/perl
use strict;
use warnings;
use utf8;
use File::Path qw/make_path/;

make_path('foo/bar/baz'); #ver 2.06以降

■ディレクトリの削除
下記ディレクトリ構造でfooディレクトリを削除したい時
├── foo
│   ├── bar
│   │   ├── baz
│   │   │   └── sample.txt
│   │   └── sample.txt
│   └── sample.txt
最下層のディレクトリ内のファイルを削除⇒ディレクトリ削除の順で削除する必要がある。
File::Findeモジュールのfinddepth関数で最下層のディレクトリからアクセスして削除していく

#!/usr/bin/perl
use strict;
use warnings;
use utf8;
use File::Find;
use FindBin;

finddepth(\&deleteAll, 'foo');

sub deleteAll{
  #フルパスじゃないと削除できなかったのでスクリプトのパスを取得しておく
  my $BasePath = $FindBin::Bin . '/';
  if(-f $_){ unlink $BasePath . $File::Find::name || die $! };
  if(-d $_){ rmdir  $BasePath . $File::Find::name || die $! };                          
}

File::Pathを使うと１行ですむ。

#!/usr/bin/perl
use strict;
use warnings;
use utf8;
use File::Path qw/remove_tree/;

remove_tree('foo'); #ver 2.06以降

v2.00より前とv2.06より前とそれ以降でインターフェースが異なります。
perl -MFile::Path -le 'print "$File::Path::VERSION"'
等で、確認した上で利用する必要があります。

v2.06以降の場合

use File::Path qw(make_path remove_tree);

  make_path('foo/bar/baz', '/zug/zwang'); #複数作成したい場合コンマで区切る
  make_path('foo/bar/baz', '/zug/zwang', {
      verbose => 1,  #1を指定すると実行時コマンドを出力する
      mode => 0711, #アクセス権限を指定  デフォ:0777
  });

  remove_tree('foo/bar/baz', '/zug/zwang');
  remove_tree('foo/bar/baz', '/zug/zwang', {
      verbose => 1,
      error  => \my $err_list, #エラー情報
  });

ワンライナー

2012-04-08T13:01:00.001+09:00

随時追加していく予定。

・eスイッチ
文字列をスクリプトとして解釈する
---
perl -e 'print "hello world¥n"'
---

・lスイッチ
行末に改行をつけてくれる。下の２コードは同じ結果となる
---
perl -e 'print "hello world¥n"'
perl -le 'print "hello world"'
---
改行を自動的につけてくれるといえばsay関数があるのでそれを使っても同じ結果となる。
ただし、Eスイッチになる。
---
perl -e 'print "hello world¥n"'
perl -le 'print "hello world"'
perl -E 'say "hello world"'
---

・Mスイッチ
モジュールを呼び出す
---
#FilePathモジュールのバージョンを出力
perl -MFile::Path -E 'say "$File::Path::VERSION"'
#LWP::Simpleをつかってwww.google.co.jpを取得
perl -MLWP::Simple -E 'say get shift' http://google.co.jp
---

配列からハッシュを作る

2012-04-08T12:22:00.003+09:00

■ハッシュ
・２つの配列(キー用の配列,値用の配列)からハッシュを作る
⇒ハッシュのスライスを使う

#!/usr/bin/perl
use feature 'say';
use strict;
use warnings;
use utf8;
use Encode;

my @k = qw/k1 k2 k3/;
my @v = qw/v1 v2 v3/;
my %h = ();
@h{@k} = @v; #ハッシュのスライス

for my $key (sort keys %h){
  say encode_utf8("key:". $key. " value:". $h{$key});
}

実行結果

key:k1 value:v1
key:k2 value:v2
key:k3 value:v3

上記では、空のハッシュに対し、ハッシュのスライスをおこなってみた。
今度は、値が入っているハッシュに対し、ハッシュのスライスを行い
配列データを配列に格納してみる。

#!/usr/bin/perl
use feature 'say';
use strict;
use warnings;
use utf8;
use Encode;

my @k = qw/k1 k2 k3/;
my @v = qw/v1 v2 v3/;
my %h = ("k0" => "v0", "k1" => "dummy");
@h{@k} = @v; #ハッシュのスライス

for my $key (sort keys %h){
  say encode_utf8("key:". $key. " value:". $h{$key});
}

実行結果

key:k0 value:v0
key:k1 value:v1
key:k2 value:v2
key:k3 value:v3

・配列(一つ)からハッシュを作る。
(存在するかどうかを知るためにハッシュ化するだけで値は意味のある値を必要としないとする)

#!/usr/bin/perl
use feature 'say';
use strict;
use warnings;
use utf8;
use Encode;

my @k = qw/k1 k2 k3/;
my %h = ();
@h{@k} = 1..@k; #ハッシュのスライス

for my $key (sort keys %h){
  say encode_utf8("key:". $key. " value:". $h{$key});
}

実行結果

key:k1 value:1
key:k2 value:2
key:k3 value:3

でも…map関数を使えばもっと綺麗に。

#!/usr/bin/perl
use feature 'say';
use strict;
use warnings;
use utf8;
use Encode;

my @k = qw/k1 k2 k3/;
my %h = map{($_, 1)} @k;

for my $key (sort keys %h){
  say encode_utf8("key:". $key. " value:". $h{$key});
}

WebService::YahooJapan::WebMA

2012-03-11T22:21:00.001+09:00

■Yahoo! 形態素解析APIを使ってみるメモ。
形態素解析APIを利用するにあたり、Yahooのアカウントと
AppIDを取得する必要があるので先に済ませておく。

1.Yahoo!のアカウントを取る。
https://login.yahoo.co.jp/config/login

2.どのページでもよいが、アプリケーションIDの登録をすませておく。
http://developer.yahoo.co.jp/webapi/jlp/ma/v1/parse.html

#!/usr/bin/perl
use feature 'say';
use strict;
use warnings;
use WebService::YahooJapan::WebMA;
use utf8;
use Dumpvalue; my $d = Dumpvalue->new();
binmode STDOUT, ":utf8";

my $AppID = '上記で取得しておいたアプリケーションIDを記載する';
$WebService::YahooJapan::WebMA::APIBase = 
         'http://jlp.yahooapis.jp/MAService/V1/parse';

my $api    = WebService::YahooJapan::WebMA->new( appid => $ApiID);
my $result = $api->parse(sentence => '本日は晴天なり') or die $api->error; #解析したい文章を指定する

$d->dumpValue($result);

'ma_result' => HASH(0x7fa5bbb28ec8)
   'filtered_count' => 4
   'total_count' => 4
   'word_list' => ARRAY(0x7fa5bbb1ee98)
      0  HASH(0x7fa5bbb25838)
         'pos' => '名詞'
         'reading' => 'ほんじつ'
         'surface' => '本日'
      1  HASH(0x7fa5bbb25880)
         'pos' => '助詞'
         'reading' => 'は'
         'surface' => 'は'
      2  HASH(0x7fa5bbb25670)
         'pos' => '名詞'
         'reading' => 'せいてん'
         'surface' => '晴天'
      3  HASH(0x7fa5bbb24718)
         'pos' => '助動詞'
         'reading' => 'なり'
         'surface' => 'なり'
'xmlns' => 'urn:yahoo:jp:jlp'
'xmlns:xsi' => 'http://www.w3.org/2001/XMLSchema-instance'
'xsi:schemaLocation' => 'urn:yahoo:jp:jlp http://jlp.yahooapis.jp/MAService/V1/parseResponse.xsd'

perlの特殊変数のめも

2012-03-04T22:01:00.003+09:00

気長にメモしていく予定。

変数	内容
$$	プロセスIDを返す
$,	リストを出力時のセパレータ。デフォルトは空文字。
$.	ファイルハンドルが読み込みを行った行番号が格納されている。ファイルの内容を１行ずつ読み込んでいる際に目的の行を見つけた際にそれが何行目か知りたい時などに利用
$0	スクリプト実行時のパスを返す(絶対パスなら絶対パス。相対パスなら相対パス)
$]	スクリプト実行した際のperlのバージョン
$\|	０以外を指定すると出力時のバッファーを行わなくなる。デフォルトは0

say関数

2012-03-03T22:13:00.001+09:00

say関数を使いたい時どうすればいいのか。
というので、調べてみたら

use feature 'say';

だったり

use 5.10.0;

だったり

use feature ':5.10.0';

だったり

use 5.010;

いろいろあって違いがよくわからなかった。
で、featureプラグマの訳があったんで非常に理解しやすかった。
⇒http://perldoc.jp/docs/modules/feature-1.11/feature.pod

つまり
use feature　では、ピンポイントの機能追加を行い
use feature ':5.10.0'; では、追加機能が全て使えるようになる
use 5.10.0;　は、上の別表記。
use 5.010; は、移植性の警告(?)を出さないための書き方ということなのね。

言ってしまえば、sayだけ使いたいんよ。
というのであるなら、追加機能すべて使える必要はなくて
use feature 'say';

で、OKってことになるのね。
で、おｋ？

Time:Piece

2012-03-03T15:06:00.000+09:00

■日時の取得

#!/usr/bin/perl
use feature 'say';
use strict;
use warnings;
use utf8;
use Time::Piece;
binmode STDOUT, ":utf8";


my $t = localtime;

### 日時の表示
say $t;              #Sat Mar  3 14:53:37 2012
say $t->datetime;    #2012-03-03T14:53:37
say $t->datetime(
         date => '/', 
         T    => ' ',
         time => '-'
                );   #2012/03/03 14-53-37
say $t->strftime('%Y*%m*%d  %H@%M@%S');
                     #2012*03*03  14@53@37  注：UTF8フラグが落ちてます


### 年月日の表示
say $t->ymd;      #2012-03-03
say $t->ymd("/"); #2012/03/03
say $t->ymd("");  #20120303

say $t->year;     #2012
say $t->mon;      #3
say $t->mday;     #3


### 曜日の表示
say $t->wday;      #7
say $t->wdayname;  #Sat
say $t->wdayname(
   qw/日 月 火 水 木 金 土/
                ); #土

#wdaynameを何度も使うのなら
#デフォルトの曜日を変更してしまう
$t->day_list(qw/日 月 火 水 木 金 土/);
say $t->wdayname;  #土


### 時分秒の表示
say $t->hms;      #14:53:37
say $t->hms("-"); #14-53-37
say $t->hms("");  #145337

say $t->hour;     #14
say $t->min;      #53
say $t->sec;      #37


### 他
#閏年判定
say $t->is_leap_year ? "閏年" : "Not閏年"; #閏年

#最終日
say $t->month_last_day; #31


### 任意の時間を設定
$t = localtime->strptime('2000-01-01 12:00:00', '%Y-%m-%d %H:%M:%S');
say $t->datetime; #2000-01-01T12:00:00


### 時間の比較
my $BaseDate = localtime->strptime('20001122', '%Y%m%d');
my $TestDate = localtime->strptime('20111122', '%Y%m%d');
say $BaseDate < $TestDate ? "もうすぎたよ" : "まだ過ぎてないよ";
                  #もうすぎだよ

### 時間の加減・減算(秒単位で返ってくる)
my $date1 = localtime->strptime('20120101', '%Y%m%d');
my $date2 = localtime->strptime('20130101', '%Y%m%d');
my $days  = ($date2 - $date1) / (24 * 60 * 60);
say $days;        #366

ただ、一つ注意。
strftimeメソッドは、utf8フラグを落とすことに注意。

#!/usr/bin/perl
use strict;
use warnings;
use Time::Piece;
use utf8;
use Devel::Peek;

my $t = localtime;
Dump $t->wdayname(qw/日 月 火 水 木 金 土/);
Dump $t->strftime('%Y年%m月%d日');

実行結果

SV = PV(0x7fd56b801170) at 0x7fd56b842708
  REFCNT = 1
  FLAGS = (TEMP,POK,pPOK,UTF8)
  PV = 0x105d08220 "\346\227\245"\0 [UTF8 "\x{65e5}"]
  CUR = 3
  LEN = 16
SV = PV(0x7fd56b801190) at 0x7fd56b842708
  REFCNT = 1
  FLAGS = (TEMP,POK,pPOK)
  PV = 0x105d06df0 "2012\345\271\26403\346\234\21004\346\227\245"\0
  CUR = 17
  LEN = 32

wdaynameメソッドの方には、UTF8フラグが残っているけど
strftimeメソッドの方には、UTF8フラグがないですよね。

上の例のように
binmode STDOUT, ":utf8";
して、標準出力する際にフラグを落とすようにしている場合
文字化けしちゃいます。

美しくないけど
binmode STDOUT, ":utf8";　するなら
use Encode;
say decode_utf8($t->strftimeメソッド);

のように内部にあるデータには徹底してフラグをつけるか

binmode STDOUT, ":utf8";　を使わないなら
use Encode;
say encode_utf8($t->strftime以外のメソッド);
say $t->strftimeメソッド;

とするしかないのかな…。

おまけ。
1日後、1ヶ月後を簡単に求めるのに
Time::Secondsを使う方法があります。

#!/usr/bin/perl
use strict;
use warnings;
use utf8;
use feature 'say';
use Time::Piece;
use Time::Seconds;

my $t = localtime;
say $t->ymd; #2012-03-03

$t += ONE_MONTH;
say $t->ymd; #2012-04-03

$t += ONE_MONTH;
say $t->ymd; #2012-05-03

$t += ONE_MONTH * 2;
say $t->ymd; #2012-07-03

Time::Secondsを利用すると以下の定数が使えるようになります。

ONE_DAY
ONE_WEEK
ONE_HOUR
ONE_MINUTE
ONE_MONTH
ONE_YEAR
ONE_FINANCIAL_MONTH
LEAP_YEAR
NON_LEAP_YEAR

後は、掛け算して加減算するなりすればよいですね。

perlめも

Perl Memo Index

DBI

エラー情報は、発生行？呼出し行 warn/die or carp/croak

マルチバイと文字列の文字列操作のお話

リファレンス+do

Config::Simple

perlの変更点が知りたい時

その２ ルートについて

Mojolicious

その１ てっとり早く動かしてみる

リファレンスのメモ

File::Find

FindBin

File::Path

ワンライナー

配列からハッシュを作る

WebService::YahooJapan::WebMA

perlの特殊変数のめも

say関数

Time:Piece

その２　ルートについて

その１　てっとり早く動かしてみる