Flash Blog

ImTOO FLV Converter

Horia Condrea — Sat, 21 Jan 2012 16:15:26 PST

ImTOO FLV Converter is a professional FLV video converter software to convert FLV to AVI, MP4, DivX, etc. It is also a video to FLV converter to convert AVI to FLV, MP4 to FLV, WMV to FLV video format. Likewise, it can convert audio files such as MP3 to FLV and SWF audios as a FLV audio converter.

ImTOO FLV Converter helps you convert Flash video (FLV) to all types of videos for playback on portable media devices. It is able to:Convert FLV to MP4, FLV to AVI, FLV to WMV/MOV/DivX/3GP; Convert AVI to FLV, MP4 to FLV, MKV to FLV, MOV to FLV, etc.

With ImTOO FLV Converter, you can conveniently upload the output FLV videos to YouTube.com and other video websites, and enjoy MP4 videos converted from your desired YouTube FLV videos on iPod, PSP, iPhone, and WMV videos on Xbox.

Quick Tip: How to use your microphone in AS 3.0

Horia Condrea — Mon, 28 Nov 2011 13:33:44 PST

Hello again and thanks for all messages. But please, no more SPAM. Well, let’s get back to our bussines, today I’ll present to you a new Quick Tip: How to use your microphone in AS 3.0. A few months ago I posted something about How to use your camera, and now you will learn how to play with your microphone.

The code is not hard at all, I’m sure that you will understand immediately. But if you have any questions please contact me or leave me a comment:

 
package
{
	import flash.display.Bitmap;
	import flash.display.BitmapData;
	import flash.display.Sprite;
	import flash.geom.Rectangle;
	import flash.media.Microphone;
	import flash.utils.setInterval;
 
	public class Mic extends Sprite
	{
		private var microphone:Microphone;
		private var volumeBar:Bitmap = new Bitmap(new BitmapData(100,10,true));
 
		public function Mic()
		{
			this.addChild(volumeBar);
			microphone = Microphone.getMicrophone();
			microphone.setLoopBack(true);
			microphone.setUseEchoSuppression(true);
			setInterval(show,30);
		}
 
		private function show():void
		{
			with(volumeBar.bitmapData)
			{
				fillRect(new Rectangle(0,0,100,10), 0x00000000);
				fillRect(new Rectangle(0,0,microphone.activityLevel,10),0xff00ff00);
 
			}
 
 
		}
	}
}

As you can see this is not only a simple exemple. In this code a have a rectange that measure the sound intensity recorded by microphone. The show function draw the rectangle and make him to oscilate depends of sound intensity.

Box2D 2.1a Lesson 2(Tutorial)

Horia Condrea — Thu, 18 Aug 2011 06:06:11 PDT

Hi readers, this is the second lesson about Box2d, a very powerfull engine, not only in flash. If you missed the first lesson, then you will not understand what I am gonig to do here. So, please go to the : Box2D 2.1a Lesson 1(Tutorial). If you already seen the first tutorial then it will be much easier to understand.

As you know, I promised last time that in the second lesson I will put some graphics on our SWF file. Please be ready beacause in this tutorial we will actualy see something in our project.

So let’s see what we will doing today, this is the final result:

Interesting or not?

Now let’s look a bit at the source code. I don’t think is so hard, given that in the first tutorial I tried to explain very good, and I think that a many of you guys out there allready understand. Well, this is the code:

package
{
	import Box2D.Collision.Shapes.b2PolygonShape;
	import Box2D.Common.Math.b2Vec2;
	import Box2D.Dynamics.b2Body;
	import Box2D.Dynamics.b2BodyDef;
	import Box2D.Dynamics.b2DebugDraw;
	import Box2D.Dynamics.b2FixtureDef;
	import Box2D.Dynamics.b2World;
 
	import flash.display.MovieClip;
	import flash.display.Sprite;
	import flash.events.Event;
	import flash.events.MouseEvent;
 
	[SWF(width="550", height="400", frameRate="30", backgroundColor="#333333")]
 
	public class Main extends Sprite
	{
		private var _world:b2World;
 
		private var _gravityX:Number = 0;
		private var _gravityY:Number = 9.81;
 
		private var _block:b2Body;
		private var _blockX:Number;
		private var _blockY:Number;
 
		private var _btn:MovieClip = new MovieClip();
 
		private static const RATIO:Number = 30;
 
		public function Main()
		{
			// Set up the world
			setupWorld();
			//Create the floor
			createF();
			//Create the Block
			createB();
 
			setupDraw();
 
			//ENTER_FRAME
			addEventListener(Event.ENTER_FRAME, onEnterFrame);
 
			// Draw button
			setBtn();
			// Reset Position
			_btn.addEventListener(MouseEvent.CLICK, onClick);
		}
 
		private function setupDraw():void
		{
			var sprite:Sprite = new Sprite();
			addChild(sprite);
 
			var b2DD:b2DebugDraw = new b2DebugDraw();
			b2DD.SetSprite(sprite);
			b2DD.SetDrawScale(RATIO);
			b2DD.SetFlags(b2DebugDraw.e_shapeBit);
			b2DD.SetLineThickness(2);
			b2DD.SetFillAlpha(0.6);
 
			_world.SetDebugDraw(b2DD);
			_world.DrawDebugData();
		}
 
		private function setupWorld():void
		{
			var gravity:b2Vec2 = new b2Vec2(_gravityX, _gravityY);
			var ignoreSleeping:Boolean = true;
 
			_world = new b2World(gravity,ignoreSleeping);
		}
 
		private function createF():void
		{
			var floor:b2Body;
			var floorDef:b2BodyDef;
			var floorShape:b2PolygonShape;
 
			floorDef = new b2BodyDef();
			floorDef.position.Set(275 / RATIO, 400 / RATIO);
			floorDef.type = b2Body.b2_staticBody;
 
			floorShape = new b2PolygonShape();
			floorShape.SetAsBox(250 / RATIO,10 / RATIO);
 
			var fixtureDef:b2FixtureDef = new b2FixtureDef();
			fixtureDef.shape = floorShape;
			fixtureDef.density = 1.0;
			fixtureDef.friction = 0.8;
			fixtureDef.restitution = 0.3;
 
			floor = _world.CreateBody(floorDef);
			floor.CreateFixture(fixtureDef);
 
		}
 
		private function createB():void
		{
			var blockDef:b2BodyDef;
			var blockShape:b2PolygonShape;
 
			blockDef = new b2BodyDef();
			blockDef.position.Set(300 / RATIO,  10/  RATIO);
			blockDef.type = b2Body.b2_dynamicBody;
 
			blockShape = new b2PolygonShape();
			blockShape.SetAsBox(25 / RATIO,25 / RATIO);
 
			var fixtureDef:b2FixtureDef = new b2FixtureDef();
			fixtureDef.shape = blockShape;
			fixtureDef.density = 1.0;
			fixtureDef.friction = 0.8;
			fixtureDef.restitution = 0.3;
 
			_block = _world.CreateBody(blockDef);
			_block.CreateFixture(fixtureDef);
 
		}
 
		private function setBtn():void
		{
			with(_btn.graphics)
			{
				beginFill(0xcccccc,1)
				drawRect(25,25,25,25)
				endFill()
			}
			addChild(_btn);
			_btn.buttonMode = true;
		}
 
		private function onClick(e:MouseEvent):void
		{
			_block.SetSleepingAllowed(false);
			var position:b2Vec2 = new b2Vec2(275 / RATIO, 0 / RATIO);
			var angle:Number = (Math.random() * 360 ) * Math.PI / 180;
			_block.SetPositionAndAngle(position,angle);
 
		}
 
		private function onEnterFrame(e:Event):void
		{
			_world.Step(1 / 30 ,10, 10);
			_world.ClearForces();
			_world.DrawDebugData();
			trace(_block.GetPosition().y);
		}
	}
}

You can now play with the gravity, density, friction, restitution, etc and you can see what each can do. If you have any questions please leave a comment or contact me, I will try to answer to any question. See ya next time.

Box2D 2.1a Lesson 1(Tutorial)

Horia Condrea — Wed, 20 Jul 2011 01:12:45 PDT

Hello again, this is the first lesson for teaching Box2D. Don’t worry is not so hard, and if you realy like physics, is hard not to like what Box2D can do. You need to know that Box2D is in origin a Physics Engine for C++ programing. So you will see that are a lot of differences betwen writing code in pure AS 3.0 for a real object move, and writing code for a real object move in Box2D. But, let’s stop talking, and see how this engine works.

If we want to do an object that moves, we first need to create a World, is exactly like in our lifes. This World need to have gravity and need to know if he will igone or not static bodies. We will see later how will this look in a code.

Like I said this engine works like the real word, so he don’t work in PIXEL(this is very important, for you to know), this engine works in METERS. Again this is very important, you will see later how to make an application on a monitor that works in pixels.

In Box2D of course we will work with objects. Let’s see how we will make an object:

Box2D (Object)

View more presentations from Condrea Horatiu

Those are only the basic things that we will use, but are enough for making an object. In future lessons we will talk more about other interesting things that you will learn.

After you read this, you are ready to understand how this application works. For this first lesson I made a very very very simple application. We will make an object and put him to fall into space with a gravity of 9.8 meters per seccond.

You won’t be able to see anything graphic for this project, you will be only able to see Y coordinate for our block that will fall down. I know that this is not very fun for you, and I’m sorry for that, but I promise that in the next lesson , I will show you how to make a graphic for your object.

Code:

package
{
	import Box2D.Collision.Shapes.b2PolygonShape;
	import Box2D.Common.Math.b2Vec2;
	import Box2D.Dynamics.b2Body;
	import Box2D.Dynamics.b2BodyDef;
	import Box2D.Dynamics.b2FixtureDef;
	import Box2D.Dynamics.b2World;
 
	import flash.display.Sprite;
	import flash.events.Event;
 
	public class Main extends Sprite
	{
		private var _world:b2World;
		private var _block:b2Body;
		private static const RATIO:Number = 30;
 
		public function Main()
		{
			//// Set up the world
			createWorld();
			//Create the Block
			createB();
			// Give this World some life
			addEventListener(Event.ENTER_FRAME, onEnterFrame);
		}
 
		private function createWorld():void
		{
			// Set up the gravity
			var gravity:b2Vec2 = new b2Vec2(0 , 9.8);
			// Tell the world to ignore sleeping objects
			var doSleep:Boolean = true;
 
			_world = new b2World(gravity, doSleep);
		}
 
		private function createB():void
		{
			var blockDef:b2BodyDef;
			var blockShape:b2PolygonShape;
 
			blockDef = new b2BodyDef();
			blockDef.position.Set(300 / RATIO, 0 /  RATIO);
			blockDef.type = b2Body.b2_dynamicBody;
 
			blockShape = new b2PolygonShape();
			blockShape.SetAsBox(20 / RATIO,25 / RATIO);
 
			var fixtureDef:b2FixtureDef = new b2FixtureDef();
			fixtureDef.shape = blockShape;
			fixtureDef.density = 1.0;
			fixtureDef.friction = 0.8;
			fixtureDef.restitution = 0.3;
 
			_block = _world.CreateBody(blockDef);
			_block.CreateFixture(fixtureDef);
 
		}
 
		private function onEnterFrame(e:Event):void
		{
			_world.Step(10,10,10);
			_world.ClearForces();
 
			trace(_block.GetPosition().y);
		}
 
	}
}

Let’s take a look again in this code, we have 3 private variables. The first one represents the World, the second one the body, and the last one help as to convert pixels to meters. As I said at the begining, Box2D works in meters.
After that I create the world function -createWorld- . I think this is clear I give the world a gravity of 9.8 on Y, and I set the world to ignore sleeping objects. On the -createB- function, I creat our body, I give him a position:

blockDef.position.Set(300 / RATIO, 0 /  RATIO);

and a form (Width and Hight):

 blockShape.SetAsBox(20 / RATIO,25 / RATIO);

Now, let’s see if your block is falling down or not. As you can see I have a -trace- statement at the end of the code, that will show as the Y coordinate for our block. Let’s test this and see what kind of result we will obtain.

As you can see our result is exactly as I expected. As you can see, my block is falling. And he will not stop because in this world that we created we don’t have any other objects that can interact with him. So, because of that he will fall continuously.

That was the first lesson about how to get started with Box2D. I hope you enjoy this, and see you soon at the next tutorials. THANKS.

Box2D 2.1a Lesson 2(Tutorial)

Contact Form in AS 3.0 with PHP Tutorial

Horia Condrea — Fri, 08 Jul 2011 00:38:55 PDT

Hi, today I found a very nice -PSD Contact Form - and with that design I made a very simple contact form with PHP. Is not very hard to understand. Bellow is an image with the contact form design, and all the Instance Name that I use:

Step 1

Download that PSD file, or make your own design for this Contact Form Project, open Adobe Flash Professional, make a new ActinScript 3.0 Project and importat the PSD file, or make there a new design. If you want to use my code, name your TextFiled as mine. All your TextFields are INPUT.

Step 2

Now let’s get started with coding. This is the code:

package
{
	import flash.display.Sprite;
	import flash.net.URLLoader;
	import flash.net.URLRequest;
	import flash.net.URLVariables;
	import flash.net.URLLoaderDataFormat;
	import flash.net.URLRequestMethod;
 
	import flash.events.Event;
	import flash.events.MouseEvent;
	import flash.text.TextField;
 
	public class index extends Sprite
	{
		private var loader:URLLoader = new URLLoader();
		private var req:URLRequest = new URLRequest("contact.php");
		private var variables:URLVariables = new URLVariables();
 
		public function index():void
		{
			option();
			init();
		}
 
		protected function option():void
		{
			loader.dataFormat = URLLoaderDataFormat.VARIABLES;
			req.method = URLRequestMethod.POST;
 
			name_txt.tabIndex = 0;
			company_txt.tabIndex = 1;
			email_txt.tabIndex = 2;
			msg_txt.tabIndex = 3;
 
			button.buttonMode = true;
 
		}
 
		protected function init():void
		{
			button.addEventListener(MouseEvent.CLICK, onClick);
		}
 
		protected function onClick(e:MouseEvent):void
		{
 
			variables.senderName = name_txt.text;
			variables.senderEmail = email_txt.text;
			variables.senderMsg = msg_txt.text;
			variables.senderCompany = company_txt.text;
			req.data = variables;
			loader.load(req);
		}
	}
}

Step 3

Our ActionScript Project is ready, because we need this to work , all that we need now is a PHP file, a file that will actualy send uor message to a mail address.

So, PHP:


              	Sent By: $senderName @$senderCompany
 
				Message Sent:
 
$senderMsg
 
";
$EmailFooter	= "
Sent: $date
 
";
$Message 		= $EmailBody.$EmailFooter;
$ok = mail($to, $ToSubject, $Message, $headers . "From:$senderName <".$to.">");
if($ok){
	echo "retval=1";
}else{
	echo "retval=0";
}
 
?&gt;

Now, this is ready, put your project on a server and you’ll see that it will work. But edit this PHP file with your own details.

Download
Downloaded 96 times

SWF Protector

Horia Condrea — Tue, 05 Jul 2011 05:30:25 PDT

Hello everybody, as you know Flash Player has a bad reputation, because he has a problem with his protection. Well a few days ago, I was asked if I want to make a review for a SWF protector, i came across this sofware called SWF Protector. I started to make some tests, and I was really surprised when I saw that he realy makes a very good job.
Below is an example of a trying a decompilation. The SWF that I used is my last project, posted on my blog. If you are a reader of my blog you know that my last project is that Bounce Effect

So, this is the code that I extract from the SWF without having a protection:

 
package  
{
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.geom.Rectangle;
	import flash.geom.ColorTransform;
	import flash.geom.Transform;
 
	public class Ball extends MovieClip
	{
		public var speedX:int = 10;
		public var speedY:int = -10;
 
		public function Ball() 
		{
			super();
			addEventListener(Event.ENTER_FRAME, onE);
			var cT:ColorTransform = new ColorTransform();
			cT.color = Math.random() * 0xFFFFFF;
			transform.colorTransform = cT;
		}
 
		private function onE(e:Event):void
		{
			x += speedX;
			y += speedY;
 
			var bounds:Rectangle = getBounds(parent);
 
			if(bounds.left < 0 || bounds.right > stage.stageWidth)
			{
				speedX *= -1;
			}
 
			if(bounds.top < 0 || bounds.bottom > stage.stageHeight)
			{
				speedY *= -1;
			}
		}
 
	}
 
}

And this is the code that I extract with protection:

 
package
{
	import flash.geom.*;
	import flash.display.*;
	import flash.events*;
 
	public class Ball extends flash.display.MovieClip
	{
		public function Ball()
		{
			if (false)
			{
				!false;
			}
		}
 
		internal function onE(arg1:flash.events.Event):void
		{
			if (!true)
			{
				-true;
			}
		}
 
		public var speedX:int = 10;
		public var speedY:int = -10;
	}
}
 
import flash.display.*;
import flash.events.*;
 
{
	if(!false)
	{
		;
	}
}

As you can see, without a protection the source code is note safe.

SWF Protector is a highly reliable encryption solution, which will thoroughly protect all of your Flash files from all kinds of SWF decompilers. SWF Protector fully protects ActionScript, so your artwork is impossible to steal. It uses four different protection algorithms that allow SWF file playback in Flash Player, but conceal the source code completely. You will be able to encrypt all ActionScript classes, or select specific ones that contain most sensitive code.
You can see more HERE

Bounce Effect

Horia Condrea — Mon, 13 Jun 2011 06:19:32 PDT

Hello again. I come back with a simple exemple of ‘bouncing on stage’. Very simple to understand, and if you have any questions, feel free to ask. I have a lot on my head right now, sorry for my little introduction for this ActionScript class.

package  
{
	import flash.display.MovieClip;
	import flash.events.Event;
	import flash.geom.Rectangle;
	import flash.geom.ColorTransform;
	import flash.geom.Transform;
 
	public class Ball extends MovieClip
	{
		public var speedX:int = 10;
		public var speedY:int = -10;
 
		public function Ball() 
		{
			// constructor code
			addEventListener(Event.ENTER_FRAME, onE);
			var cT:ColorTransform = new ColorTransform();
			cT.color = Math.random() * 0xFFFFFF;
			transform.colorTransform = cT;
		}
 
		private function onE(e:Event):void
		{
			x += speedX;
			y += speedY;
 
			var bounds:Rectangle = getBounds(parent);
 
			if(bounds.left < 0 || bounds.right > stage.stageWidth)
			{
				speedX *= -1;
			}
 
			if(bounds.top < 0 || bounds.bottom > stage.stageHeight)
			{
				speedY *= -1;
			}
		}
 
	}
 
}

Download
Downloaded 313 times

Quick Tip: How to Load XML File in AS 3.0

Horia Condrea — Fri, 27 May 2011 02:42:08 PDT

There is another quick tip:”How to Load XML File in AS 3.0″. All you need to do is to create an XML file. And then look at my code over there, and try to do it yourself. Is not hard to understand. One important thing, for this project the XML file, will be in the some folder with the ‘.fla’ and ‘.as’ file.

Code:

package
{
	import flash.display.Sprite;
	import flash.net.URLRequest;
	import flash.net.URLLoader;
	import flash.events.Event;
 
	public class main extends Sprite
	{
		private var xml:XML;
 
		public function main()
		{
			loadXML("main.xml");
		}
 
		private function loadXML(name:String):void
		{
			trace(name);
 
			var reqURL:URLRequest = new URLRequest(name);
			var loadURL:URLLoader = new URLLoader(reqURL);
			loadURL.addEventListener(Event.COMPLETE, show);
		}
 
		private function show(e:Event):void
		{
			trace (new XML(e.target.data));
		}
	}
}

Download
Downloaded 105 times

Adobe Flash Builder 4.5 – Free to Students and the Unemployed

Horia Condrea — Sun, 15 May 2011 00:22:46 PDT

For Students and Faculty

The rules for this program:

1. Your student ID showing current enrollment, or
2. Your faculty ID showing current employment, or
3. Your employee ID showing current employment, or
4. A letter on an educational institution letterhead stating that you are either a current student, a current faculty member or a current employee of the institution.

For the Unemployed:

1. I am not employed and not otherwise paid to develop software applications or web pages
2. Adobe Flash Builder 4.5 Software I receive under this program is licensed by Adobe only for my personal use to learn about Adobe Flex and improve my skills
3. I will not use the software obtained under this program for production or commercial purposes
4. I will not transfer the license to the software obtained under this program to any other person or entity, including to my employer should I become employed.

Visit this page to sign–up.

Quick Tip: How to use your web camera in AS 3.0

Horia Condrea — Sun, 01 May 2011 14:01:40 PDT

In the following code, I will access the camera that I have at my computer.

Video type objects can be used to render images from the webcam. flash.media.Camera class extends EventDispatcher – are inherited property / events / methods in this class. The camera will be attached to a Video object using the method attachCamera. A camera object will not be added through the operator “new “, the reason being that, every time, we must access the same memory area in which we find images from the webcam.Assume that the system is attached a single webcam.

Code:

package  
{
	import flash.media.Video;
	import flash.media.Camera;
	import flash.display.Sprite;
 
	public class main extends Sprite
	{
		private var v:Video = new Video();
		private var c:Camera = Camera.getCamera();
 
		public function main() 
		{
			v.attachCamera(c);
			this.addChild(v);
			c.setMode(320,240,32,true);
 
		}
 
	}
 
}