ABAPx.in

REGEX in ABAP

2012-07-08T01:52:00.006+05:30

Using REGEX (Regular Expressions) we can build smart codes. Regex is used for string processing, and they are very fast.

In this example I'm formatting the names. My intention is to convert any name in the given format "Xxxxx Yyyyy". Using conventional ABAP programming this can get pretty messy as a name can be in any format. Thankfully REGEX helps a lot.

Example Name: PIERRE-LOUIS LEFÈVRE

The Output:

Another example with name: MARTIN LUTHER KING,JR.

The output:

Another example with name: TALLEGA Y PRADO

The output:

The Code :

*&---------------------------------------------------------------------*
*& Report ZTEST_SB1
*&---------------------------------------------------------------------*
*&
*&---------------------------------------------------------------------*
REPORT ZTEST_REGEX.

DATA: i_seltext TYPE STANDARD TABLE OF rsseltexts,
      wa_seltext TYPE rsseltexts.
DATA: l_off TYPE i,
      r_root TYPE REF TO cx_root,
      l_dummy TYPE c LENGTH 500,
      l_replacement TYPE string.

PARAMETERS: p_name TYPE c LENGTH 100 OBLIGATORY.

INITIALIZATION.

  wa_seltext-name = 'P_NAME'.
  wa_seltext-kind = 'P'.
  wa_seltext-text = 'Name'.
  APPEND wa_seltext TO i_seltext.
  CALL FUNCTION 'SELECTION_TEXTS_MODIFY'
    EXPORTING
      program                     = sy-repid
    TABLES
      seltexts                    = i_seltext
    EXCEPTIONS
      program_not_found           = 1
      program_cannot_be_generated = 2
      OTHERS                      = 3.
  IF sy-subrc <> 0.
* Implement suitable error handling here
  ENDIF.

START-OF-SELECTION.
  l_dummy = p_name.

  TRANSLATE l_dummy TO LOWER CASE.
  WHILE sy-subrc = 0.
    TRANSLATE l_dummy+l_off(1) TO UPPER CASE.
    FIND REGEX '(\<[a-z])' IN  l_dummy MATCH OFFSET l_off.
  ENDWHILE.
  WRITE: /1 'Formatted Name:',20 l_dummy.

How to use BOL Query Service in CRM 7.0

2011-08-17T14:23:00.001+05:30

This simple program is used to demonstrate how to use SAP BOL Query service in CRM 7.0

The Code :

*&---------------------------------------------------------------------*
*& Report  ZTEST_SB_BOL_READ
*&
*&---------------------------------------------------------------------*
*&***********DEMO Code for http://abap-explorer.blogspot.com/***********
*&
*&---------------------------------------------------------------------*
 
REPORT  ztest_sb_bol_read.
DATA :v_bol_core TYPE REF TO cl_crm_bol_core,
      v_qs TYPE REF TO cl_crm_bol_query_service,
      v_iterator TYPE REF TO if_bol_entity_col_iterator,
      v_search_result_coll TYPE REF TO if_bol_entity_col,
      v_btorder TYPE REF TO cl_crm_bol_entity,
      v_btheader TYPE REF TO cl_crm_bol_entity.
 
DATA: wa_btADMINH TYPE CRMST_ADMINH_BTIL,
      i_btadminh TYPE STANDARD TABLE OF CRMST_ADMINH_BTIL INITIAL SIZE 0.
 
DATA: v_alv TYPE REF TO cl_salv_table,
      v_columns TYPE REF TO cl_salv_columns_table.
 
PARAMETERS: p_bp TYPE bu_partner OBLIGATORY.
 
AT SELECTION-SCREEN OUTPUT.
  DATA: l_i_seltexts TYPE STANDARD TABLE OF rsseltexts INITIAL SIZE 0,
        l_wa_seltexts TYPE rsseltexts.
 
  CLEAR l_wa_seltexts.
  l_wa_seltexts-name = 'P_BP'.
  l_wa_seltexts-kind = 'P'.
  l_wa_seltexts-text = 'Business Partner'.
  APPEND l_wa_seltexts TO l_i_seltexts.
 
  CALL FUNCTION 'SELECTION_TEXTS_MODIFY'
    EXPORTING
      program                     = sy-repid
    TABLES
      seltexts                    = l_i_seltexts
    EXCEPTIONS
      program_not_found           = 1
      program_cannot_be_generated = 2
      OTHERS                      = 3.
  IF sy-subrc <> 0.
    MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
            WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
  ENDIF.
 
START-OF-SELECTION.
 
  v_bol_core = cl_crm_bol_core=>get_instance( ).
  v_bol_core->start_up( 'CRMIC_DEFAULT' ).
  v_qs = cl_crm_bol_query_service=>get_instance( 'BTQuery1O' ).
 
  CALL METHOD v_qs->set_property
    EXPORTING
      iv_attr_name = 'BP_NUMBER'
      iv_value     = p_bp.
 
  v_search_result_coll = v_qs->get_query_result( ).
  IF v_search_result_coll IS BOUND.
    v_iterator = v_search_result_coll->get_iterator( ).
  ENDIF.
  IF v_iterator IS BOUND.
    v_btorder = v_iterator->get_first( ).
  ENDIF.
 
  WHILE v_btorder IS BOUND.
    v_btheader = v_btorder->get_related_entity( 'BTOrderHeader' ).
    v_btheader->get_properties( IMPORTING es_attributes = wa_btadminh ).
 
      APPEND wa_btadminh TO i_btadminh.
    v_btorder = v_iterator->get_next( ).
  ENDWHILE.
 
END-OF-SELECTION.
 
  IF i_btadminh IS NOT INITIAL.
 
    TRY.
        CALL METHOD cl_salv_table=>factory
          IMPORTING
            r_salv_table = v_alv
          CHANGING
            t_table      = i_btadminh.
      CATCH cx_salv_msg .                               "#EC NO_HANDLER
 
    ENDTRY.
 
    v_columns = v_alv->get_columns( ).
    v_columns->set_optimize( abap_true ).
    v_alv->display( ).
 
 
  ELSE.
    MESSAGE i001(00) WITH 'No data found!'.
    LEAVE LIST-PROCESSING.
  ENDIF.

When tested :

How to get Internal Table Components at runtime

2010-01-14T01:19:00.004+05:30

This code can be helpful to get fields names of an Internal Table at Runtime.

The Code:

*&---------------------------------------------------------------------*
*& Report  ZTEST_INTERNAL_TAB_COMP
*&
*&---------------------------------------------------------------------*
*&***********DEMO Code for http://abap-explorer.blogspot.com/***********
*&
*&---------------------------------------------------------------------*
 
report  ztest_internal_tab_comp line-size 100.
type-pools: abap.
 
*Declare the type of the internal table
types: begin of x_final,
 matnr type matnr,
 werks type werks_d,
 flag type c length 1,
 value type p length 10 decimals 2,
end of x_final.
 
data:
*The Internal table whose components are to found
i_data type sorted table of x_final with unique key matnr,
*Table to hold the components
tab_return type abap_compdescr_tab,
*Work area for the component table
components like line of tab_return.
 
*Call Perform to get the Int. Table Components
perform get_int_table_fields using    i_data
                            changing  tab_return.
*Display Components
loop at tab_return into components.
  write: / components-name,  components-type_kind,
           components-length,components-decimals.
endloop.
 
 
 
 
*&---------------------------------------------------------------------*
*&      Form  get_int_table_fields
*&---------------------------------------------------------------------*
*       Get the Components of an internal table
*----------------------------------------------------------------------*
*      -->T_DATA     text
*      -->T_RETURN   text
*----------------------------------------------------------------------*
form get_int_table_fields  using    t_data type any table
                           changing t_return type abap_compdescr_tab.
 
  data:
  oref_table type ref to cl_abap_tabledescr,
  oref_struc type ref to cl_abap_structdescr,
  oref_error type ref to cx_root,
  text type string.
*Get the description of data object type
  try.
      oref_table ?=
      cl_abap_tabledescr=>describe_by_data( t_data ).
    catch cx_root into oref_error.
      text = oref_error->get_text( ).
      write: / text.
      exit.
  endtry.
*Get the line type
  try.
      oref_struc ?= oref_table->get_table_line_type( ).
    catch cx_root into oref_error.
      text = oref_error->get_text( ).
      write: / text.
      exit.
  endtry.
 
  append lines of oref_struc->components to t_return.
 
endform.                    " GET_INT_TABLE_FIELDS

Now if we test it...

The code can also be used to get components of a structure.

User Defined Conversion Exits

2010-01-08T01:22:00.016+05:30

This post will show how to create custom user defined Conversion-Exits.

Step 1) Create a Function Group and two Function Modules:

a) Create a Function Group. For eg. ZCONVERSION_EXIT.

b) Create two Function Modules with naming convention:

CONVERSION_EXIT_xxxxx_INPUT and CONVERSION_EXIT_xxxxx_OUTPUT, where XXXXX is the name of the Conversion Routine. Here I will create a Routine ZZERO so the
name of the Function Modules will be CONVERSION_EXIT_ZZERO_INPUT and CONVERSION_EXIT_ZZERO_OUTPUT. While create the Function Module you may get some error like "Function Module name is reserved for SAP", you can ignore this.

The Function Modules should have one Import Parameter Input and one Export Parameter Output.

The FM for conversion from External Format to Internal Format:

The Code:

FUNCTION conversion_exit_zzero_input.
*"----------------------------------------------------------------------
*"*"Local Interface:
*"  IMPORTING
*"     REFERENCE(INPUT)
*"  EXPORTING
*"     REFERENCE(OUTPUT)
*"----------------------------------------------------------------------

output = input.
REPLACE ALL OCCURRENCES OF 'Ø' IN output
WITH '0' IN CHARACTER MODE.

ENDFUNCTION.

The FM for conversion from Internal Format to External Format:

The Code:

FUNCTION CONVERSION_EXIT_ZZERO_OUTPUT.
*"----------------------------------------------------------------------
*"*"Local Interface:
*"  IMPORTING
*"     REFERENCE(INPUT)
*"  EXPORTING
*"     REFERENCE(OUTPUT)
*"----------------------------------------------------------------------
output = input.
REPLACE ALL OCCURRENCES OF '0' IN output
WITH 'Ø' IN CHARACTER MODE.

ENDFUNCTION.

Step 2) Create a data Element and a Domain.

Create the Data Element ZZERO:

The Domain ZZERO:

The name of the conversion routine created has to provided here. Now if the FM's for Conversion are created, if you double click on the Routine name, it will display the FM's.

Step 3)Now we can use a sample code to test the Conversion Routine:
The Code:

*&---------------------------------------------------------------------*
*& Report  ZTEST_CONVERSION_EXIT
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*

REPORT  ztest_conversion_exit.


PARAMETERS: p_value TYPE c LENGTH 20 OBLIGATORY.

DATA: v_result TYPE zzero. " data type with the Coversion Exit ZZERO

v_result = p_value.

WRITE: /5 'Input:',22  p_value,
      /5 'Converted Value:',22 v_result.

Now test it, If we give an input as "345RGT00VDF4340".

When Executed:

The "0" has been replaced by "Ø"

Similarly the Input Conversion Routine can be used and tested.

The Best way to find SUM of records

2009-07-25T21:13:00.004+05:30

In this post I would like to show which is the fastest way to find sum for a number of records.
The three possible ways to calculate a sum of records are:

Using COLLECT Statement.
Using SUM statement within Control-break statement AT-ENDAT.
Using a variable within a parallel cursor.

The conclusion is that the second option always takes less time compared to other three.The following graph explains it:

The following code is used to calculate it.Please test it yourself and give me a feedback.

PROGRAM ztest_sum.
 
TYPES:
BEGIN OF x_sbook,
  carrid     TYPE s_carr_id,
  connid     TYPE s_conn_id,
  fldate     TYPE s_date,
  luggweight TYPE s_lugweigh,
  wunit      TYPE s_weiunit,
END OF x_sbook.
 
DATA: i_sbook TYPE STANDARD TABLE OF x_sbook INITIAL SIZE 0,
      i_final1 TYPE STANDARD TABLE OF x_sbook INITIAL SIZE 0,
      i_final2 TYPE STANDARD TABLE OF x_sbook INITIAL SIZE 0,
      i_final3 TYPE STANDARD TABLE OF x_sbook INITIAL SIZE 0,
      wa_sbook TYPE x_sbook,
      rtime1 TYPE i,
      rtime2 TYPE i,
      rtime3 TYPE i.
 
PARAMETERS: p_rec TYPE i. " No. of records
 
SELECT carrid
       connid
       fldate
       luggweight
       wunit
  FROM sbook
  UP TO p_rec ROWS
  INTO TABLE i_sbook.
 
CHECK sy-subrc = 0.
APPEND LINES OF i_sbook TO i_sbook.
 
SORT i_sbook BY carrid connid fldate.
 
PERFORM collect.
 
PERFORM at_end_of_sum.
 
PERFORM sum_by_variable.
 
END-OF-SELECTION.
 
  PERFORM display.
 
 
*&---------------------------------------------------------------------*
*&      Form  collect
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM collect .
  DATA: time1 TYPE i,
        time2 TYPE i.
 
  GET RUN TIME FIELD time1.
 
  LOOP AT i_sbook INTO wa_sbook.
    COLLECT wa_sbook INTO i_final1.
  ENDLOOP.
 
  GET RUN TIME FIELD time2.
 
  rtime1  = time2 - time1.
ENDFORM.                    " collect
*&---------------------------------------------------------------------*
*&      Form  at_end_of_sum
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM at_end_of_sum .
  DATA: time1 TYPE i,
        time2 TYPE i.
 
  GET RUN TIME FIELD time1.
  LOOP AT i_sbook INTO wa_sbook.
    AT END OF fldate.
      SUM.
      APPEND wa_sbook TO i_final2.
    ENDAT.
  ENDLOOP.
 
  GET RUN TIME FIELD time2.
 
  rtime2 = time2 - time1.
ENDFORM.                    " at_end_of_sum
*&---------------------------------------------------------------------*
*&      Form  sum_by_variable
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM sum_by_variable .
  DATA: time1    TYPE i,
        time2    TYPE i,
        i_temp   TYPE STANDARD TABLE OF x_sbook INITIAL SIZE 0,
        l_index  TYPE i,
        wa_temp  TYPE x_sbook,
        l_weight TYPE s_lugweigh,
        wa_final TYPE x_sbook.
 
  GET RUN TIME FIELD time1.
 
  i_temp = i_sbook.
 
  DELETE ADJACENT DUPLICATES FROM i_temp
   COMPARING carrid connid fldate.
 
  LOOP AT i_temp INTO wa_temp.
    READ TABLE i_sbook
    TRANSPORTING NO FIELDS
    WITH KEY carrid = wa_temp-carrid
             connid = wa_temp-connid
             fldate = wa_temp-fldate
             BINARY SEARCH.
    IF sy-subrc = 0.
      l_index = sy-tabix.
      LOOP AT i_sbook INTO wa_sbook FROM l_index.
        IF wa_sbook-carrid <> wa_temp-carrid OR
           wa_sbook-connid <> wa_temp-connid OR
           wa_sbook-fldate <> wa_temp-fldate.
          EXIT.
        ENDIF.
        l_weight = wa_sbook-luggweight + l_weight.
      ENDLOOP.
 
      wa_final = wa_sbook.
      wa_final-luggweight = l_weight.
      APPEND wa_sbook TO i_final3.
      CLEAR l_weight.
    ENDIF.
  ENDLOOP.
 
  GET RUN TIME FIELD time2.
  rtime3 = time2 - time1.
ENDFORM.                    " sum_by_variable
*&---------------------------------------------------------------------*
*&      Form  display
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*  -->  p1        text
*  <--  p2        text
*----------------------------------------------------------------------*
FORM display .
  DATA: wa_final TYPE x_sbook.
 
  DATA: l_lines TYPE i.
 
  l_lines = LINES( i_final1 ).
  ULINE.
  FORMAT COLOR 2 ON.
  WRITE: /5 'Using COLLECT Statement',':', l_lines.
  WRITE: /5 'Run Time:',rtime1,'microseconds'.
  FORMAT COLOR 2 OFF.
  ULINE.
  l_lines = LINES( i_final2 ).
  FORMAT COLOR 1 ON.
  WRITE: /5 'Using Control Break statement AT-END-OF, SUM', ':',
          l_lines.
  WRITE: /5 'Run Time:',rtime2,'microseconds'.
  FORMAT COLOR 1 OFF.
  ULINE.
  l_lines = LINES( i_final3 ).
  FORMAT COLOR 4 ON.
  WRITE: /5 'Using Parallel Cursor',':', l_lines.
  WRITE: /5 'Run Time:',rtime3,'microseconds'.
  FORMAT COLOR 4 OFF.
  ULINE.
ENDFORM.                    " display

Traffic Light in ALV Reports

2009-07-24T17:43:00.015+05:30

Many a times we have to display a traffic light in ALV report. We can do that easily using "Exceptions" parameter provided by SAP. But it has one drawback, we cannot change the column header to something meaningful. It always set as "Exception" in case of ALV Grid and an icon in case of ALV List.

Here I'll show a workaround to show the traffic lights with a meaningful column header.

The exception display:

The workaround is to use a field of type CHAR4 and display it as Icon.
To display a field as icon, in ALV Field catalog we have to mark ICON field as 'X'. The icons for traffic lights are : icon_green_light, icon_red_light and icon_yellow_light.

The code :

*&---------------------------------------------------------------------*
*& Report  ZTEST_SOURAV_TRAFFIC_LIGHTS
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*

REPORT  ztest_sourav_traffic_lights.
TYPE-POOLS: slis,icon.
TYPES: BEGIN OF x_sflight,
carrid TYPE s_carr_id,
connid TYPE s_conn_id,
fldate TYPE s_date,
price  TYPE s_price,
currency TYPE s_currcode,
seatsmax TYPE s_seatsmax,
seatsocc TYPE s_seatsocc,
END OF x_sflight.
TYPES:BEGIN OF x_final,
icon TYPE char4.
INCLUDE TYPE x_sflight.
TYPES: END OF x_final.

DATA: i_sflight  TYPE STANDARD TABLE OF x_sflight INITIAL SIZE 0,
i_final    TYPE STANDARD TABLE OF x_final INITIAL SIZE 0,
i_fieldcat TYPE slis_t_fieldcat_alv,
wa_layout  TYPE slis_layout_alv.


CONSTANTS: program TYPE syrepid VALUE sy-repid.

START-OF-SELECTION.
SELECT carrid    " Airline Code
  connid    " Flight Connection Number
  fldate    " Flight date
  price     " Airfare
  currency  " Local currency of airline
  seatsmax  " Maximum capacity in economy class
  seatsocc  " Occupied seats in economy class
FROM sflight   " Flight
INTO TABLE i_sflight.
IF sy-subrc <> 0.
MESSAGE i001(00) WITH 'No data found!'.
LEAVE LIST-PROCESSING.
ENDIF.


END-OF-SELECTION.

PERFORM populate_records.

PERFORM display_records.


*&---------------------------------------------------------------------*
*&      Form  populate_records
*&---------------------------------------------------------------------*
*       Populate final table
*----------------------------------------------------------------------*
FORM populate_records .

DATA:
wa_sflight TYPE x_sflight,
wa_final TYPE x_final,
temp TYPE p DECIMALS 2.

LOOP AT i_sflight INTO wa_sflight.
CLEAR temp.
*Calculate Percentage of booked flights
temp = ( wa_sflight-seatsocc / wa_sflight-seatsmax ) .

IF temp > '0.9'.
*If booked more than 90%
wa_final-icon = icon_green_light.
ELSEIF temp < '0.2'.
*If booked less than 20%
wa_final-icon = icon_red_light.
ELSE.
*If its between 20% to 90 %
wa_final-icon = icon_yellow_light.
ENDIF.

wa_final-carrid = wa_sflight-carrid.
wa_final-connid = wa_sflight-connid.
wa_final-fldate = wa_sflight-fldate.
wa_final-price  = wa_sflight-price.
wa_final-currency = wa_sflight-currency.
wa_final-seatsmax = wa_sflight-seatsmax.
wa_final-seatsocc = wa_sflight-seatsocc.

APPEND wa_final TO i_final.
CLEAR wa_final.
ENDLOOP.
FREE i_sflight.
ENDFORM.                    " populate_records
*&---------------------------------------------------------------------*
*&      Form  display_records
*&---------------------------------------------------------------------*
*       Subroutines for Display
*----------------------------------------------------------------------*
FORM display_records .

PERFORM populate_field_catalog.

PERFORM populate_layout.

PERFORM trigger_alv.

ENDFORM.                    " display_records
*&---------------------------------------------------------------------*
*&      Form  populate_field_catalog
*&---------------------------------------------------------------------*
*       Popualte Field Catalog
*----------------------------------------------------------------------*
FORM populate_field_catalog .
DATA:
wa_fieldcat TYPE slis_fieldcat_alv.
DEFINE fcat_merge.

wa_fieldcat-col_pos        = &1.
wa_fieldcat-fieldname      = &2.
if wa_fieldcat-fieldname   = 'ICON'.
wa_fieldcat-icon         = 'X'.  " Display the field as ICON
wa_fieldcat-seltext_m    = 'Occupency Status'.   " Column Header
wa_fieldcat-inttype      = 'C'.
wa_fieldcat-outputlen    = '4'.
endif.

wa_fieldcat-ref_fieldname  = &3.
wa_fieldcat-ref_tabname    = &4.

if wa_fieldcat-fieldname  = 'PRICE'.
wa_fieldcat-cfieldname  = 'CURRENCY'.
wa_fieldcat-ctabname    = 'I_FINAL'.
endif.

append wa_fieldcat to i_fieldcat.
clear wa_fieldcat.
END-OF-DEFINITION.

fcat_merge: '1'  'ICON'     ''         '',
       '2'  'CARRID'   'CARRID'   'SFLIGHT',
       '3'  'CONNID'   'CONNID'   'SFLIGHT',
       '4'  'FLDATE'   'FLDATE'   'SFLIGHT',
       '5'  'PRICE'    'PRICE'    'SFLIGHT',
       '6'  'CURRENCY' 'CURRENCY' 'SFLIGHT',
       '7'  'SEATSMAX' 'SEATSMAX' 'SFLIGHT',
       '8'  'SEATSOCC' 'SEATSOCC' 'SFLIGHT'.

ENDFORM.                    " populate_field_catalog

*&---------------------------------------------------------------------*
*&      Form  populate_layout
*&---------------------------------------------------------------------*
*       Populate LAYOUT Structure for ALV
*----------------------------------------------------------------------*
FORM populate_layout.
wa_layout-zebra = 'X'.
wa_layout-colwidth_optimize = 'X'.
ENDFORM.                    "populate_layout
*&---------------------------------------------------------------------*
*&      Form  trigger_alv
*&---------------------------------------------------------------------*
*       Trigger the ALV API
*----------------------------------------------------------------------*
FORM trigger_alv .

CALL FUNCTION 'REUSE_ALV_GRID_DISPLAY'
EXPORTING
i_callback_program = program
is_layout          = wa_layout
it_fieldcat        = i_fieldcat
TABLES
t_outtab           = i_final
EXCEPTIONS
program_error      = 1
OTHERS             = 2.
IF sy-subrc <> 0.
MESSAGE i001(00) WITH 'Error while displaing ALV'.
LEAVE LIST-PROCESSING.
ENDIF.
ENDFORM.                    " trigger_alv

Helpful BASIS Transactions for ABAPers

2009-07-21T15:38:00.006+05:30

The following are some transactions which may come in handy for ABAPers:

Transaction Codes	Description
SCCL	LOCAL CLIENT COPY WITHIN THE SAME SYSTEM
SCC1	CLIENT COPY - SPECIAL SELECTIONS(COPY TRANSPORTS WITHIN CLIENTS)
SCC9	REMOTE CLIENT COPY IN DIFFERENT SYSTEM
SCC5	DELETING A CLIENT
SP01	SHOW SPOOL REQUEST
SPAD	CONFIGURE A PRINTER IN SAP
ST01	SYSTEM TRACE
ST02	SAP BUFFER
ST03	WORKLOAD MONITOR
ST04	DATABASE MONITOR
ST05	SQL TRACE
ST06	OS MONITOR
ST22	ABAP DUMP
SCUA	FOR CREATING/DELETING CUA
SCUM	WHICH DATA U WANT TO STORE LOCALLY AND WHICH GLOBALLY
SCUL	CUA LOG
PPOCE	CREATE A PLAN
PPOME	MAINTAIN A PLAN
PPOSE	DISPLAY A PLAN
STMS	TRANSPORT MANAGEMENT SYSTEM
SLG0	CONFIGURE APPLICATION LOG
SLG1	ANALYSE APPLICATION LOG
SLG2	DELETE APPLICATION LOG
SCUG	TRANSPORT OF USER
RZ01	JOB SCHEDULING MONITOR
RZ02	NETWORK GRAPHICS FOR SAP INSTANCES
RZ03	PRESENTATION CONTROL SAP INSTANCE
RZ04	MAINTAIN SAP INSTANCE
RZ06	ALERT THRESHOLD MAINTAINCE
RZ08	SAP ALERT MONITOR
RZ10	PROFILE PARAMETER CHECKING AND MAINTAINENCE
RZ11	DISPLAY PROFILE PARAMETER
RZ20	CCMS MONITOR
RZ04	SHIFTING OF OPERATION
BD54	CREATING A LOGICAL SYSTEM
BD64	DISPLAY OF DISTRIBUTION MODEL
SM01	LOCK/UNLOCK A TRANSTACTION
SM02	SEND SYSTEM MESSAGE
SM04	WHO ARE THE USER CURRENTLY LOGGED ON NOW
SM12	TO VIEW LOCK AND ALSO DELETE LOG
SM13	CHECK UPDATE
SM30	TABLE MAINTAINCE
SM36	SCHEDULING A BACKGROUND JOB
SM37	MONITORING A BACKGROUND JOB
SM49	EXECUTE A EXTERNAL COMMAND
SM59	CREATE A RFC CONNECTION
SM69	CREATING A COMMAND
SALE/BD54	LOGICAL NAME
SUPC	TO GENERATE PROFILE
DB01	ANALYZE EXCUSIVE LOCK WAITS
BD02	ANALYZE TABLES AND INDEX
DB03	PARAMETER CHANGE IN DB
DB11	EARLY WATCH PROFILE MAINTAINCE
DB12	OVERVIEW OF BACKUP LOGS
DB13	DATABASE ADMINISTRATOR CALENDER
DB14	SHOW DBA ACTION LOGS

How to print apostrophe ( ' ) using the WRITE statement

2009-07-16T01:16:00.009+05:30

Printing apostrophes ( ' ) in ABAP is really tricky as in ABAP coding we have to give values in quotes like 'Ricky World'. So how to use WRITE: 'Ricky's World' ? If you try to type this it will give syntax error!

The trick is use three apostrophes instead of one.

1
2
3

DATA: LINE(20) TYPE C.
CONCATENATE 'You''' 'll be there.' INTO LINE.
WRITE:/ LINE.

or simply :

1	WRITE:/ 'You''ll be there.'.

Determine whether a file is open or not in Application Server

2009-07-15T23:44:00.008+05:30

To determine whether a file is opened or not in application server we can use the class 'CX_SY_FILE_OPEN'. By using this class we can determine whether a file is opened or not in application server as SY-SUBRC <> 0 may not provide the file's open information while we are interacting with the file. SY-SUBRC <> 0 may happens for other reasons also.

DATA:
*    First declare an object of type CX_ROOT.
OREF TYPE REF TO CX_ROOT,
 
*    Then declare a variable of type string.
          TEXT TYPE STRING.
 
*Now open a dataset in a TRY-CATCH block
TRY.
OPEN DATASET '/USR/SAP/TRANS/ECC1/ETC/B12008.TXT' FOR OUTPUT
IN TEXT MODE ENCODING DEFAULT
 
* Then in the catch block instantiate the Object.
CATCH CX_SY_FILE_OPEN INTO OREF.
*   Now in 'CATCH' block use the TEXT variable to get the TEXT from the Object.
 TEXT = OREF->GET_TEXT( ).
 
*Now if the TEXT is not initial that means the file is already opened 
*else it is not opened and we have to open it
IF TEXT IS NOT INITIAL.
 
* If open then we can close the file
CLOSE DATASET '/USR/SAP/TRANS/ECC1/ETC/B120080627112.TXT'.
 
ENDIF.
 
ENDTRY.

Individual cell coloring in ALV

2009-04-24T13:47:00.020+05:30

This program demonstrates how to color individual cell in an ALV List. The same logic works for ALV grid also.

The ALV:

The Code:

*&---------------------------------------------------------------------*
*& Report  ZTEST_SOURAV31
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*
 
REPORT  ztest_sourav31.
TYPE-POOLS: slis.
TYPES: BEGIN OF x_sflight,
        sflight TYPE sflight.
TYPES    prop TYPE slis_t_specialcol_alv.
TYPES   END OF x_sflight.
 
DATA:
i_sflight    TYPE STANDARD TABLE OF sflight,
itab_sflight TYPE STANDARD TABLE OF x_sflight INITIAL SIZE 0,
wa_prop      TYPE slis_specialcol_alv,
average      TYPE s_seatsocc,
layout       TYPE slis_layout_alv,
fieldcat     TYPE slis_t_fieldcat_alv.
 
FIELD-SYMBOLS:
<wa> TYPE ANY,
<field> TYPE ANY,
<wa_sflight> TYPE x_sflight,
<wa_fcat>      TYPE slis_fieldcat_alv.
 
START-OF-SELECTION.
 
  SELECT *
      FROM sflight INTO TABLE i_sflight.
 
  CHECK sy-subrc = 0.
 
  SELECT AVG( seatsocc ) FROM sflight
    INTO average.
  CHECK sy-subrc = 0.
 
END-OF-SELECTION.
 
  LOOP AT i_sflight ASSIGNING <wa>.
    APPEND INITIAL LINE TO itab_sflight ASSIGNING <wa_sflight>.
    DO.
      ASSIGN COMPONENT sy-index OF STRUCTURE <wa> TO <field>.
      IF sy-subrc = 0.
        IF sy-index = 9.
          IF <field> > average.
            wa_prop-fieldname  = 'SFLIGHT-SEATSOCC'.
            wa_prop-color-col  = '5'.
            wa_prop-color-int  = '0'.
            wa_prop-color-inv  = '0'.
            wa_prop-nokeycol   = 'X'.
            APPEND wa_prop TO <wa_sflight>-prop.
          ELSE.
            wa_prop-fieldname  = 'SFLIGHT-SEATSOCC'.
            wa_prop-color-col  = '6'.
            wa_prop-color-int  = '0'.
            wa_prop-color-inv  = '0'.
            wa_prop-nokeycol   = 'X'.
            APPEND wa_prop TO <wa_sflight>-prop.
          ENDIF.
        ENDIF.
      ELSE.
        EXIT.
      ENDIF.
    ENDDO.
    <wa_sflight>-sflight = <wa>.
  ENDLOOP.
 
  layout-coltab_fieldname = 'PROP'.
 
  CALL FUNCTION 'REUSE_ALV_FIELDCATALOG_MERGE'
    EXPORTING
      i_program_name         = 'ZTEST_SOURAV31'
      i_internal_tabname     = 'ITAB_SFLIGHT'
      i_structure_name       = 'SFLIGHT'
      i_client_never_display = 'X'
    CHANGING
      ct_fieldcat            = fieldcat
    EXCEPTIONS
      inconsistent_interface = 1
      program_error          = 2
      OTHERS                 = 3.
  IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.
 
  LOOP AT fieldcat ASSIGNING <wa_fcat>.
    CONCATENATE 'SFLIGHT-' <wa_fcat>-fieldname INTO <wa_fcat>-fieldname.
    IF <wa_fcat>-cfieldname IS NOT INITIAL.
  CONCATENATE 'SFLIGHT-' <wa_fcat>-cfieldname INTO <wa_fcat>-cfieldname.
    ENDIF.
  ENDLOOP.
 
  CALL FUNCTION 'REUSE_ALV_LIST_DISPLAY'
    EXPORTING
      i_callback_program = 'ZTEST_SOURAV31'
      is_layout          = layout
      it_fieldcat        = fieldcat
    TABLES
      t_outtab           = itab_sflight
    EXCEPTIONS
      program_error      = 1
      OTHERS             = 2.
  IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
  ENDIF.

Display an ALV in a Selection Screen

2009-01-02T01:02:00.011+05:30

This program demonstrates how to display an ALV grid in the selection screen itself upon hitting "ENTER" button.

The Selection Screen:

The ALV (Upon hitting enter):

The ALV gets refreshed when new selection screen values are entered:

The code:

*&---------------------------------------------------------------------*
*& Report  ZSB_ALV_SAME_SCREEN
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*
 
REPORT  zsb_alv_same_screen.
 
DATA:
wa_sflight TYPE sflight,
i_sflight TYPE STANDARD TABLE OF sflight INITIAL SIZE 0,
oref_dock TYPE REF TO cl_gui_docking_container,
oref_alv TYPE REF TO cl_gui_alv_grid,
i_exclude TYPE TABLE OF syucomm.
 
 
SELECT-OPTIONS:
s_carrid FOR wa_sflight-carrid,
s_connid FOR wa_sflight-connid,
s_fldate FOR wa_sflight-fldate.
 
AT SELECTION-SCREEN OUTPUT.
 
  APPEND 'ONLI' TO i_exclude.
  APPEND 'SJOB' TO i_exclude.
  APPEND 'PRIN' TO i_exclude.
 
  CALL FUNCTION 'RS_SET_SELSCREEN_STATUS'
    EXPORTING
      p_status  = sy-pfkey
      p_program = sy-repid
    TABLES
      p_exclude = i_exclude.
 
 
AT SELECTION-SCREEN.
  CHECK sy-ucomm = space.
  SELECT * FROM sflight INTO TABLE i_sflight
  WHERE carrid IN s_carrid
  AND   connid IN s_connid
  AND   fldate IN s_fldate.
 
  IF sy-subrc = 0.
 
    IF oref_dock IS NOT BOUND.
 
      CREATE OBJECT oref_dock
         EXPORTING
           repid                       = sy-repid
           dynnr                       = '1000'
           side                        =
      cl_gui_docking_container=>dock_at_bottom
               ratio                       = 70
        EXCEPTIONS
          cntl_error                  = 1
          cntl_system_error           = 2
          create_error                = 3
          lifetime_error              = 4
          lifetime_dynpro_dynpro_link = 5
          OTHERS                      = 6
          .
      IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
      ENDIF.
    ENDIF.
    IF oref_alv IS NOT BOUND.
 
      CHECK oref_dock IS BOUND.
      CREATE OBJECT oref_alv
        EXPORTING
          i_parent          = oref_dock
        EXCEPTIONS
          error_cntl_create = 1
          error_cntl_init   = 2
          error_cntl_link   = 3
          error_dp_create   = 4
          OTHERS            = 5.
      IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
      ENDIF.
 
      CHECK oref_alv IS BOUND.
 
      CALL METHOD oref_alv->set_table_for_first_display
        EXPORTING
          i_structure_name              = 'SFLIGHT'
        CHANGING
          it_outtab                     = i_sflight
        EXCEPTIONS
          invalid_parameter_combination = 1
          program_error                 = 2
          too_many_lines                = 3
          OTHERS                        = 4.
      IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
      ENDIF.
    ELSE.
 
      CALL METHOD oref_alv->refresh_table_display
        EXCEPTIONS
          finished = 1
          OTHERS   = 2.
      IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
      ENDIF.
 
    ENDIF.
  ENDIF.

ALE / EDI/ IDOCS Transaction Codes

2009-01-01T15:45:00.005+05:30

The following are some helpful transaction codes used for ALE, EDI and IDoc :

Transaction Codes	Description
WE02	List Of All Idocs Created. (Default, Additional, EDI)
WE05	List Of Idocs Created. (Standard, Additional)
WE06	Active Monitoring For Idoc Processing.
WE07	Idoc Statistics.
WE08	Display View “File Status”:Overview-Path Name.
WE09	Idoc Search For Business Contents (Database).
WE10	Idoc Search For Business Contents (Archive).
WE12	Modification Of Outbound File, Triggering Inbound Processing.
WE14	Process All Selected Idocs.
WE15	Selection Program For Issuing Output.
WE16	Trigger Inbound Processing.
WE17	Trigger Status Processing.
WE18	Generate Test Status File For Outbound Idocs.
WE19	Test Tool For Idoc Processing
WE20	Partner Profile.
WE21	Ports In Idoc Processing.
WE23	Display Test Catalog Test Idoc Interface.
WE24	Maintain Table View. Direction-1.(Outbound)
WE27	Maintain Table View. Direction-2.(Inbound)
WE30	Develop Idoc Type.
WE31	Develop Idoc Segments.
WE32	View Development.
WE33	Maintain Table Views.
WE34	Change View “Table Of Style Ids With The Objects To Be Loaded”
WE40	Display System Process Code.
WE41	Display View: Logical Msg Overview. For Outbund.
WE42	Display View: Logical Msg Overview. For Inbound.
WE43	Display Status Records.
WE44	Display Partner Types
WE45	Maintenance Interface: Forwarding Inbound/EDILOGADR For Application
WE46	Global Parameter For Idoc Interface.
WE47	Status Maintenance.
WE50	Display Text For Process Code System.
WE54	Idoc Function Module For File Name
WE56	Display Status Process Code
WE57	Idoc Assignment Of FM To Log. Message And Idoc Type.
WE58	Text For Process Code Status.
WE60	Documentation For Idoc Type.
WE61	Documentation For Idoc Record Type.
WE62	Documentation For Idoc Segment Type.
WE63	Documentation For Idoc Record Types And Idoc Types (Parser).
WE64	Process Code In Idoc Inbound And Outbound.
WE70	Conversion Table For Basic Types.
WE71	Conversion Table For Extensions.
WE72	Conversion Table For Field DOCTYP.
WE73	Conversion Table For Logical Message Type.
WE81	EDI:Logical Message Type.
WE82	Message Types And Assignment To Idoc Types.
WE84	Assignment Table Between Idoc And Application Field.
BD10	Send Material (Matmas)
BD11	Get Material.
BD12	Send Customer.
BD13	Get Customers
BD14	Send Vendor.
BD15	Get Vendor.
BD16	Send Cost Center. (Cosmas)
BD17	Request Cost Center.
BD18	Send G/L Accounts.
BD19	Get Master Data G/L Accounts.
BD20	Inbound Processing Of Idocs Ready For Transfer.
BD21	Creating Idoc Types For Change Pointers.
BD22	Delete Change Pointers.
BD23	Serialization Using Time Stamp: Deletion Of Old Time Stamp.
BD24	Send Cost Elements.
BD25	Send Activity Type (COAMAS)
BD26	Request Activity Type
BD27	Cost Center/Activity Types: Transmit Plan Quantities And Acty Prices.
BD28	Cost Center/ Cost Elements: Send Control Records.
BD30	Material Bom Distribution. (Bommat).
BD31	Document Structure Distribution. (Bomdoc)
BD32	Plant Allocation To Material Boms Distribution.
BD33	Distribution Of Material Variants. (STTMAT)
BD34	Distribution Of Boms (BOMORD)
BD35	ALE: Send Business Process Group.
BD36	ALE: Send Business Process.
BD37	ALE: Send Business Process Price.
BD40	Generate Idocs For Serialization Group From Change Pointers.
BD41	Dispatch Of Idocs Of Serialization Group.
BD42	Check Dispatch Status Of Idocs Of Serialization Group.
BD43	Processing Inbound Idocs Of Serialization Group.
BD44	Change View “Serialization Group”.
BD47	Dependence Between Methods.
BD48	Dependence Between Methods And Message Type.
BD50	Activate Change Pointers For Message Type.
BD51	Characteristics Of Inbound Function Module.
BD52	Determine Work Area.
BD53	Reduce Message Type.
BD54	Change View: Logical Systems
BD55	Idoc Conversion.
BD56	Maintain Idoc Segment Filters.
BD57	Link Type And Serialization Type Of Message Type.
BD58	Convert Organizational Unit.
BD59	Allocation Of Object Type.
BD60	Additional Data For Message Type.
BD61	Activate Change Pointers Generally.
BD62	Display Conversion Rule.
BD63	Transport Of Ale Tables For A Message Type.
BD64	Display Distribution Model.
BD65	Maintain Idoc Type Required Fields.
BD66	Change Idoc Fields.
BD67	Function Module For ALE/EDI Overview.
BD68	Maintain List.
BD69	Assignment Of Idoc Type To Message Type.
BD70	Cross-System Comparison Of Number Range Objects.
BD71	Attributes For Receiver Determination.
BD72	Active Events For ALE/EDI
BD73	Start Error Handling For Non-Posted Idocs.
BD75	Status Conversion With Trfc Execution.
BD77	Generate Transport Requests For Distributing ALE Customizing Data.
BD78	Monitoring Ale Customizing Data Transport
BD79	ALE IDOC Segments - Conversion Rule
BD81	Filter Objects For BAPI Parameter Filtering
BD82	Generating Partner Profile
BD83	Re-Processing Incorrect Outbound Odocs.
BD84	Re-Processing Of Idocs After ALE Input Error.
BD85	Consistency Check: Reassignment Between Two System.
BD86	ALE Consistency Check: Create Purchase Order From Sales Order.
BD87	Select Idocs
BD89	Customizing Data Modeling For Distribution Model.
BD91	Distribute All Characteristics Via ALE.
BD92	Distribute Class Via ALE: Send Direct.
BD93	Distribution Of Classification Data Via ALE.
BD95	Ale Object View
BD96	Filter Object For Receiver Determination Of Methods.
BD97	Assign RFC Destination For Synchronous Method Calls.
BD98	Consistency Check With Workflow Link
BD99	Dependencies Between Message Types.
BD100	Display Serialized Idocs. (Serialization Using Object Types)
BD101	Serialization Using Object Types: Consistency Check.
BD102	Ale: Outbound Channel Registry.

Demo program for TOP-OF-PAGE for ALV displayed through CL_GUI_ALV_GRID

2008-12-10T21:58:00.011+05:30

This program demonstrates how to create TOP OF PAGE for an ALV grid displayed through CL_GUI_ALV_GRID. One interesting fact which may be considered here is that the splitter TOP-OF-PAGE is not called while printing or background spool and the TOP-OF-PAGE printed in the spool cannot be displayed in the foreground.

The TOP-OF-PAGE displayed in foreground (this TOP-OF-PAGE won't be printed):

Choose the list output:

The list output(this top-of-page will be printed):

The code:

*&---------------------------------------------------------------------*
*& Report  Z_SOURAV_ALV_TOP_OF_PAGE
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*
 
REPORT  z_sourav_alv_top_of_page.
 
*----------------------------------------------------------------------*
*       CLASS cl_main DEFINITION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS cl_main DEFINITION.
  PUBLIC SECTION.
    METHODS:
    constructor,
    get_data,
    populate_fc_layout,
    top_of_page FOR EVENT top_of_page OF cl_gui_alv_grid
    IMPORTING
     e_dyndoc_id
     table_index,
    print_top_of_page FOR EVENT print_top_of_page OF  cl_gui_alv_grid
     IMPORTING table_index,
    display.
 
 
  PROTECTED SECTION.
 
  PRIVATE SECTION.
    TYPE-POOLS:sdydo.
    DATA:i_sbook TYPE STANDARD TABLE OF sbook INITIAL SIZE 0.
    DATA:oref_splitter TYPE REF TO cl_gui_splitter_container,
         oref_container TYPE REF TO cl_gui_custom_container,
         oref_alv TYPE REF TO cl_gui_alv_grid,
         container1 TYPE REF TO cl_gui_container,
         container2 TYPE REF TO cl_gui_container,
         oref_doc TYPE REF TO cl_dd_document,
         oref_html TYPE REF TO cl_gui_html_viewer,
         wa_layout TYPE lvc_s_layo,
         i_fieldcatalog TYPE lvc_t_fcat.
 
ENDCLASS.                    "cl_main DEFINITION
*----------------------------------------------------------------------*
*       CLASS cl_main IMPLEMENTATION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS cl_main IMPLEMENTATION.
  METHOD constructor.
 
    CREATE OBJECT oref_container
      EXPORTING
        container_name              = 'CONTAINER'
        repid                       = 'Z_SOURAV_ALV_TOP_OF_PAGE'
        dynnr                       = '0100'
      EXCEPTIONS
        cntl_error                  = 1
        cntl_system_error           = 2
        create_error                = 3
        lifetime_error              = 4
        lifetime_dynpro_dynpro_link = 5
        OTHERS                      = 6.
    IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
 
 
    CREATE OBJECT oref_splitter
      EXPORTING
        parent            = oref_container
        rows              = 2
        columns           = 1
      EXCEPTIONS
        cntl_error        = 1
        cntl_system_error = 2
        OTHERS            = 3.
    IF sy-subrc <> 0.
*     MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*                WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
 
    CALL METHOD oref_splitter->get_container
      EXPORTING
        row       = 1
        column    = 1
      RECEIVING
        container = container1.
 
    CALL METHOD oref_splitter->set_row_height
      EXPORTING
        id                = 1
        height            = 20
      EXCEPTIONS
        cntl_error        = 1
        cntl_system_error = 2
        OTHERS            = 3.
    IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
 
 
    CALL METHOD oref_splitter->get_container
      EXPORTING
        row       = 2
        column    = 1
      RECEIVING
        container = container2.
 
 
    CREATE OBJECT oref_doc
      EXPORTING
        style = 'ALV_GRID'.
 
 
    CREATE OBJECT oref_alv
      EXPORTING
        i_parent          = container2
      EXCEPTIONS
        error_cntl_create = 1
        error_cntl_init   = 2
        error_cntl_link   = 3
        error_dp_create   = 4
        OTHERS            = 5.
    IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
 
 
  ENDMETHOD.                    "constructor
  METHOD get_data.
    SELECT * FROM sbook INTO TABLE i_sbook UP TO 500 ROWS.
    IF sy-subrc <> 0.
 
    ENDIF.
 
  ENDMETHOD.                    "get_data
  METHOD populate_fc_layout.
    CALL FUNCTION 'LVC_FIELDCATALOG_MERGE'
      EXPORTING
        i_structure_name       = 'SBOOK'
        i_client_never_display = 'X'
        i_internal_tabname     = 'I_SBOOK'
      CHANGING
        ct_fieldcat            = i_fieldcatalog
      EXCEPTIONS
        inconsistent_interface = 1
        program_error          = 2
        OTHERS                 = 3.
    IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
 
    wa_layout-cwidth_opt = 'X'.
 
  ENDMETHOD.                    "populate_fc_layout
  METHOD top_of_page.
 
    DATA: text TYPE sdydo_text_element,
          background_id TYPE sdydo_key VALUE 'ALV_BACKGROUND'.
 
    text = 'Top of Page'.
 
    CALL METHOD oref_doc->add_text
      EXPORTING
        text         = text
        sap_color    = cl_dd_document=>list_positive
        sap_fontsize = cl_dd_document=>large.
 
    oref_doc->new_line( ).
    text = 'Line1'.
 
    CALL METHOD oref_doc->add_text
      EXPORTING
        text = text.
 
    CREATE OBJECT oref_html
      EXPORTING
        parent             = container1
      EXCEPTIONS
        cntl_error         = 1
        cntl_install_error = 2
        dp_install_error   = 3
        dp_error           = 4
        OTHERS             = 5.
    IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
 
    oref_doc->html_control = oref_html.
 
    CALL FUNCTION 'REUSE_ALV_GRID_COMMENTARY_SET'
      EXPORTING
        document = oref_doc
        bottom   = space.
 
    CALL METHOD oref_doc->merge_document.
 
    CALL METHOD oref_doc->set_document_background
      EXPORTING
        picture_id = background_id.
 
    CALL METHOD oref_doc->display_document
      EXPORTING
        reuse_control      = 'X'
        parent             = container1
      EXCEPTIONS
        html_display_error = 1
        OTHERS             = 2.
    IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
  ENDMETHOD.                    "create_top_of_page
  METHOD display.
 
    SET HANDLER me->top_of_page FOR oref_alv.
    SET HANDLER me->print_top_of_page FOR oref_alv.
 
    CALL METHOD oref_alv->set_table_for_first_display
      EXPORTING
        is_layout                     = wa_layout
      CHANGING
        it_outtab                     = i_sbook
        it_fieldcatalog               = i_fieldcatalog
      EXCEPTIONS
        invalid_parameter_combination = 1
        program_error                 = 2
        too_many_lines                = 3
        OTHERS                        = 4.
    IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
 
    CALL METHOD oref_doc->initialize_document
      .
 
 
    CALL METHOD oref_alv->list_processing_events
      EXPORTING
        i_event_name = 'TOP_OF_PAGE'
        i_dyndoc_id  = oref_doc.
 
 
    CALL SCREEN 0100.
  ENDMETHOD.                    "display
  METHOD print_top_of_page.
    WRITE:/5 'Print top of page' COLOR 5 INTENSIFIED OFF.
    WRITE:/5 'Line1'.
  ENDMETHOD.                    "print_top_of_page
ENDCLASS.                    "cl_main IMPLEMENTATION
 
DATA: oref_main TYPE REF TO cl_main.
DATA:ok_code TYPE syucomm.
 
START-OF-SELECTION.
 
  CREATE OBJECT oref_main.
 
  oref_main->get_data( ).
  oref_main->populate_fc_layout( ).
 
END-OF-SELECTION.
 
  oref_main->display( ).
*&---------------------------------------------------------------------*
*&      Module  STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE status_0100 OUTPUT.
  SET PF-STATUS '0100'.
*  SET TITLEBAR 'xxx'.
ENDMODULE.                 " STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_0100  INPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE user_command_0100 INPUT.
  CASE ok_code.
    WHEN 'BACK'.
      SET SCREEN 00.
      LEAVE SCREEN.
  ENDCASE.
ENDMODULE.                 " USER_COMMAND_0100  INPUT

Upload data from multiple worksheets of an excel file into SAP

2008-12-04T00:44:00.009+05:30

This program demonstrates hoe to read data from multiple worksheets of an excel file.
I developed this code using SAP class:
CL_GUI_CUSTOM_CONTAINER
and intefaces:
I_OI_CONTAINER_CONTROL,
I_OI_DOCUMENT_PROXY AND
I_OI_SPREADSHEET.

The test file:

The selection screen:

The output:

The Code:

*&---------------------------------------------------------------------*
*& Report  ZTEST_SOURAV_EXCEL
*&
*&---------------------------------------------------------------------*
*& Sourav Bhaduri 02-Dec-2008
*&---------------------------------------------------------------------*
 
REPORT  ztest_sourav_excel NO STANDARD PAGE HEADING.
 
DATA:
oref_container   TYPE REF TO cl_gui_custom_container,
iref_control     TYPE REF TO i_oi_container_control,
iref_document    TYPE REF TO i_oi_document_proxy,
iref_spreadsheet TYPE REF TO i_oi_spreadsheet,
iref_error       TYPE REF TO i_oi_error.
 
DATA:
v_document_url TYPE c LENGTH 256,
i_sheets TYPE soi_sheets_table,
wa_sheets TYPE soi_sheets,
i_data        TYPE soi_generic_table,
wa_data       TYPE soi_generic_item,
i_ranges      TYPE soi_range_list.
 
PARAMETERS:
p_file  TYPE  localfile OBLIGATORY,
p_rows TYPE i DEFAULT 100 OBLIGATORY,   "Rows (Maximum 65536)
p_cols TYPE i DEFAULT 10 OBLIGATORY.    "Columns (Maximum 256)
 
INITIALIZATION.
 
  CALL METHOD c_oi_container_control_creator=>get_container_control
    IMPORTING
      control = iref_control
      error   = iref_error.
  IF iref_error->has_failed = 'X'.
    CALL METHOD iref_error->raise_message
      EXPORTING
        type = 'E'.
  ENDIF.
 
 
  CREATE OBJECT oref_container
    EXPORTING
      container_name              = 'CONT'
    EXCEPTIONS
      cntl_error                  = 1
      cntl_system_error           = 2
      create_error                = 3
      lifetime_error              = 4
      lifetime_dynpro_dynpro_link = 5
      OTHERS                      = 6.
  IF sy-subrc <> 0.
    MESSAGE e001(00) WITH 'Error while creating container'.
  ENDIF.
 
  CALL METHOD iref_control->init_control
    EXPORTING
      inplace_enabled      = 'X'
      r3_application_name  = 'EXCEL CONTAINER'
      parent               = oref_container
    IMPORTING
      error                = iref_error
    EXCEPTIONS
      javabeannotsupported = 1
      OTHERS               = 2.
  IF iref_error->has_failed = 'X'.
    CALL METHOD iref_error->raise_message
      EXPORTING
        type = 'E'.
  ENDIF.
 
  CALL METHOD iref_control->get_document_proxy
    EXPORTING
      document_type  = soi_doctype_excel_sheet
    IMPORTING
      document_proxy = iref_document
      error          = iref_error.
  IF iref_error->has_failed = 'X'.
    CALL METHOD iref_error->raise_message
      EXPORTING
        type = 'E'.
  ENDIF.
 
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_file.
 
* To provide F4 help for the file
  PERFORM sub_file_f4.
 
START-OF-SELECTION.
 
  CONCATENATE 'FILE://' p_file INTO v_document_url.
 
  CALL METHOD iref_document->open_document
    EXPORTING
      document_title = 'Excel'
      document_url   = v_document_url
      open_inplace   = 'X'
    IMPORTING
      error          = iref_error.
  IF iref_error->has_failed = 'X'.
    CALL METHOD iref_error->raise_message
      EXPORTING
        type = 'I'.
    LEAVE LIST-PROCESSING.
  ENDIF.
 
  CALL METHOD iref_document->get_spreadsheet_interface
    EXPORTING
      no_flush        = ' '
    IMPORTING
      error           = iref_error
      sheet_interface = iref_spreadsheet.
 
  IF iref_error->has_failed = 'X'.
    CALL METHOD iref_error->raise_message
      EXPORTING
        type = 'I'.
    LEAVE LIST-PROCESSING.
  ENDIF.
 
  CALL METHOD iref_spreadsheet->get_sheets
    EXPORTING
      no_flush = ' '
    IMPORTING
      sheets   = i_sheets
      error    = iref_error.
  IF iref_error->has_failed = 'X'.
    CALL METHOD iref_error->raise_message
      EXPORTING
        type = 'I'.
    LEAVE LIST-PROCESSING.
  ENDIF.
  LOOP AT i_sheets INTO wa_sheets.
    CALL METHOD iref_spreadsheet->select_sheet
      EXPORTING
        name  = wa_sheets-sheet_name
      IMPORTING
        error = iref_error.
    IF iref_error->has_failed = 'X'.
      EXIT.
    ENDIF.
    CALL METHOD iref_spreadsheet->set_selection
      EXPORTING
        top     = 1
        left    = 1
        rows    = p_rows
        columns = p_cols.
 
    CALL METHOD iref_spreadsheet->insert_range
      EXPORTING
        name     = 'Test'
        rows     = p_rows
        columns  = p_cols
        no_flush = ''
      IMPORTING
        error    = iref_error.
    IF iref_error->has_failed = 'X'.
      EXIT.
    ENDIF.
 
    REFRESH i_data.
 
    CALL METHOD iref_spreadsheet->get_ranges_data
      EXPORTING
        all      = 'X'
      IMPORTING
        contents = i_data
        error    = iref_error
      CHANGING
        ranges   = i_ranges.
    DELETE i_data WHERE value IS INITIAL OR value = space.
    ULINE.
    WRITE:/1 wa_sheets-sheet_name COLOR 3.
    ULINE.
 
    LOOP AT i_data INTO wa_data.
      WRITE:(50) wa_data-value.
      AT END OF row.
        NEW-LINE.
      ENDAT.
    ENDLOOP.
  ENDLOOP.
 
  CALL METHOD iref_document->close_document
    IMPORTING
      error = iref_error.
  IF iref_error->has_failed = 'X'.
    CALL METHOD iref_error->raise_message
      EXPORTING
        type = 'I'.
    LEAVE LIST-PROCESSING.
  ENDIF.
 
  CALL METHOD iref_document->release_document
    IMPORTING
      error = iref_error.
  IF iref_error->has_failed = 'X'.
    CALL METHOD iref_error->raise_message
      EXPORTING
        type = 'I'.
    LEAVE LIST-PROCESSING.
  ENDIF.
 
*&---------------------------------------------------------------------*
*&      Form  SUB_FILE_F4
*&---------------------------------------------------------------------*
*       F4 help for file path
*----------------------------------------------------------------------*
FORM sub_file_f4 .
  DATA:
  l_desktop       TYPE string,
  l_i_files       TYPE filetable,
  l_wa_files      TYPE file_table,
  l_rcode         TYPE int4.
 
* Finding desktop
  CALL METHOD cl_gui_frontend_services=>get_desktop_directory
    CHANGING
      desktop_directory    = l_desktop
    EXCEPTIONS
      cntl_error           = 1
      error_no_gui         = 2
      not_supported_by_gui = 3
      OTHERS               = 4.
  IF sy-subrc <> 0.
    MESSAGE e001(00) WITH
    'Desktop not found'.
  ENDIF.
 
* Update View
  CALL METHOD cl_gui_cfw=>update_view
    EXCEPTIONS
      cntl_system_error = 1
      cntl_error        = 2
      OTHERS            = 3.
 
  CALL METHOD cl_gui_frontend_services=>file_open_dialog
    EXPORTING
      window_title            = 'Select Excel file'
      default_extension       = '.xls'
      file_filter             = '.xls'
      initial_directory       = l_desktop
    CHANGING
      file_table              = l_i_files
      rc                      = l_rcode
    EXCEPTIONS
      file_open_dialog_failed = 1
      cntl_error              = 2
      error_no_gui            = 3
      not_supported_by_gui    = 4
      OTHERS                  = 5.
  IF sy-subrc <> 0.
    MESSAGE e001(00) WITH 'Error while opening file'.
  ENDIF.
 
  READ TABLE l_i_files INDEX 1 INTO l_wa_files.
  IF sy-subrc = 0.
    p_file = l_wa_files-filename.
  ELSE.
    MESSAGE e001(00) WITH 'Error while opening file'.
  ENDIF.
 
ENDFORM.                    " SUB_FILE_F4

How to display a picture in a SAP screen

2008-10-01T19:05:00.010+05:30

Step 1)Check what extensions are allowed in table "MIMITYPES".

Step 2)Modify the file extension of the picture from ".jpg" etc. to ".html"(any of the allowed MIME types from the previous step).

Step 3)Upload a picture through transaction SMW0 by creating a new "Z" object (you can save it in a transport if you want):

Step 4) Create a program as shown below with a Screen 0100, PF-STATUS "S0100" and Custom Container "CONT" . This program can be used to display any of the pictures uploaded through SMW0.

*&---------------------------------------------------------------------*
*& Report  ZTEST_PICTURE
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*
 
REPORT  ztest_picture.
TYPE-POOLS: cndp.
DATA: ok_code TYPE syucomm,
container TYPE REF TO cl_gui_custom_container,
picture   TYPE REF TO cl_gui_picture,
url       TYPE cndp_url.
 
 
PARAMETERS: p_objid TYPE w3objid OBLIGATORY.
 
AT SELECTION-SCREEN.
  SELECT COUNT(*) FROM wwwparams
  WHERE objid = p_objid.
  IF sy-subrc <> 0.
    MESSAGE e001(00) WITH 'MIME Object not found'.
  ENDIF.
 
 
START-OF-SELECTION.
 
  IF container IS INITIAL.
 
    CREATE OBJECT container
      EXPORTING
        container_name              = 'CONT'
        repid                       = 'ZTEST_PICTURE'
        dynnr                       = '0100'
      EXCEPTIONS
        cntl_error                  = 1
        cntl_system_error           = 2
        create_error                = 3
        lifetime_error              = 4
        lifetime_dynpro_dynpro_link = 5
        OTHERS                      = 6.
    IF sy-subrc <> 0.
      MESSAGE i001(00) WITH 'Error while creating container'.
      LEAVE LIST-PROCESSING.
    ENDIF.
  ENDIF.
  IF picture IS INITIAL.
    CREATE OBJECT picture
      EXPORTING
        parent = container
      EXCEPTIONS
        error  = 1
        OTHERS = 2.
    IF sy-subrc <> 0.
      MESSAGE i001(00) WITH 'Error while displaying picture'.
      LEAVE LIST-PROCESSING.
    ENDIF.
  ENDIF.
  IF picture IS NOT INITIAL.
 
    CALL FUNCTION 'DP_PUBLISH_WWW_URL'
      EXPORTING
        objid    = p_objid
        lifetime = cndp_lifetime_transaction
      IMPORTING
        url      = url
      EXCEPTIONS
        OTHERS   = 1.
 
    IF sy-subrc = 0.
      CALL METHOD picture->load_picture_from_url_async
        EXPORTING
          url = url.
 
      CALL METHOD picture->set_display_mode
        EXPORTING
          display_mode = cl_gui_picture=>display_mode_fit.
    ELSE.
      MESSAGE i001(00) WITH 'Error while load picture'.
      LEAVE LIST-PROCESSING.
    ENDIF.
  ENDIF.
 
  CALL SCREEN 0100.
*&---------------------------------------------------------------------*
*&      Module  STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE status_0100 OUTPUT.
  SET PF-STATUS 'S0100'.
*  SET TITLEBAR 'xxx'.
 
ENDMODULE.                 " STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_0100  INPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE user_command_0100 INPUT.
  CASE ok_code.
    WHEN 'BACK'.
      SET SCREEN 00.
      LEAVE SCREEN.
  ENDCASE.
ENDMODULE.                 " USER_COMMAND_0100  INPUT

Test it :

Display multiple list under same list using FM REUSE_ALV_BLOCK_LIST_DISPLAY

2008-09-30T02:05:00.006+05:30

Display Multiple lists under a same list display using FM: "REUSE_ALV_BLOCK_LIST_DISPLAY". We have to call four function modules in sequence to achieve this:
1)REUSE_ALV_BLOCK_LIST_INIT
2)REUSE_ALV_BLOCK_LIST_APPEND
3)then again REUSE_ALV_BLOCK_LIST_APPEND
4)At last REUSE_ALV_BLOCK_LIST_DISPLAY

*&---------------------------------------------------------------------*
*& Report  ZZSOURAV_MULTIPLE_LIST
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*

REPORT  zzsourav_multiple_list.
TYPE-POOLS:slis.

DATA:
v_repid TYPE syrepid,
i_spfli TYPE STANDARD TABLE OF spfli INITIAL SIZE 0,
i_scarr TYPE STANDARD TABLE OF scarr INITIAL SIZE 0,
i_fcat1 TYPE slis_t_fieldcat_alv,
i_fcat2 TYPE slis_t_fieldcat_alv,
wa_layout1 TYPE slis_layout_alv,
wa_layout2 TYPE slis_layout_alv,
i_events1 TYPE slis_t_event,
i_events2 TYPE slis_t_event.

INITIALIZATION.
v_repid = sy-repid.

START-OF-SELECTION.

SELECT * FROM spfli
INTO TABLE i_spfli.
IF sy-subrc <> 0.
MESSAGE i001(00) WITH 'No data found!'.
LEAVE LIST-PROCESSING.
ENDIF.

SELECT * FROM scarr
INTO TABLE i_scarr.

IF sy-subrc <> 0.
MESSAGE i001(00) WITH 'No data found!'.
LEAVE LIST-PROCESSING.
ENDIF.

CALL FUNCTION 'REUSE_ALV_FIELDCATALOG_MERGE'
EXPORTING
  i_program_name               = v_repid
  i_internal_tabname           = 'I_SCARR'
  i_structure_name             = 'SCARR'
  i_client_never_display       = 'X'
*     I_INCLNAME                   =
*     I_BYPASSING_BUFFER           =
*     I_BUFFER_ACTIVE              =
   CHANGING
  ct_fieldcat                  = i_fcat1
EXCEPTIONS
 inconsistent_interface       = 1
 program_error                = 2
 OTHERS                       = 3
        .
IF sy-subrc <> 0.
MESSAGE i001(00) WITH 'Unable to populate field-catalog!'.
LEAVE LIST-PROCESSING.
ENDIF.

CALL FUNCTION 'REUSE_ALV_FIELDCATALOG_MERGE'
EXPORTING
  i_program_name               = v_repid
  i_internal_tabname           = 'I_SPFLI'
  i_structure_name             = 'SPFLI'
  i_client_never_display       = 'X'
*     I_INCLNAME                   =
*     I_BYPASSING_BUFFER           =
*     I_BUFFER_ACTIVE              =
   CHANGING
  ct_fieldcat                  = i_fcat2
EXCEPTIONS
 inconsistent_interface       = 1
 program_error                = 2
 OTHERS                       = 3
        .
IF sy-subrc <> 0.
MESSAGE i001(00) WITH 'Unable to populate field-catalog!'.
LEAVE LIST-PROCESSING.
ENDIF.

END-OF-SELECTION.
wa_layout1-colwidth_optimize = wa_layout2-colwidth_optimize = 'X'.
wa_layout1-zebra = wa_layout2-zebra = 'X'.

CALL FUNCTION 'REUSE_ALV_BLOCK_LIST_INIT'
EXPORTING
  i_callback_program             = v_repid
*   I_CALLBACK_PF_STATUS_SET       = ' '
*   I_CALLBACK_USER_COMMAND        = ' '
*   IT_EXCLUDING                   =
           .


CALL FUNCTION 'REUSE_ALV_BLOCK_LIST_APPEND'
EXPORTING
  is_layout                        = wa_layout1
  it_fieldcat                      = i_fcat1
  i_tabname                        = 'I_SCARR'
  it_events                        = i_events1
*   IT_SORT                          =
*   I_TEXT                           = ' '
TABLES
  t_outtab                         = i_scarr
EXCEPTIONS
 program_error                    = 1
 maximum_of_appends_reached       = 2
 OTHERS                           = 3
        .
IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.


CALL FUNCTION 'REUSE_ALV_BLOCK_LIST_APPEND'
EXPORTING
  is_layout                        = wa_layout2
  it_fieldcat                      = i_fcat2
  i_tabname                        = 'I_SPFLI'
  it_events                        =  i_events2
*   IT_SORT                          =
*   I_TEXT                           = ' '
TABLES
  t_outtab                         = i_spfli
EXCEPTIONS
 program_error                    = 1
 maximum_of_appends_reached       = 2
 OTHERS                           = 3
        .
IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.

CALL FUNCTION 'REUSE_ALV_BLOCK_LIST_DISPLAY'
*   EXPORTING
*     I_INTERFACE_CHECK             = ' '
*     IS_PRINT                      =
*     I_SCREEN_START_COLUMN         = 0
*     I_SCREEN_START_LINE           = 0
*     I_SCREEN_END_COLUMN           = 0
*     I_SCREEN_END_LINE             = 0
*   IMPORTING
*     E_EXIT_CAUSED_BY_CALLER       =
*     ES_EXIT_CAUSED_BY_USER        =
EXCEPTIONS
 program_error                 = 1
 OTHERS                        = 2
        .
IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
ENDIF.

The Output:

How to get the updated data from a editable ALV (CL_GUI_ALV_GRID)

2008-09-27T14:04:00.017+05:30

This program demonstrates how to get the updated data when a button is clicked in the GUI toolbar or ALV toolbar. The ALV is created using CL_GUI_ALV_GRID.

*&---------------------------------------------------------------------*
*& Report  ZZSOURAV_REFRESH_ALV
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*
 
REPORT  zzsourav_refresh_alv.
DATA: ok_code TYPE syucomm.
*----------------------------------------------------------------------*
*       CLASS main DEFINITION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS main DEFINITION.
  PUBLIC SECTION.
    DATA: i_sbook TYPE STANDARD TABLE OF sbook INITIAL SIZE 0,
          i_sbook_old TYPE STANDARD TABLE OF sbook INITIAL SIZE 0.
 
    METHODS:constructor,
            handle_toolbar FOR EVENT toolbar OF cl_gui_alv_grid
            IMPORTING e_object e_interactive,
            handle_user_command FOR EVENT
            user_command OF cl_gui_alv_grid
            IMPORTING e_ucomm,
            check_changed_data.
  PROTECTED SECTION.
 
 
  PRIVATE SECTION.
    TYPE-POOLS: icon.
    DATA:container TYPE REF TO cl_gui_custom_container,
          oref_alv TYPE REF TO cl_gui_alv_grid,
          wa_layout TYPE lvc_s_layo,
          i_fieldcatalog TYPE lvc_t_fcat.
    METHODS:get_field_catalog,get_layout.
ENDCLASS.                    "main DEFINITION
*----------------------------------------------------------------------*
*       CLASS main IMPLEMENTATION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS main IMPLEMENTATION.
  METHOD constructor.
 
    SELECT * FROM sbook INTO TABLE i_sbook
      UP TO 50 ROWS.
    i_sbook_old[] = i_sbook[].
 
    CREATE OBJECT container
      EXPORTING
*       parent                      =
        container_name              = 'CONT1'
*       style                       =
*       lifetime                    = lifetime_default
        repid                       = sy-repid
        dynnr                       = '0100'
*       no_autodef_progid_dynnr     =
      EXCEPTIONS
        cntl_error                  = 1
        cntl_system_error           = 2
        create_error                = 3
        lifetime_error              = 4
        lifetime_dynpro_dynpro_link = 5
        OTHERS                      = 6
        .
    IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
 
 
    CREATE OBJECT oref_alv
      EXPORTING
*        i_shellstyle      = 0
*        i_lifetime        =
         i_parent          = container
*        i_appl_events     = space
*        i_parentdbg       =
*        i_applogparent    =
*        i_graphicsparent  =
*        i_name            =
*        i_fcat_complete   = space
      EXCEPTIONS
        error_cntl_create = 1
        error_cntl_init   = 2
        error_cntl_link   = 3
        error_dp_create   = 4
        OTHERS            = 5
        .
    IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
 
    CALL METHOD me->get_field_catalog.
    CALL METHOD me->get_layout.
 
    CALL METHOD oref_alv->set_table_for_first_display
      EXPORTING
*       i_buffer_active               =
*       i_bypassing_buffer            =
*       i_consistency_check           =
*       i_structure_name              =
*       is_variant                    =
*       i_save                        =
*       i_default                     = 'X'
        is_layout                     = wa_layout
*       is_print                      =
*       it_special_groups             =
*       it_toolbar_excluding          =
*       it_hyperlink                  =
*       it_alv_graphics               =
*       it_except_qinfo               =
*       ir_salv_adapter               =
      CHANGING
        it_outtab                     = i_sbook
        it_fieldcatalog               = i_fieldcatalog
*       it_sort                       =
*       it_filter                     =
      EXCEPTIONS
        invalid_parameter_combination = 1
        program_error                 = 2
        too_many_lines                = 3
        OTHERS                        = 4
            .
    IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*            WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
    SET HANDLER me->handle_toolbar FOR oref_alv.
    SET HANDLER me->handle_user_command FOR oref_alv.
 
    CALL METHOD oref_alv->set_toolbar_interactive.
 
  ENDMETHOD.                    "constructor
  METHOD get_layout.
    wa_layout-cwidth_opt = 'X'.
  ENDMETHOD.                    "get_layout
  METHOD get_field_catalog.
    FIELD-SYMBOLS: <lf1> TYPE lvc_s_fcat.
 
    CALL FUNCTION 'LVC_FIELDCATALOG_MERGE'
      EXPORTING
*       I_BUFFER_ACTIVE              =
        i_structure_name             = 'SBOOK'
        i_client_never_display       = 'X'
*       I_BYPASSING_BUFFER           =
        i_internal_tabname           = 'I_SBOOK'
      CHANGING
        ct_fieldcat                  = i_fieldcatalog
      EXCEPTIONS
        inconsistent_interface       = 1
        program_error                = 2
        OTHERS                       = 3
              .
    IF sy-subrc <> 0.
* MESSAGE ID SY-MSGID TYPE SY-MSGTY NUMBER SY-MSGNO
*         WITH SY-MSGV1 SY-MSGV2 SY-MSGV3 SY-MSGV4.
    ENDIF.
 
    LOOP AT i_fieldcatalog ASSIGNING <lf1>.
      IF <lf1>-fieldname = 'SMOKER'.
        <lf1>-edit = 'X'.  " REUSE_ALV_GRID_DISPLAY
      ENDIF.
    ENDLOOP.
  ENDMETHOD.                    "get_field_catalog
  METHOD handle_toolbar.
    DATA: l_toolbar  TYPE stb_button.
    CLEAR l_toolbar.
* append an icon to show booking table
    CLEAR l_toolbar.
    MOVE 'SAVE' TO l_toolbar-function.
    MOVE icon_system_save TO l_toolbar-icon.
    MOVE 'Save' TO l_toolbar-quickinfo.
    MOVE 'Save' TO l_toolbar-text.
    MOVE ' ' TO l_toolbar-disabled.
    APPEND l_toolbar TO e_object->mt_toolbar.
 
  ENDMETHOD.                    "handle_toolbar
  METHOD handle_user_command.
    CASE e_ucomm.
      WHEN 'SAVE'.
        IF i_sbook[] <> i_sbook_old[].
          MESSAGE i001(00) WITH 'You have changed some data'.
        ELSE.
          MESSAGE i001(00) WITH 'No data changed'.
        ENDIF.
    ENDCASE.
  ENDMETHOD.                    "user_command
  METHOD check_changed_data.
 
    CALL METHOD oref_alv->check_changed_data
*      IMPORTING
*        e_valid   =
*      CHANGING
*        c_refresh = 'X'
        .
 
 
  ENDMETHOD.                    "CHECK_CHANGED_DATA
ENDCLASS.                    "main IMPLEMENTATION
 
START-OF-SELECTION.
 
  DATA: oref_main TYPE REF TO main.
  CREATE OBJECT oref_main.
 
  CALL SCREEN 0100.
*&---------------------------------------------------------------------*
*&      Module  STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE status_0100 OUTPUT.
  SET PF-STATUS 'S0100'.
*  SET TITLEBAR 'xxx'.
 
ENDMODULE.                 " STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_0100  INPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE user_command_0100 INPUT.
 
  CASE ok_code.
    WHEN 'BACK'.
 
      SET SCREEN 00.
      LEAVE SCREEN.
    WHEN 'SAVE'.
      " Check this part if the button is SAP standard toolbar
      CALL METHOD oref_main->check_changed_data.
      IF oref_main->i_sbook[] NE oref_main->i_sbook_old[].
        MESSAGE i001(00) WITH 'You have changed some data'.
      ELSE.
        MESSAGE i001(00) WITH 'No data changed'.
      ENDIF.
 
  ENDCASE.
ENDMODULE.                 " USER_COMMAND_0100  INPUT

Initial ALV display with editable column:

When any of the "SAVE" button is clicked but no changed data:

When something is changed and any of the "SAVE" button is clicked:

Displaying fields as BUTTONS and Raising an event in ALV

2008-08-23T13:45:00.043+05:30

This code demonstrates how to display fields in ALV as a button.

on clicking a button..

The Code:

*&---------------------------------------------------------------------*
*&Program: ZTEST_SDN
*&Creation Date: 23.08.2008 14:11:22
*&---------------------------------------------------------------------*
*& Demo Program for blog http://abap-explorer.blogspot.com/
*&---------------------------------------------------------------------*
REPORT  z_sb_column_as_pushbutton.
 
TYPE-POOLS:cntl,icon.
 
TYPES:
BEGIN OF x_final,
carrid  TYPE s_carr_id,
carrname  TYPE s_carrname,
END OF x_final.
 
DATA: i_final TYPE STANDARD TABLE OF x_final INITIAL SIZE 0,
i_fieldcat TYPE lvc_t_fcat,
wa_layout TYPE lvc_s_layo,
ok_code TYPE syucomm,
oref_alv TYPE REF TO cl_gui_alv_grid.
field-symbols: <f1> type any.
*----------------------------------------------------------------------*
*       CLASS lcl_event_handlers DEFINITION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS lcl_event_handlers DEFINITION.
PUBLIC SECTION.
METHODS:handle_button_click FOR EVENT button_click OF cl_gui_alv_grid
      IMPORTING es_col_id  es_row_no.
ENDCLASS.                    "lcl_event_handlers DEFINITION
*----------------------------------------------------------------------*
*       CLASS lcl_event_handlers IMPLEMENTATION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS lcl_event_handlers IMPLEMENTATION.
METHOD handle_button_click.
DATA l_row TYPE c LENGTH 10.
l_row = es_row_no-row_id.
MESSAGE i001(00) WITH 'You have clicked on column :'
ES_COL_ID-FIELDNAME ',row:' l_row.
ENDMETHOD.                    "handle_button_click
ENDCLASS.                    "lcl_event_handlers IMPLEMENTATION
 
 
START-OF-SELECTION.
 
PERFORM get_data.
 
END-OF-SELECTION.
 
PERFORM build_field_catalog USING: 'CARRID' 'CARRID' 'SCARR',
                               'CARRNAME' 'CARRNAME' 'SCARR'.
PERFORM populate_layout.
 
PERFORM display_alv.
 
*&---------------------------------------------------------------------*
*&      Form  get_data
*&---------------------------------------------------------------------*
*       Get data
*----------------------------------------------------------------------*
FORM get_data .
 
SELECT carrid carrname FROM scarr
INTO TABLE i_final
UP TO 200 ROWS.
IF sy-subrc NE 0.
 
MESSAGE i001(00) WITH 'No data found'.
LEAVE LIST-PROCESSING.
ENDIF.
 
ENDFORM.                    " get_data
*&---------------------------------------------------------------------*
*&      Form  build_field_catalog
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->P_FIELDNAME  Fieldname
*      -->P_REF_FIELD  Reference Field
*      -->P_REF_TAB    Reference Table
*----------------------------------------------------------------------*
FORM build_field_catalog USING
            p_fieldname TYPE lvc_fname
            p_ref_field TYPE lvc_rfname
            p_ref_tab   TYPE lvc_rtname.
 
DATA:l_fieldcat TYPE lvc_s_fcat.
 
l_fieldcat-fieldname = p_fieldname.
l_fieldcat-tabname   = 'I_FINAL'.
l_fieldcat-ref_field = p_ref_field.
l_fieldcat-ref_table = p_ref_tab.
IF p_fieldname = 'CARRID'.
l_fieldcat-style = cl_gui_alv_grid=>mc_style_button.
ENDIF.
 
APPEND l_fieldcat TO i_fieldcat.
ENDFORM.                    " build_field_catalog
*&---------------------------------------------------------------------*
*&      Form  populate_layout
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM populate_layout.
wa_layout-zebra = 'X'.
ENDFORM.                    "populate_layout
*&---------------------------------------------------------------------*
*&      Form  display_alv
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
FORM display_alv.
 
DATA: l_repid TYPE syrepid VALUE sy-repid,
  oref_handlers TYPE REF TO lcl_event_handlers.
DATA l_wa_event TYPE cntl_simple_event.
IF oref_alv IS NOT BOUND.
 
CREATE OBJECT oref_alv
EXPORTING
*    i_shellstyle      = 0
*    i_lifetime        =
  i_parent          = cl_gui_container=>screen0
*    i_appl_events     = space
*    i_parentdbg       =
*    i_applogparent    =
*    i_graphicsparent  =
*    i_name            =
*    i_fcat_complete   = space
EXCEPTIONS
error_cntl_create = 1
error_cntl_init   = 2
error_cntl_link   = 3
error_dp_create   = 4
OTHERS            = 5
  .
IF sy-subrc = 0.
 
CREATE OBJECT oref_handlers.
SET HANDLER oref_handlers->handle_button_click FOR oref_alv.
 
CALL METHOD oref_alv->set_table_for_first_display
  EXPORTING
*         i_buffer_active               =
*         i_bypassing_buffer            =
*         i_consistency_check           =
*         i_structure_name              =
*         is_variant                    =
*         i_save                        =
*         i_default                     = 'X'
   is_layout                     = wa_layout
*        is_print                      =
*        it_special_groups             =
*        it_toolbar_excluding          =
*        it_hyperlink                  =
*        it_alv_graphics               =
*        it_except_qinfo               =
*        ir_salv_adapter               =
   CHANGING
    it_outtab                     = i_final
    it_fieldcatalog               = i_fieldcat
*         it_sort                       =
*         it_filter                     =
  EXCEPTIONS
    invalid_parameter_combination = 1
    program_error                 = 2
    too_many_lines                = 3
    OTHERS                        = 4
               .
IF sy-subrc <> 0.
  MESSAGE e001(00) WITH 'Error while ALV display'.
ENDIF.
ENDIF.
ENDIF.
CALL SCREEN 0100.
 
ENDFORM.                    "display_alv
*&---------------------------------------------------------------------*
*&      Module  STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE status_0100 OUTPUT.
SET PF-STATUS '0100'.
SET TITLEBAR '0100'.
 
ENDMODULE.                 " STATUS_0100  OUTPUT
*&---------------------------------------------------------------------*
*&      Module  USER_COMMAND_0100  INPUT
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
MODULE user_command_0100 INPUT.
CASE ok_code.
WHEN 'BACK'.
CLEAR ok_code.
SET SCREEN 00.
LEAVE SCREEN.
 
ENDCASE.
ENDMODULE.                 " USER_COMMAND_0100  INPUT

HTML through ABAP

2008-08-20T22:26:00.013+05:30

This code demonstrates how to write HTML code and raise SAP event in ABAP.

The Code:

*&---------------------------------------------------------------------*
*&Program: Z_TEST_SOURAV_HTML
*&Creation Date: 20.08.2008 22:08:32
*&---------------------------------------------------------------------*
*& Demo Program for blog http://abap-explorer.blogspot.com/
*&---------------------------------------------------------------------*
REPORT  z_test_sourav_html.
*----------------------------------------------------------------------*
*       CLASS lcl_class DEFINITION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS lcl_class DEFINITION.
PUBLIC SECTION.
 METHODS:
 main,
 on_html_event FOR EVENT sapevent OF cl_gui_html_viewer
  IMPORTING action frame getdata.
PROTECTED SECTION.

PRIVATE SECTION.
 DATA oref TYPE REF TO cl_gui_html_viewer.
ENDCLASS.                    "lcl_class DEFINITION
*----------------------------------------------------------------------*
*       CLASS lcl_class IMPLEMENTATION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*
CLASS lcl_class IMPLEMENTATION.
METHOD main.
 DATA oref_lcl TYPE REF TO lcl_class.
 DATA html TYPE w3htmltab.
 DATA url  TYPE c LENGTH 255.
 CREATE OBJECT oref
   EXPORTING
     parent = cl_gui_container=>screen0.

 DATA events TYPE cntl_simple_events.
 DATA event TYPE cntl_simple_event.

 event-eventid = oref->m_id_sapevent.
 event-appl_event = 'X'.
 APPEND event TO events.

 CALL METHOD oref->set_registered_events
   EXPORTING
     events = events.
 SET HANDLER me->on_html_event FOR oref.

 APPEND '<html>'                       TO html.
 APPEND '<body bgcolor= "#FFFFCC">'    TO html.
 APPEND '<font face="arial" size="2">' TO html.
 APPEND '<b>Header</b>'                TO html.
 APPEND '<br>'                         TO html.
 APPEND 'Text'                         TO html.
 APPEND '</font>'                      TO html.
 APPEND '<form name= "form1" action="SAPEVENT:save">' TO html.
 APPEND 'First name:'                  TO html.
 APPEND '<input type="text" name="firstname">' TO html.
 APPEND '<br>'                         TO html.
 APPEND 'Last name: '                  TO html.
 APPEND '<input type="text" name="lastname">'  TO html.
 APPEND '<br>'                         TO html.
 APPEND '<input type="submit" value="Submit">' TO html.
 APPEND '</form>'                      TO html.
 APPEND '</body>'                      TO html.
 APPEND '</html>'                      TO html.
 oref->load_data( IMPORTING assigned_url = url
                  CHANGING data_table = html ).
 oref->show_url( url = url ).
ENDMETHOD.                    "main
METHOD on_html_event.
 DATA:l_string TYPE string.
 l_string = getdata.

 MESSAGE i001(00) WITH l_string.
ENDMETHOD.                    "on_html_event
ENDCLASS.                    "lcl_class IMPLEMENTATION

PARAMETERS: p_dummy TYPE c LENGTH 1.
AT SELECTION-SCREEN OUTPUT.
DATA:lcl_oref TYPE REF TO lcl_class.
IF lcl_oref IS NOT BOUND.
 CREATE OBJECT lcl_oref.
 CALL METHOD lcl_oref->main.
ENDIF.

Toolbar for a Custom Container

2008-08-20T12:41:00.011+05:30

This code demonstrates how we can create a toolbar for Custom Container...I've used a Docking Container.

The Code:

*&---------------------------------------------------------------------*
*&Program: ZTEST_DOCKING
*&Creation Date: 20.08.2008 12:43:57
*&---------------------------------------------------------------------*
*& Demo Program for blog http://abap-explorer.blogspot.com/
*&---------------------------------------------------------------------*

REPORT  ztest_docking.

TYPE-POOLS:icon.

DATA: docking  TYPE REF TO cl_gui_docking_container,
   splitter TYPE REF TO cl_gui_easy_splitter_container,
   toolbar  TYPE REF TO cl_gui_toolbar,
   picture TYPE REF TO cl_gui_picture,
   events   TYPE cntl_simple_events,
   event    TYPE cntl_simple_event,
   url  TYPE cndp_url.

*----------------------------------------------------------------------*
*       CLASS lcl_class DEFINITION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*

CLASS lcl_class DEFINITION.

PUBLIC SECTION.

 METHODS:handle_toolbar_selection

 FOR EVENT function_selected OF cl_gui_toolbar
   IMPORTING fcode .

ENDCLASS.                    "lcl_class DEFINITION

*----------------------------------------------------------------------*
*       CLASS lcl_class IMPLEMENTATION
*----------------------------------------------------------------------*
*
*----------------------------------------------------------------------*

CLASS lcl_class IMPLEMENTATION.

METHOD handle_toolbar_selection.

 CASE fcode.

   WHEN 'FIND'.

     MESSAGE i001(00) WITH 'You have clicked "FIND" button'.

   WHEN 'FINDNX'.

     MESSAGE i001(00) WITH 'You have clicked "FINDNX" button'.

   WHEN OTHERS.

 ENDCASE.
ENDMETHOD.                    "handle_toolbar_selection
ENDCLASS.                    "lcl_class IMPLEMENTATION

PARAMETERS : p_para TYPE c LENGTH 1.
DATA:oref TYPE REF TO lcl_class.

AT SELECTION-SCREEN OUTPUT.

IF docking IS NOT BOUND.

 CREATE OBJECT docking
    EXPORTING
*      parent                      =
      repid                       = sy-repid
      dynnr                       = sy-dynnr
      side                        = docking->dock_at_left
      extension                   = 1000
*      style                       =
*      lifetime                    = lifetime_default
*      caption                     =
*      metric                      = 0
*      ratio                       =
*      no_autodef_progid_dynnr     =
*      name                        =
     EXCEPTIONS
       cntl_error                  = 1
       cntl_system_error           = 2
       create_error                = 3
       lifetime_error              = 4
       lifetime_dynpro_dynpro_link = 5
       OTHERS                      = 6
       .
 IF sy-subrc = 0.

CREATE OBJECT splitter
EXPORTING
*    link_dynnr        =
*    link_repid        =
*    metric            = cntl_metric_dynpro
        parent            = docking
*    orientation       = 0
        sash_position     = 4
*    with_border       = 1
*    name              =
      EXCEPTIONS
        cntl_error        = 1
        cntl_system_error = 2
        OTHERS            = 3
        .
   IF sy-subrc = 0.

     CREATE OBJECT toolbar
       EXPORTING
         parent             = splitter->top_left_container
*    shellstyle         =
*    lifetime           =
*    display_mode       = m_mode_horizontal
*    name               =
       EXCEPTIONS
         cntl_install_error = 1
         cntl_error         = 2
         cntb_wrong_version = 3
         OTHERS             = 4
         .

     IF sy-subrc = 0.

       DATA: l_quickinfo TYPE iconquick.

       l_quickinfo = 'Find'.
       CALL METHOD toolbar->add_button
         EXPORTING
           fcode     = 'FIND'
           icon      = icon_search
           quickinfo = l_quickinfo
           butn_type = cntb_btype_button.


       l_quickinfo = 'Find next'.

       CALL METHOD toolbar->add_button
         EXPORTING
           fcode     = 'FINDNX'
           icon      = icon_search_next
           quickinfo = l_quickinfo
           butn_type = cntb_btype_button.

       CLEAR event.
       REFRESH events.

       event-eventid = toolbar->m_id_function_selected.
       event-appl_event = space.     " system event

       APPEND event TO events.

       CALL METHOD toolbar->set_registered_events
         EXPORTING
           events = events.

       CREATE OBJECT oref.
       SET HANDLER oref->handle_toolbar_selection
                   FOR toolbar.

       IF picture IS NOT BOUND.
         CREATE OBJECT picture
           EXPORTING
*       lifetime =
*       shellstyle =
             parent = splitter->bottom_right_container
*       name   =
          EXCEPTIONS
             error  = 1
             OTHERS = 2
             .

         IF sy-subrc <> 0.
           MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
                      WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
         ENDIF.

         CALL METHOD picture->set_display_mode
           EXPORTING
             display_mode = cl_gui_picture=>display_mode_normal
           EXCEPTIONS
             error        = 1
             OTHERS       = 2.
         IF sy-subrc <> 0.
           MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
                      WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
         ENDIF.

         CALL FUNCTION 'DP_PUBLISH_WWW_URL'
           EXPORTING
             objid                 = 'DOCFINDER_LOGO'
             lifetime              = cndp_lifetime_transaction
           IMPORTING
             url                   = url
           EXCEPTIONS
             dp_invalid_parameters = 1
             no_object             = 2
             dp_error_publish      = 3
             OTHERS                = 4.
         IF sy-subrc = 0.
           CALL METHOD picture->load_picture_from_url_async
             EXPORTING
               url    = url
             EXCEPTIONS
               error  = 1
               OTHERS = 2.

           IF sy-subrc <> 0.
*        MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
*                   WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
           ENDIF.
         ENDIF.
       ENDIF.
     ENDIF.
   ENDIF.
 ENDIF.
ENDIF.

Create a SELECT-OPTIONS in a module pool screen

2008-08-02T21:51:00.010+05:30

Create a SELECT-OPTIONS in module pool screen using two methods as shown.

Method 1

a) Create a subscreen area in your screen layout where you want to create the select options.
b) In the top include of your module pool program declare a selection screen as a subscreen e.g.

SELECTION-SCREEN BEGIN OF SCREEN 100 AS SUBSCREEN.
 
      select-options s_matnr for mara-matnr.
 
SELECTION-SCREEN END OF SCREEN.

c) In the PBO and PAI of the main screen where the select options needs to be created do a call subscreen of the above screen (100).


CALL SUBCREEN sub_area INCLUDING  <program>   <screen>

This CALL SUBSCREEN statement is necessary for transport of values between screen and program.

Note: All validations of the selection screen fields e.g. the s_matnr field created above should be done in selection screen events like AT SELECTION-SCREEN etc and not in PAI. These selection screen validations etc should be done in the top include only.

Method 2

a) Create 2 separate fields in your screen layout - one for the low value and one for the high value. Insert an icon beside the high value which will call the multiple selections popup screen on user command. Use function module COMPLEX_SELECTIONS_DIALOG to achieve this.

struc_tab_and_field-fieldname = con_cust.  " 'KUNNR'
struc_tab_and_field-tablename = con_kna1.  " 'KNA1'.

CALL FUNCTION 'COMPLEX_SELECTIONS_DIALOG'
  EXPORTING
*          TITLE                        = ' '
    text                         = g_titl1   " 'Customers'
    tab_and_field                = struc_tab_and_field
  TABLES
    RANGE                        = rng_kunnr
  EXCEPTIONS
    NO_RANGE_TAB                 = 1
    CANCELLED                    = 2
    INTERNAL_ERROR               = 3
    INVALID_FIELDNAME            = 4
    OTHERS                       = 5.

IF NOT rng_kunnr[] IS INITIAL.

*          Read the very first entry of the range table and pass it to
*          dynpro screen field

   READ TABLE rng_kunnr INDEX 1.
   IF sy-subrc = 0.
      g_cust = rng_kunnr-low.
   ENDIF.
ENDIF.

You can use the return table rng_kunnr to populate your own internal range table with the values entered by the user. Basically here you are just simulating the work of a select-options parameter by module pool screen elements.

Populate a screen field without triggering PAI using FM DYNP_VALUES_UPDATE

2008-07-26T13:49:00.011+05:30

This program demonstrates how to populate a screen field depending upon another field without triggering PAI using FM DYNP_VALUES_UPDATE.

The Code:

*&---------------------------------------------------------------------*
*&Program: Z_TEST_PROGRAM
*&Creation Date: 26.07.2008 12:54:08
*&---------------------------------------------------------------------*
*& Test program for blog http://abap-explorer.blogspot.com/
*&---------------------------------------------------------------------*
REPORT  z_test_program1.
 
PARAMETERS:
p_name TYPE uname,
p_ctry TYPE char2.
 
AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_name.
 
PERFORM sub_populate_f4_help USING 'P_NAME'.
 
START-OF-SELECTION.
 
END-OF-SELECTION.
 
*&---------------------------------------------------------------------*
*&      Form  sub_populate_f4_help
*&---------------------------------------------------------------------*
*       text
*----------------------------------------------------------------------*
*      -->P_RETFIELD text
*----------------------------------------------------------------------*
FORM sub_populate_f4_help USING p_retfield TYPE dynfnam.
TYPES:
BEGIN OF l_x_names,
  uname TYPE uname,
END OF l_x_names.
 
DATA:
l_i_names TYPE STANDARD TABLE OF l_x_names INITIAL SIZE 0,
l_wa_names TYPE l_x_names,
l_i_field_tab TYPE STANDARD TABLE OF dfies INITIAL SIZE 0,
l_i_return_tab TYPE STANDARD TABLE OF ddshretval INITIAL SIZE 0,
l_wa_return_tab TYPE ddshretval,
l_i_dynpfld_mapping TYPE STANDARD TABLE OF dselc INITIAL SIZE 0.
 
l_wa_names-uname = 'TEST1'.
APPEND l_wa_names TO l_i_names.
l_wa_names-uname = 'TEST2'.
APPEND l_wa_names TO l_i_names.
l_wa_names-uname = 'TEST3'.
APPEND l_wa_names TO l_i_names.
l_wa_names-uname = 'TEST4'.
APPEND l_wa_names TO l_i_names.
 
 
CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
  EXPORTING
    retfield        = 'UNAME'
    dynpprog        = sy-repid
    dynpnr          = sy-dynnr
    dynprofield     = p_retfield
    value_org       = 'S'
  TABLES
    value_tab       = l_i_names
    field_tab       = l_i_field_tab
    return_tab      = l_i_return_tab
    dynpfld_mapping = l_i_dynpfld_mapping
  EXCEPTIONS
    parameter_error = 1
    no_values_found = 2
    OTHERS          = 3.
IF sy-subrc = 0.
  READ TABLE l_i_return_tab INTO l_wa_return_tab INDEX 1.
  p_name = l_wa_return_tab-fieldval.
ELSE.
  MESSAGE e001(00) WITH 'Error while displaying F4 help'.
ENDIF.
 
DATA: l_i_dynpfields  TYPE STANDARD TABLE OF dynpread INITIAL SIZE 0,
      l_wa_dynpfields TYPE dynpread.
IF p_name = 'TEST1'.
  l_wa_dynpfields-fieldname = 'P_CTRY'.
  l_wa_dynpfields-fieldvalue = 'IN'.
  APPEND l_wa_dynpfields TO l_i_dynpfields.
ELSE.
  l_wa_dynpfields-fieldname = 'P_CTRY'.
  CLEAR l_wa_dynpfields-fieldvalue.
  APPEND l_wa_dynpfields TO l_i_dynpfields.
ENDIF.
 
CALL FUNCTION 'DYNP_VALUES_UPDATE'
  EXPORTING
    dyname               = sy-repid
    dynumb               = sy-dynnr
  TABLES
    dynpfields           = l_i_dynpfields
  EXCEPTIONS
    invalid_abapworkarea = 1
    invalid_dynprofield  = 2
    invalid_dynproname   = 3
    invalid_dynpronummer = 4
    invalid_request      = 5
    no_fielddescription  = 6
    undefind_error       = 7
    OTHERS               = 8.
IF sy-subrc <> 0.
  MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
          WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.
ENDFORM.                    "sub_populate_f4_help

Get the entered value from a field on POV of another field using FM DYNP_VALUES_READ

2008-07-24T00:17:00.021+05:30

Demo code on how to populate search help values dynamically depending upon values of another parameter on F4 button press. We have to use FM "DYNP_VALUES_READ".

The Code:

*&---------------------------------------------------------------------*
*& Program : Z_TEST_PROGRAM
*& Created on : 23.07.2008 22:55:41
*&---------------------------------------------------------------------*
*& Test program for blog http://abap-explorer.blogspot.com/
*&---------------------------------------------------------------------*
REPORT  z_test_program.

*Data Declaration
TYPES :
BEGIN OF x_spfli,
carrid TYPE s_carr_id,
connid TYPE s_conn_id,
END OF x_spfli.

DATA :
i_spfli TYPE STANDARD TABLE OF x_spfli INITIAL SIZE 0.
*Parameters
PARAMETERS:
p_carrid TYPE x_spfli-carrid OBLIGATORY,
p_connid TYPE x_spfli-connid.

AT SELECTION-SCREEN ON VALUE-REQUEST FOR p_connid.

PERFORM sub_get_f4.

START-OF-SELECTION.

WRITE: / ' this is for testing'.
*&---------------------------------------------------------------------*
*&      Form  sub_get_f4
*&---------------------------------------------------------------------*
*       Subroutine to populate F$ help
*----------------------------------------------------------------------*
FORM sub_get_f4 .
DATA:
l_i_dynpfields  TYPE STANDARD TABLE OF dynpread INITIAL SIZE 0,
l_wa_dynpfields TYPE dynpread,
l_carrid TYPE s_carr_id.
*Populate the Parameter Name whoso value is required

l_wa_dynpfields-fieldname = 'P_CARRID'.
APPEND l_wa_dynpfields TO l_i_dynpfields.

*Call the FM to read that value
CALL FUNCTION 'DYNP_VALUES_READ'
EXPORTING
dyname                         = sy-repid
dynumb                         = sy-dynnr
*   TRANSLATE_TO_UPPER             = ' '
*   REQUEST                        = ' '
*   PERFORM_CONVERSION_EXITS       = ' '
*   PERFORM_INPUT_CONVERSION       = ' '
*   DETERMINE_LOOP_INDEX           = ' '
TABLES
dynpfields                     = l_i_dynpfields
EXCEPTIONS
invalid_abapworkarea           = 1
invalid_dynprofield            = 2
invalid_dynproname             = 3
invalid_dynpronummer           = 4
invalid_request                = 5
no_fielddescription            = 6
invalid_parameter              = 7
undefind_error                 = 8
double_conversion              = 9
stepl_not_found                = 10
OTHERS                         = 11
      .
IF sy-subrc = 0.
*Get the value
READ TABLE l_i_dynpfields INTO l_wa_dynpfields
WITH KEY fieldname = 'P_CARRID'.
IF sy-subrc = 0.
l_carrid = l_wa_dynpfields-fieldvalue.

SELECT
carrid          " Airline Code
connid          " Flight Connection Number
FROM spfli      " Flight schedule
INTO TABLE i_spfli WHERE carrid = l_carrid.

CALL FUNCTION 'F4IF_INT_TABLE_VALUE_REQUEST'
  EXPORTING
    retfield    = 'CONNID'
    dynpprog    = sy-repid
    dynpnr      = sy-dynnr
    dynprofield = 'P_CONNID'
    value_org   = 'S'
  TABLES
    value_tab   = i_spfli.
ENDIF.
ENDIF.
ENDFORM.                    " sub_get_f4

Call Maintenance View from a program using FM VIEW_MAINTENANCE_CALL

2008-07-23T01:32:00.021+05:30

This code demonstrates how to call function module VIEW_MAINTENANCE_CALL to call a table maintenance view from any program.

The Code:

*&---------------------------------------------------------------------*
*& Report  Z_TEST_PROGRAM
*&---------------------------------------------------------------------*
*& Demo program for blog http://abap-explorer.blogspot.com/
*&---------------------------------------------------------------------*
REPORT  z_test_program.
DATA:
i_sellist TYPE STANDARD TABLE OF vimsellist INITIAL SIZE 0,
i_header  TYPE STANDARD TABLE OF vimdesc INITIAL SIZE 0,
i_namtab  TYPE STANDARD TABLE OF vimnamtab INITIAL SIZE 0.
 
PARAMETERS: p_view TYPE viewname MATCHCODE OBJECT viewmaint OBLIGATORY.
 
AT SELECTION-SCREEN.
 
CALL FUNCTION 'VIEW_GET_DDIC_INFO'
EXPORTING
 viewname                    = p_view
*     VARIANT_FOR_SELECTION       = ' '
TABLES
 sellist                     = i_sellist
 x_header                    = i_header
 x_namtab                    = i_namtab
EXCEPTIONS
no_tvdir_entry              = 1
table_not_found             = 2
OTHERS                      = 3
       .
IF sy-subrc <> 0.
data: l_message type NATXT.
CONCATENATE 'Table/View' p_view
INTO l_message SEPARATED BY space.
MESSAGE e001(00) WITH l_message ' not in the Dictonary'.
ENDIF.
 
START-OF-SELECTION.
 
CALL FUNCTION 'VIEW_MAINTENANCE_CALL'
EXPORTING
action                               = 'S'
view_name                            = p_view
EXCEPTIONS
client_reference                     = 1
foreign_lock                         = 2
invalid_action                       = 3
no_clientindependent_auth            = 4
no_database_function                 = 5
no_editor_function                   = 6
no_show_auth                         = 7
no_tvdir_entry                       = 8
no_upd_auth                          = 9
only_show_allowed                    = 10
system_failure                       = 11
unknown_field_in_dba_sellist         = 12
view_not_found                       = 13
maintenance_prohibited               = 14
OTHERS                               = 15
       .
 
IF sy-subrc <> 0.
MESSAGE i001(00) WITH 'Error while calling the view'.
LEAVE LIST-PROCESSING.
ENDIF.

Checking Syntax a program at runtime

2008-07-22T00:52:00.016+05:30

Check out this test code to check syntactical errors in a code through a program. My test code will work only in unicode systems, as I have checked an unicode error.

*&---------------------------------------------------------------------*
*& Report  Z_TEST_SYNTAX_CHECK
*&
*&---------------------------------------------------------------------*
*&
*&
*&---------------------------------------------------------------------*
REPORT  z_test_syntax_check.
DATA: itab1 TYPE STANDARD TABLE OF string,
    itab2 TYPE STANDARD TABLE OF string,
    mess TYPE string,
    lin  TYPE i,
    wrd  TYPE string,
    dir  TYPE trdir.
**********************************************************************
APPEND 'PROGRAM test.'                  TO itab1.
APPEND 'DATA dat TYPE d.'               TO itab1.
APPEND 'DATA len TYPE c.'               TO itab1.
APPEND 'DESCRIBE FIELD dat LENGTH len.' TO itab1.
 
SELECT SINGLE *
     FROM trdir
     INTO dir
     WHERE name = sy-repid.
 
SYNTAX-CHECK FOR itab1 MESSAGE mess
            LINE lin WORD wrd
           DIRECTORY ENTRY dir.
 
IF sy-subrc = 4.
WRITE: /1 'Error in first program:' , mess.
ELSE.
WRITE: /1 'No error in first program'.
ENDIF.
**********************************************************************
APPEND 'PROGRAM test.'                  TO itab2.
APPEND 'DATA dat TYPE d.'               TO itab2.
APPEND 'DATA len TYPE i.'               TO itab2.
APPEND 'DESCRIBE FIELD dat LENGTH len IN byte MODE.' TO itab2.
 
SYNTAX-CHECK FOR itab2 MESSAGE mess
             LINE lin WORD wrd
             DIRECTORY ENTRY dir.
 
IF sy-subrc = 4.
WRITE : /1 'Error in second program:' , mess.
ELSE.
WRITE: /1 'No error in second program'.
ENDIF.