Sometimes you need to do a bunch of similar tasks at once (create similar display objects, render stuff, reindex pools etc), but often this may be a pain due to performance limits (which may result in poor user experience) and that’s where the queue pattern comes to the rescue. I’ve wrote a simple thought useful util for that purpose.

Play with the demo below (a simple IQueueItem implementation) or download the source (com.chargedweb.queue.*)


UPDATE: v.1.2 update + docs updated

ps: no holy wars plz guys ^_^

The news about the new “flash killer” (adobe shared the wallaby source code to google or it’s just a clone?) flew over around the web (even Lee Brimelow posted about it). So i’ve decided to check it out and see it myself.
So, i made a simple as2 movie compiled for fp6 ( they recommend version below 8 ) to see if swiffy could manage to convert it.

Original as2 movie http://chargedweb.com/labs/files/2011/06/fp6.as2.swf

Swiffy output http://chargedweb.com/labs/files/2011/06/fp6.as2.html

it’s you to comment…

Try it out yourself:

package
{
	import flash.display.MovieClip;
	import flash.display.Graphics;
	import flash.display.Shape;
	import flash.display.JointStyle;
	import flash.display.CapsStyle;
	import flash.display.LineScaleMode;
	import flash.events.Event;

	[SWF(width="400", height="400", frameRate="50")]
	public class MitterBug extends MovieClip
	{
		var inc:Boolean = true;
		var b:int = 1;
		var jointStyles:Array = [JointStyle.BEVEL, JointStyle.ROUND, JointStyle.MITER];	// MITTER's buggy

		public function MitterBug()
		{
			if(stage) init();
			else addEventListener(Event.ADDED_TO_STAGE, init);
		}

		private function init(event:Event = null):void
		{
			var n:int = jointStyles.length;
			for(var i = 0; i < n; ++i) addChild(new Shape());
			addEventListener(Event.ENTER_FRAME, onEnterFrameHandler);
		}

		private function redrawRect(g:Graphics, b:int, j:String, w:int, h:int):void
		{
			g.clear();
			g.lineStyle(b, 0, 1, true, LineScaleMode.NONE, CapsStyle.NONE, j);
			g.beginFill(0xff0000, 1);
			g.drawRect(0, 0, w, h);
			g.endFill();
		}

		private function onEnterFrameHandler(event:Event):void
		{
			if(b == 50) 	inc = false;	// increase 'til 50
			if(b == 0)		inc = true;		// decrease 'til 0

			if(inc) b++;
			else b--;

			var n:int = jointStyles.length;

			for(var i = 0; i < n; ++i)
			{
				var s:Shape = getChildAt(i) as Shape;
				s.rotation++;
				s.x = 200;
				s.y = 70 + i*120;
				redrawRect(s.graphics, b, jointStyles[i], 40, 40);
			}
		}
	}
}

Take a MAXRacer ride

// using ByteArray
function cloneObjectBA(value:Object):Object
{
var ba:ByteArray = new ByteArray();
ba.writeObject(value); ba.position = 0;
return ba.readObject() as Object;
}

// using for in loop
function cloneObjectForInLoop(value:Object):Object
{
var obj:Object = new Object();
for(var p:String in value) obj[p] = value[p];
return obj;
}

// >> Benchmark
var t:int, tb:int, tbAvg:int, tbTotal:int, tl:int, tlAvg:int, tlTotal:int;
var obj:Object = {};		// our testee ^_^
var numProps:int = 100000;	// num props to push to the object
var numCycles:int = 20;		// num cycles to run

// create properties
for(var i:int = 0; i < numProps; i++) obj["prop_"+i] = "val_"+i; trace("object", "->", numProps, "props");
trace("bytes", "\t|\t", "for in loop");
trace("-------------------------");

for(i = 0; i < numCycles; i++)
{
t = getTimer();
cloneObjectBA(obj);
tb = getTimer() - t;
tbTotal += tb;

t = getTimer();
cloneObjectForInLoop(obj);
tl = getTimer() - t;
tlTotal += tl;
trace(tb, "ms", "\t|\t", tl, "ms");
}
tbAvg = tbTotal/numCycles;
tlAvg = tlTotal/numCycles;

trace("-------------------------");
trace("AVG after "+numCycles+" cycles:");
trace("bytes", "\t|\t", "for in loop");
trace("-------------------------");
trace(tbAvg, "ms", "\t|\t", tlAvg, "ms");
trace("-------------------------");

My results on core2duo 3Ghz, win 10.2.152.26 debug:

object -> 100000 props
bytes | for in loop
-------------------------
678 ms | 32 ms
407 ms | 32 ms
380 ms | 32 ms
383 ms | 32 ms
384 ms | 31 ms
392 ms | 34 ms
405 ms | 32 ms
391 ms | 32 ms
393 ms | 32 ms
397 ms | 31 ms
390 ms | 31 ms
394 ms | 31 ms
395 ms | 31 ms
395 ms | 32 ms
399 ms | 31 ms
412 ms | 32 ms
390 ms | 31 ms
390 ms | 31 ms
389 ms | 32 ms
392 ms | 32 ms
-------------------------
AVG after 20 cycles:
bytes | for in loop
-------------------------
407 ms | 31 ms
-------------------------


K.O. for in loop wins

SWFSize master branch is now available at GitHub, so that those of u that use svn/git could easily pull the source.
https://github.com/jloa/SWFSize

trace(0 === -0);			// true
trace(Math.atan2(0, 0));	// 0
trace(Math.atan2(0, -0));	// 3.141592653589793
trace(Math.atan2(-0, -0));	// -3.141592653589793

function posZero(n:Number) { if(n === 0) return Math.abs(n); }

It’s been a while since i last posted in my blog thx to the holidays and the the enormous num of projects that’ve fallen down. One of my lastest projects was to build a swf course for an LMS using the SCORM standart. That’s when i’ve ran across Philip Hutchison’s blog and his SCORM project. After a few days of SCORM researches and running through the pipwerks SCORM solution, i came up with the idea to make an extention of it, which would fully implement SCORM 1.2 and 2004 “from the box” in the nearest future (currently a beta yet it works). [to be continued...]

So, here’s my version of the SCORM implementation for as3:

Download as3scorm at sourceforge (OS, MIT license as always)

UPDATE: added a new archive with a sample course

Might be useful:
SCORM 1.2
SCORM 2004 4th edition (and some more)
SCORM resourses, books, articles, tools etc
Adobe’s serialization as3corelib
Philip Hutchison’s aka pipwerks SCORM labs

ps: Philip thx A LOT for yr help! Btw if u have any scorm related questions, do not hesitate to contact either me or Philip

Today was the 1st day of the Adobe max 2010, and as far as some of you already know, i wasn’t able to attend it personally, so i had to watch it live at http://max.adobe.com/online/ (btw in HD !!!).
I won’t write a poem about it, as tomorrow there will be one available at the said above http://max.adobe.com/online/ they’ve already posted the replay of today’s session. However i just owe to mention what really impressed me and that was the Alternativa’s 3d game called “Max racer” (a demo of the new, 8th edition of the engine), which was presented by Kevin Lynch as a sneak peak of fp’s performance increasement.

Ough, and the most important notice: check out the today’s replay http://max.adobe.com/online/monday/


I guess, that’s it for now. Now, back to work. Cheers

The YUI Compressor is written in Java (requires Java >= 1.4) and relies on Rhino to tokenize the source JavaScript file. It starts by analyzing the source JavaScript file to understand how it is structured. It then prints out the token stream, omitting as many white space characters as possible, and replacing all local symbols by a 1 (or 2, or 3) letter symbol wherever such a substitution is appropriate (in the face of evil features such as eval or with, the YUI Compressor takes a defensive approach by not obfuscating any of the scopes containing the evil statement) The CSS compression algorithm uses a set of finely tuned regular expressions to compress the source CSS file. The YUI Compressor is open-source, so don’t hesitate to look at the code to understand exactly how it works.

In short, YUI Compressor is a jar tool which compresses *.js files. Sure, u can use it through the command line as described here, however just give JSCompressor a try

Requirements:
AIR: 2.0 run-time installed (in case u don’t have it click here)
OS: win
Download: jscompressor.exe

ps: i just love making small apps is my spare time ^_^

Recently i had to align tons of UIComponents with scale and even rotation defined. And so, i decided to write a small static class that would really facilitate my life. I called it AlignUtil. That’s it for now. All links are listed bellow. Hope it helps someone. Cheers ^_^

ps: btw i decided to switch my devs license to MIT, so from now on u r free to use the source codes for whatever u want purpose.

Online demo
Download the AlignUtil class

UPDATE: class updated to v.1.3

And here’s the source code (in case u r 2 lazy to download the archive):

////////////////////////////////////////////////////////////////////////////////
//
//  (c) 2011 Julius Loa | jloa[u know wha]chargedweb.com | http://chargedweb.com/labs/
//  All Rights Reserved.
//  license:	MIT {http://www.opensource.org/licenses/mit-license.php}
//  notice: 	just keep the header plz
//
////////////////////////////////////////////////////////////////////////////////

package com.chargedweb.utils
{
/** fp api **/
import flash.display.DisplayObject;
import flash.text.TextField;
import flash.geom.Rectangle;
import flash.geom.Point;

/**
* <p>AlignUtil class - vertical/horizontal align DisplayObjects</p>
* @availability 	fp9 (flash/flex, as3)
* @version 		1.3
*
* <p>Class usage:</p>
* @example using parentalRelation set to "true" (aligning children inside the "parent")
* <listing version="3.0">
* import com.chargedweb.utils.AlignUtil;
*
* var btn:Button = new Button();
* btn.x = 100;
* btn.y = 100;
* btn.width = 100;
* btn.height = 30;
* btn.rotation = 30;
* addChild(btn);
*
* AlignUtil.setAlign(AlignUtil.H_CENTER, btn, this);
* AlignUtil.setAlign(AlignUtil.V_MIDDLE, btn, this);
* </listing>
*
* @example using parentalRelation set to "false" (aligning children according to another child on the same level)
* <listing version="3.0">
* import flash.display.Shape;
* import com.chargedweb.utils.AlignUtil;
*
* function createBox(w:Number, h:Number, r:Number):Shape
* {
* 	var sp:Shape = new Shape();
*	sp.graphics.beginFill(Math.random()*0xffffff);
*	sp.graphics.drawRect(0, 0, w, h);
*	sp.graphics.endFill();
*	sp.rotation = r;
*	return sp;
* }
*
* var a:Shape = createBox(200, 200, 45);
* a.x = 200; a.y = 100;
* addChild(a);
*
* var b:Shape = createBox(50, 20, -10);
* b.x = 50; b.y = 200;
* addChild(b);
*
* var c:Shape = createBox(120, 75, 150);
* c.x = 300; c.y = 200;
* addChild(c);
*
* // align 'b','c' according to 'a' (horizontal-left and vertical-top alignment)
* // horizontally
* AlignUtil.setAlign(AlignUtil.H_LEFT, b, a, false);
* AlignUtil.setAlign(AlignUtil.H_LEFT, c, a, false);
* // now vertically
* AlignUtil.setAlign(AlignUtil.V_TOP, b, a, false);
* AlignUtil.setAlign(AlignUtil.V_TOP, c, a, false);
* </listing>
*/
public class AlignUtil
{
/** Horizontal left alignment **/
public static const H_LEFT:String = "horizontalLeft";
/** Horizontal center alignment **/
public static const H_CENTER:String = "horizontalCenter";
/** Horizontal right alignment **/
public static const H_RIGHT:String = "horizontalRight";

/** Vertical top alignment **/
public static const V_TOP:String = "verticalTop";
/** Vertical middle alignment **/
public static const V_MIDDLE:String = "verticalMiddle";
/** Vertical bottom alignment **/
public static const V_BOTTOM:String = "verticalBottom";

/**
* Applies a specified alignment to the target DisplayObject
* @param	align:String				alignment mode (see the public constants defined above)
* @param	target:DisplayObject		target DisplayObject to align (according to the set alignment mode) @see flash.display.DisplayObject
* @param	parent:DisplayObject		the parent DisplayObject of the target one @see flash.display.DisplayObject
* @param	parentalRelation:Boolean	whether the "target" DisplayObject is a child of the "parent" or not @default true;
* @return	nothing
*/
public static function setAlign(align:String, target:DisplayObject, parent:DisplayObject, parentalRelation:Boolean = true):void
{
var a:String = align;
var t:DisplayObject = target;
var p:DisplayObject = parent;
var b:Rectangle = t.transform.pixelBounds;
var tp:Point = new Point();
var bp:Point;

/**
* @note 28/03/2011 :: bug fix for TextFields :: tip by Arindam Mojumder
* TextField.transform.pixelBounds return incorrect x/y coordinates (not the actual, but rather
* the one of the transform point) and the x/y are always 'zero' valued, so we make an exception for tfs
*/
if(t is TextField) b = t.getBounds(t.parent);

/** if parentalRelation is enabled, use local coordinates **/
if(parentalRelation)
{
bp = p.globalToLocal(new Point(b.x, b.y));
b.x = bp.x;	b.y = bp.y;
}else{
tp = new Point(p.transform.pixelBounds.x, p.transform.pixelBounds.y);
}

if(a == H_LEFT) t.x = (t.x > b.x) ? tp.x + t.x - b.x : tp.x;
if(a == H_CENTER) t.x = tp.x + int((p.width - b.width)/2 + t.x - b.x);
if(a == H_RIGHT) t.x = (t.x > b.x + b.width) ? tp.x + p.width : tp.x + p.width - (b.x + b.width - t.x);
if(a == V_TOP) t.y = (t.y > b.y) ? tp.y + t.y - b.y : tp.y;
if(a == V_MIDDLE) t.y = tp.y + int((p.height - b.height)/2 + t.y - b.y);
if(a == V_BOTTOM) t.y = (t.y > b.y + b.height) ? tp.y + p.height : tp.y + p.height - (b.y + b.height - t.y);
}
}
}

The European Union’s new Digital Agenda, an ambitious program of incentives and legislation designed to improve access to technology across the EU, could force companies such as Apple to open up their businesses by requiring them to offer more interoperability and use open standards. It could force more openness even if those companies are not the dominant player in a specific market, because the language in the EU Agenda says that such measures could apply merely to “significant” players in a market — broadening the scope of previous antitrust rules substantially.

Could that be true? Flash player support on i-devices, really? Or just another rumor?

more info here => http://bit.ly/abeBdC

ps: 0k, that’s it guys. I’m fed up with that apple stuff, let’s get back to development

Frash is a port of the Adobe Flash runtime for Android to the iPhone, using a compatibility layer, by comex (http://twitter.com/comex). Frash can currently run most Flash programs natively in the MobileSafari browser. Frash currently only runs on the iPad, but support for other devices (3GS+ only due to technical restrictions) is planned, as well as support for iOS 4.

A release is planned for when Frash is stable. Developers are welcome to join the effort at http://github.com/comex/frash – fork it and send a pull request with your patches.

Frash uses a multi-process model similar to Chrome on the desktop, so a crash in the Frash/Flash plugin doesn’t take down the browser. You can see this while I’m playing Alien Hominid: the ad above crashed (probably a Frash bug), but Safari stays open just fine, and continues to play other Flash content on the page.

Video and keyboard input are currently not supported. The former will require major reverse engineering of the video decoding frameworks on the iPhone, but the latter should be reasonably easy to implement.

…and if anyone from Adobe reads this: Hosting the libflashplayer.so binary somewhere accessible outside the Android Market would make this a lot easier to distribute .

Shot on an iPhone 4 and edited using iMovie on the phone.

ps: muhaha, i told u Steve that yr rage was useless

+

Well, i’m not a js-developer actually, however i had to write a small tooltip in js 2day and i thought that some of you would probably find it usefull. Won’t post the source code here this time, but the demo and source archive are still available @see the links below.

• Lightweight
• Supports basic fade effects
• Easy to use
• Uses external png graphics
• Supports html
• Works in all browsers

Check out the online demo or grab the source files

ps: thx DryIcons for the icon.

Yes, guys, finally realaxy is out for download
Btw it supports win/mac/linux. And guess what, it’s free !
Ain’t that awesome? Profit!

Did you know that there’s a some sort of a html5 fan club?
Why am i telling you this? Because there’s a sort of a timer telling when will html5 be fully released check it http://ishtml5readyyet.com/

ps: only 12 more years still to go…

ps: So, where did the great html5 performance go?

In case u need to save utf8 data to a csv or xls file, mind that those formats do not support utf8 encoding.
Say, u’ve got to save a cyrillic text to a csv file:

// A sample cyrillic, bulgarian text, for exmaple
var utf8String:String = "Аз съм българче. Обичам наште планини зелени...";

// Try to save the file in utf8 charset and then
// open it with Microsoft Excel
var file:FileReference = new FileReference();
file.save(utf8String, "utf8_test.csv");

And here’s the result:

But don’t hurry to google for an as3 charset encoding library, as there’s a simple way to solve this issue:

// A sample cyrillic, bulgarian text, for exmaple
var utf8String:String = "Аз съм българче. Обичам наште планини зелени...";

// csv, xls appear to work only with the ascii
// and windows-like charsets, so as the string is
// cyrillic, we'll use the cyrillic (Windows) charset 'windows-1251'
// which codename's 'x-cp1251' according to the adobe's as3 reference.
var bytes:ByteArray = new ByteArray();
bytes.writeMultiByte(utf8String, "x-cp1251");

var file:FileReference = new FileReference();
file.save(bytes, "cp1251_test.csv");

Now we got the expected result:


Really simple, but still there might be someone who’d need it.

yellow – current fps
cyan – current memory usage
red – max memory usage graph

As lots of you asked me to add some new features like the font color changing, performance increasement etc, i decided to make a new version of the ResourceMonitor class. I’ve added a few new features, made the code more ammm more readable (well, it’s an os class, so probably u’d like to edit smth there) and i’ve even made a documentation this time
And i also decided to rename it to ResourceMonitorUtil.

Class usage also has shorten.

Flex:

import com.chargedweb.utils.ResourceMonitorUtil;

rawChildren.addChild(new ResourceMonitorUtil());

Flash:

import com.chargedweb.utils.ResourceMonitorUtil;

addChild(new ResourceMonitorUtil());

Blah-blah-blah, just let me download the ResourceMonitorUtil source code already

And here’s the source code in case for some reason u don’t want to download the archive:

////////////////////////////////////////////////////////////////////////////////
//
//  Copyright 2010 Julius Loa | jloa@chargedweb.com
//  All Rights Reserved.
//  license:	MIT {http://www.opensource.org/licenses/mit-license.php}
//  notice: 	just keep the header plz
//
////////////////////////////////////////////////////////////////////////////////

package com.chargedweb.utils
{
import flash.display.JointStyle;
import flash.display.Shape;
import flash.display.Sprite;
import flash.events.Event;
import flash.events.TimerEvent;
import flash.system.System;
import flash.text.TextField;
import flash.text.TextFieldAutoSize;
import flash.text.TextFormat;
import flash.utils.Timer;

/**
* <img src="http://chargedweb.com/labs/files/2010/02/resourcemonitor.png" alt="" />

*

ResourceMonitorUtil class provides the fps and used memory information <a href="http://chargedweb.com/labs/2010/05/06/resourcemonitor-v2-resourcemonitorutil/" target="_blank">more info online</a>

*
*

Version: 2.1

*

Changes in version 2.1:

*
<ul> *
<li>fixed the avg memory count algorithm (just had to switch to Number istead of int)</li>
*
<li>fixed the graphics limit exceeder bug</li>
*
<li>added max used ram memory throughout the history memoryMaxUsed()</li>
*
<li>added max used ram memory graphic</li>
*
<li>added max used ram memory graphic line size property memoryMaxUsedLineSize()</li>
*
<li>added max used ram memory graphic line color property memoryMaxUsedLineColor()</li>
*
<li>added a new replace tag to the info text MEMORY_INFO</li>
*
<li>license switched GNU -> <a href="http://www.opensource.org/licenses/mit-license.php">MIT</a></li>
*</ul>
*
*

<img src="http://chargedweb.com/labs/files/2010/02/smile.png" alt="" />

*
* @availability 	flash/flex, as3
* @version 		2.1
*
* @example Flex sample:
*

* import com.chargedweb.utils.ResourceMonitorUtil;
*
* rawChildren.addChild(new ResourceMonitorUtil());
*  	 *
* @example Flash sample:
*
* import com.chargedweb.utils.ResourceMonitorUtil;
*
* addChild(new ResourceMonitorUtil());
*  	 */
public class ResourceMonitorUtil extends Sprite
{
////////////////
//
//	Infos
//
////////////////

/**
* Fps info text
* %fps% replaced by the current fps value
* %fpsMax% replaced by the current fpsMax value
*/
public static var FPS_INFO:String = "Fps: %fps%/%fpsMax%";

/**
* Fps average info text %fpsAVG% replaced by the current average fps value
*/
public static var FPS_AVG_INFO:String = "FpsAVG: %fpsAVG%";

/**
* Memory info text
* %memory% 		replaced by the current memory value [mb]
* %memoryMaxUsed% 	replaced by the max memory used so far [mb]
* %memoryMax% 		replaced by the current memoryMax value [mb]
*/
public static var MEMORY_INFO:String = "Ram: %memory% (%memoryMaxUsed%) mb";

/**
* Memory average info text %memoryAVG% replaced by the current average memory value [mb]
*/
public static var MEMORY_AVG_INFO:String = "RamAVG: %memoryAVG% mb";

////////////////
//
//	Styles
//
////////////////

// grid color
private var _gridColor:uint = 0xFFFFFF;

// grid alpha
private var _gridAlpha:Number = .25;

// background color
private var _backgroundColor:uint = 0x000000;

// background alpha
private var _backgroundAlpha:Number = 1;

// fps line size
private var _fpsLineSize:int = 2;

// fps line color
private var _fpsLineColor:uint = 0xFFCC00;

// memory line size
private var _memoryLineSize:int = 2;

// memory line color
private var _memoryLineColor:uint = 0x00CCFF;

// memory max used line size
private var _memoryMaxUsedLineSize:int = 1;

// memory max used line color
private var _memoryMaxUsedLineColor:uint = 0xFF0000;

////////////////
//
//	Misc
//
////////////////

// current memory used [bytes]
private var _memory:int = 0;

// current average memory used [bytes]
private var _memoryAVG:int = 0;

// max value of the used memory so far (the highest value stored in history for _historyLength steps)
private var _memoryMaxUsed:int = 0;

// maximum memory value [bytes] there always has to be a limit
private var _memoryMax:int = 500*1024*1024;

// max fps value
private var _fpsMax:int = 0;

// current fps value
private var _fps:int = 0;

// current average fps value
private var _fpsAVG:int = 0;

// whether to show the average fps value
private var _showFpsAVG:Boolean = true;

// whether to show the average memory value
private var _showMemoryAVG:Boolean = true;

// whether to show the grid
private var _showGrid:Boolean = true;

// whether to show the text field
private var _showText:Boolean = true;

// history {fps:int, memory:Number}
private var _history:Array;

// history length (steps to store i.e. records for the last 'n' seconds)
private var _historyLength:int = 40;

// monitor timer
private var _monitorTimer:Timer;

// text format
private var _format:TextFormat = new TextFormat("Verdana", 10, 0x000000);

// textfield instance
private var _tf:TextField;

// background
private var _bg:Sprite;

// fps graph
private var _bgFps:Shape;

// memory graph
private var _bgMemory:Shape;

// memory graph
private var _bgMemoryMaxUsed:Shape;

// grid
private var _grid:Shape;

// frames counter
private var _frames:int = 0;

// width holder
private var _width:int = 160;

// height holder
private var _height:int = 150;

////////////////
//
//	PUBLIC
//
////////////////

/**
* Converts value from kilobytes to megabytes
* @param	value:int			kilobytes to convert
* @param	fractionDigits:int	an integer between 0 and 20, inclusive, that represents the desired number of decimal places @default 1
*/
public static function kbToMb(value:int, fractionDigits:int = 1):Number
{
if(fractionDigits < 0 || fractionDigits > 20) throw new Error("fractionDigits values must be between 0 and 20", 0);
return Number((value/(1024*1024)).toFixed(fractionDigits));
}

/**
* Constructor
* @return	nothing
*/
public function ResourceMonitorUtil()
{
super();
addEventListener(Event.ADDED_TO_STAGE, onAddedToStage);
}

/**
* Starts monitoring resource usage @see #stop()
* @return	nothing
*/
public function monitor():void
{
_monitorTimer.start();
if(!hasEventListener(Event.ENTER_FRAME)) addEventListener(Event.ENTER_FRAME, onFpsTimer);
dispatchEvent(new Event(Event.INIT));
}

/**
* Stops monitoring resource usage @see #monitor()
* @return 	nothing
*/
public function stop():void
{
_monitorTimer.stop();
if(hasEventListener(Event.ENTER_FRAME)) removeEventListener(Event.ENTER_FRAME, onFpsTimer);
}

/**
* Redraws everything
* @return	nothing
*/
public function redraw():void
{
redrawTextField();
redrawBackground();
redrawGrid();
redrawFpsGraph();
redrawMemoryGraph();
redrawMemoryMaxUsedGraph();
}

////////////////////////////////
//
//	SETTERS/GETTERS
//
////////////////////////////////

/**
* Overriden width property @default 160
* @param	value:Number	new width value
* @return	Number			current width value
*/
override public function set width(value:Number):void
{
_width = value;
redraw();
}
override public function get width():Number
{
return _width;
}

/**
* Overriden height property @default 150
* @param	value:Number	new height value
* @return	Number			current height value
*/
override public function set height(value:Number):void
{
_height = value;
redraw();
}
override public function get height():Number
{
return _height;
}

/**
* Sets/gets the textFormat for the TextField @default new TextFormat("Verdana", 10, 0x000000);
* @param	value:TextFormat	new text format
* @return	TextFormat			current text format
*/
public function set textFormat(value:TextFormat):void
{
_format = value;
redraw();
}
public function get textFormat():TextFormat
{
return _format;
}

/**
* Returns the history array of objects {fps:int, memory:Number}
* memory in bytes
* @return	Array		current history array
*/
public function get history():Array
{
return _history;
}

/**
* Sets/gets the history length (number of records to store in the history array 1 step = 1 sec) value @default 40
* @param	value:int	new history length value
* @return	int			current history length value
*/
public function set historyLength(value:int):void
{
_historyLength = value;
initHistory();
redraw();
}
public function get historyLength():int
{
return _historyLength;
}

/**
* Returns the current fps value
* @return	int		current fps value
*/
public function get fps():int
{
return _fps;
}

/**
* Returns the current average fps value
* @return	int		current average fps value
*/
public function get fpsAVG():int
{
return _fpsAVG;
}

/**
* Returns the max fps value
* @return	int		max fps value
*/
public function get fpsMax():int
{
return _fpsAVG;
}

/**
* Returns the current memory used value [bytes]
* @return	int		current memory used value [bytes]
*/
public function get memory():int
{
return _memory;
}

/**
* Returns the current average memory used value [bytes]
* @return	int		current average memory used value [bytes]
*/
public function get memoryAVG():int
{
return _memoryAVG;
}

/**
* Returs the max registered memory usage so far for the last 'n' defined by the historyLength steps @see #historyLength
*/
public function get memoryMaxUsed():int
{
return _memoryMaxUsed;
}

/**
* Sets/gets the max memory value @default 500*1024*1024
* @param	value:int	new max memory value [bytes]
* @return	int			current max memory value [bytes]
*/
public function set memoryMax(value:int):void
{
_memoryMax = value;
redraw();
}
public function get memoryMax():int
{
return _memoryMax;
}

/**
* Sets/gets whether to show or not the average fps @default true
* @param	value:Boolean	new value
* @return	Boolean			current value
*/
public function set showFpsAVG(value:Boolean):void
{
_showFpsAVG = value;
redraw();
}
public function get showFpsAVG():Boolean
{
return _showFpsAVG;
}

/**
* Sets/gets whether to show or not the average memory @default true
* @param	value:Boolean	new value
* @return	Boolean			current value
*/
public function set showMemoryAVG(value:Boolean):void
{
_showMemoryAVG = value;
redraw();
}
public function get showMemoryAVG():Boolean
{
return _showMemoryAVG;
}

/**
* Sets/gets whether to show or not the textField info @default true
* @param	value:Boolean	new value
* @return	Boolean			current value
*/
public function set showText(value:Boolean):void
{
_showText = value;
redraw();
}
public function get showText():Boolean
{
return _showText;
}

/**
* Sets/gets whether to show or not the grid @default true
* @param	value:Boolean	new value
* @return	Boolean			current value
*/
public function set showGrid(value:Boolean):void
{
_showGrid = value;
redrawGrid();
}
public function get showGrid():Boolean
{
return _showGrid;
}

/**
* Sets/gets the grid color @default 0xFFFFFF
* @param	value:uint	new grid color value
* @return	uint		current grid color value
*/
public function set gridColor(value:uint):void
{
_gridColor = value;
redrawGrid();
}
public function get gridColor():uint
{
return _gridColor;
}

/**
* Sets/gets the grid alpha @default 0.25
* @param	value:Number	new grid alpha value
* @return	Number			current grid alpha value
*/
public function set gridAlpha(value:Number):void
{
_gridAlpha = value;
redrawGrid();
}
public function get gridAlpha():Number
{
return _gridAlpha;
}

/**
* Sets/gets the background color @default 0x000000
* @param	value:uint	new background color value
* @return	uint		current background color value
*/
public function set backgroundColor(value:uint):void
{
_backgroundColor = value;
redrawBackground();
}
public function get backgroundColor():uint
{
return _backgroundColor;
}

/**
* Sets/gets the background alpha @default 1
* @param	value:Number	new background alpha value
* @return	Number			current background alpha value
*/
public function set backgroundAlpha(value:Number):void
{
_backgroundAlpha = value;
redrawBackground();
}
public function get backgroundAlpha():Number
{
return _backgroundAlpha;
}

/**
* Sets/gets the fps line size @default 2
* @param	value:int	new fps line size value
* @return	int			current fps line size value
*/
public function set fpsLineSize(value:int):void
{
_fpsLineSize = value;
redrawFpsGraph();
}
public function get fpsLineSize():int
{
return _fpsLineSize;
}

/**
* Sets/gets the fps line color @default 0xFFCC00
* @param	value:uint	new fps line color value
* @return	uint		current fps line color value
*/
public function set fpsLineColor(value:uint):void
{
_fpsLineColor = value;
redrawFpsGraph();
}
public function get fpsLineColor():uint
{
return _fpsLineColor;
}

/**
* Sets/gets the memory line size @default 2
* @param	value:int	new memory line size value
* @return	int			current memory line size value
*/
public function set memoryLineSize(value:int):void
{
_memoryLineSize = value;
redrawMemoryGraph();
}
public function get memoryLineSize():int
{
return _memoryLineSize;
}

/**
* Sets/gets the memory line color @default 0x00CCFF
* @param	value:uint	new memory line color value
* @return	uint		current memory line color value
*/
public function set memoryLineColor(value:uint):void
{
_memoryLineColor = value;
redrawMemoryGraph();
}
public function get memoryLineColor():uint
{
return _memoryLineColor;
}

/**
* Sets/gets the max used memory line size @default 1
* @param	value:int	new memory line size value
* @return	int			current memory line size value
*/
public function set memoryMaxUsedLineSize(value:int):void
{
_memoryMaxUsedLineSize = value;
redrawMemoryMaxUsedGraph();
}
public function get memoryMaxUsedLineSize():int
{
return _memoryMaxUsedLineSize;
}

/**
* Sets/gets max used memory line color @default 0xFF0000
* @param	value:uint	new memory line color value
* @return	uint		current memory line color value
*/
public function set memoryMaxUsedLineColor(value:uint):void
{
_memoryMaxUsedLineColor = value;
redrawMemoryMaxUsedGraph();
}
public function get memoryMaxUsedLineColor():uint
{
return _memoryMaxUsedLineColor;
}

////////////////
//
//	PRIVATE
//
////////////////

/**
* @private Inits the history array
* @return 	nothing
*/
private function initHistory():void
{
_history = new Array();

for(var i:int = 0; i < _historyLength; i++)
_history.push({fps: _fpsMax, memory: 0, memoryMaxUsed: 0});
}

/**
* @private Creates children
* @return nothing
*/
private function createChildren():void
{
_tf = new TextField();
_tf.defaultTextFormat = _format;
_tf.autoSize = TextFieldAutoSize.LEFT;
_tf.multiline = true;
_tf.wordWrap = true;
_tf.selectable = false;
this.addChild(_tf);

_bg = new Sprite();
this.addChild(_bg);

_grid = new Shape();
_bg.addChild(_grid);

_bgFps = new Shape();
_bg.addChild(_bgFps);

_bgMemoryMaxUsed = new Shape();
_bg.addChild(_bgMemoryMaxUsed);

_bgMemory = new Shape();
_bg.addChild(_bgMemory);

redraw();
monitor();
}

/**
* @private Redraws the textField
* @return	nothing
*/
private function redrawTextField():void
{
if(!_tf) return;
_tf.width = _width;

if(_showText)
{
_tf.text = FPS_INFO.replace("%fps%", _fps).replace("%fpsMax%", _fpsMax);
if(_showFpsAVG) _tf.appendText("\n"+FPS_AVG_INFO.replace("%fpsAVG%", _fpsAVG));
_tf.appendText("\n"+MEMORY_INFO.replace("%memory%", kbToMb(_memory)).replace("%memoryMaxUsed%", kbToMb(_memoryMaxUsed)).replace("%memoryMax%", kbToMb(_memoryMax)));
if(_showMemoryAVG) _tf.appendText("\n"+MEMORY_AVG_INFO.replace("%memoryAVG%", kbToMb(_memoryAVG)));
}else{
_tf.text = "";
}
}

/**
* @private Redraws the background
* @return	nothing
*/
private function redrawBackground():void
{
if(!_bg) return;
_bg.x = 0;
_bg.y = int(_tf.height);
_bg.graphics.clear();
_bg.graphics.beginFill(_backgroundColor, _backgroundAlpha);
_bg.graphics.drawRect(0, 0, _width, _height - _bg.y);
_bg.graphics.endFill();
}

/**
* @private Redraws the grid
* @return	nothing
*/
private function redrawGrid():void
{
if(!_grid) return;
var step:Number = _width/_historyLength;

_grid.graphics.clear();
_grid.visible = _showGrid;
if(!_showGrid) return;

for(var i:int = 0; i < _historyLength; i++)
{
_grid.graphics.lineStyle(1, _gridColor, _gridAlpha, false, "normal", "none", JointStyle.MITER);
_grid.graphics.moveTo(i*step, 0);
_grid.graphics.lineTo(i*step, _height - _bg.y);
_grid.graphics.endFill();
}
}

/**
* @private Redraws the fps graph
* @return	nothing
*/
private function redrawFpsGraph():void
{
if(!_bgFps) return;
var step:Number = _width/_historyLength;
var h:int = _height - _bg.y;

_bgFps.graphics.clear();
_bgFps.graphics.lineStyle(_fpsLineSize, _fpsLineColor, 1, false, "normal", "none", JointStyle.MITER);

for(var i:int = 0; i < _historyLength; i++)
{
if(i == 0) _bgFps.graphics.moveTo(step*i, (_history[i].fps/_fpsMax)*h);
else _bgFps.graphics.lineTo(step*i, (_history[i].fps/_fpsMax)*h);
}

_bgFps.graphics.endFill();
}

/**
* @private Redraws the memory graph
* @return	nothing
*/
private function redrawMemoryGraph():void
{
if(!_bgMemory) return;
var step:Number = _width/_historyLength;
var h:int = _height - _bg.y;

_bgMemory.graphics.clear();
_bgMemory.graphics.lineStyle(_memoryLineSize, _memoryLineColor, 1, false, "normal", "none", JointStyle.MITER);

for(var i:int = 0; i < _historyLength; i++)
{
if(i == 0) _bgMemory.graphics.moveTo(step*i, h - (_history[i].memory/_memoryMax)*h);
else _bgMemory.graphics.lineTo(step*i, h - (_history[i].memory/_memoryMax)*h);
}

_bgMemory.graphics.endFill();
}

/**
* @private Redraws the memory graph
* @return	nothing
*/
private function redrawMemoryMaxUsedGraph():void
{
if(!_bgMemory) return;
var step:Number = _width/_historyLength;
var h:int = _height - _bg.y;

_bgMemoryMaxUsed.graphics.clear();
_bgMemoryMaxUsed.graphics.lineStyle(_memoryMaxUsedLineSize, _memoryMaxUsedLineColor, 1, false, "normal", "none", JointStyle.MITER);

for(var i:int = 0; i < _historyLength; i++)
{
if(i == 0) _bgMemoryMaxUsed.graphics.moveTo(step*i, h - (_history[i].memoryMaxUsed/_memoryMax)*h);
else _bgMemoryMaxUsed.graphics.lineTo(step*i, h - (_history[i].memoryMaxUsed/_memoryMax)*h);
}

_bgMemoryMaxUsed.graphics.endFill();
}

/**
* @private Counts the current average fps value
* @return	int		current average fps value
*/
private function countFpsAVG():int
{
var f:int = 0;
var n:int = 0
for(var i:int = 0; i < _historyLength; i++) 			{ 				f += _history[i].fps; 				if(_history[i].fps > 0) n++;
}

return (f/n > 0) ? (f/n) : 0;
}

/**
* @private Counts the current average memory value
* @return	int		current average memory value
*/
private function countMemoryAVG():int
{
var m:Number = 0;
var n:int = 0
for(var i:int = 0; i < _historyLength; i++) 			{ 				m += _history[i].memory; 				if(_history[i].memory > 0) n++;
}

return (n > 0) ? (m/n) : 0;
}

/**
* @private Counts the max memory used so far
* @return	int		max used memory so far value
*/
private function countMemoryMaxUsed():int
{
var m:int = 0
for(var i:int = 0; i < _historyLength; i++) 			{ 				if(_history[i].memory > m) m = _history[i].memory;
}

return m;
}

/**
* @private Monitor timer handler
* @return	nothing
*/
private function onMonitorTimer(event:TimerEvent):void
{
_fpsMax = stage.frameRate;
_fps = (_frames > _fpsMax) ? _fpsMax : _frames;
_fpsAVG = countFpsAVG();
_memory = System.totalMemory;
_memory = (_memory > _memoryMax) ? _memoryMax : _memory; // else the graph will exceed the limits
_memoryAVG = countMemoryAVG();
_memoryMaxUsed = countMemoryMaxUsed();
_memoryMaxUsed = (_memoryMaxUsed > _memoryMax) ? _memoryMax : _memoryMaxUsed; // else the graph will exceed the limits
_frames = 0;

_history.splice(0,1);
_history.push({fps: _fps, memory: _memory, memoryMaxUsed: _memoryMaxUsed});

redraw();
dispatchEvent(new Event(Event.CHANGE));
}

/**
* @private Fps timer handler
* @return	nothing
*/
private function onFpsTimer(event:Event):void
{
_frames++;
}

/**
* @private ADDED_TO_STAGE handler
* @param	event:Event		event
* @return	nothing
*/
private function onAddedToStage(event:Event):void
{
if(!_monitorTimer)
{
_monitorTimer = new Timer(1000);
_monitorTimer.addEventListener(TimerEvent.TIMER, onMonitorTimer);
}

if(!hasEventListener(Event.ENTER_FRAME)) addEventListener(Event.ENTER_FRAME, onFpsTimer);

_fpsMax = stage.frameRate;
initHistory();
createChildren();
removeEventListener(Event.ADDED_TO_STAGE, onAddedToStage);
}
}
}

Includes such classes like: VectorUtil, ResourceMonitor, MatrixUtil, LoaderUtil, Cache, VimeoPlayer, SkypeStatusIcon etc.

Download the com.chargedweb.* package

UPD1: now with docs

UPD2:

- added AlignUtil class (more info here)

ps: i wish i had some free time to collect all my classes in one huge package

I’m not a designer actually, i just love drawing from time to time

Overview
Download icons + source

Now compare it to the “SLOW flashplayer”

ps: Back to the Mesozoic era? O.o

////////////////////////////////////////////////////////////////////////////////
//
//  Copyright 2010 Julius Loa | jloa@chargedweb.com
//  All Rights Reserved.
//  license: GNU {http://www.opensource.org/licenses/gpl-2.0.php}
//  notice: just keep the header plz
//
////////////////////////////////////////////////////////////////////////////////

package com.chargedweb.utils
{
	import flash.filters.ColorMatrixFilter;

	/**
	 * Matrix utility class
	 * @version 1.0
	 * so far added:
	 * - brightness
	 * - contrast
	 * - saturation
	 */
	public class MatrixUtil
	{
		/**
		 * sets brightness value available are -100 ~ 100 @default is 0
		 * @param 		value:int	brightness value
		 * @return		ColorMatrixFilter
		 */
		public static function setBrightness(value:Number):ColorMatrixFilter
		{
			value = value*(255/250);

			var m:Array = new Array();
    		m = m.concat([1, 0, 0, 0, value]);	// red
   		 	m = m.concat([0, 1, 0, 0, value]);	// green
   		 	m = m.concat([0, 0, 1, 0, value]);	// blue
    		m = m.concat([0, 0, 0, 1, 0]);		// alpha

    		return new ColorMatrixFilter(m);
		}

		/**
		 * sets contrast value available are -100 ~ 100 @default is 0
		 * @param 		value:int	contrast value
		 * @return		ColorMatrixFilter
		 */
		public static function setContrast(value:Number):ColorMatrixFilter
		{
			value /= 100;
			var s: Number = value + 1;
    		var o : Number = 128 * (1 - s);

			var m:Array = new Array();
			m = m.concat([s, 0, 0, 0, o]);	// red
			m = m.concat([0, s, 0, 0, o]);	// green
			m = m.concat([0, 0, s, 0, o]);	// blue
			m = m.concat([0, 0, 0, 1, 0]);	// alpha

			return new ColorMatrixFilter(m);
		}

		/**
		 * sets saturation value available are -100 ~ 100 @default is 0
		 * @param 		value:int	saturation value
		 * @return		ColorMatrixFilter
		 */
		public static function setSaturation(value:Number):ColorMatrixFilter
		{
			const lumaR:Number = 0.212671;
    		const lumaG:Number = 0.71516;
    		const lumaB:Number = 0.072169;

			var v:Number = (value/100) + 1;
			var i:Number = (1 - v);
   		 	var r:Number = (i * lumaR);
    		var g:Number = (i * lumaG);
    		var b:Number = (i * lumaB);

			var m:Array = new Array();
			m = m.concat([(r + v), g, b, 0, 0]);	// red
			m = m.concat([r, (g + v), b, 0, 0]);	// green
			m = m.concat([r, g, (b + v), 0, 0]);	// blue
			m = m.concat([0, 0, 0, 1, 0]);			// alpha

 			return new ColorMatrixFilter(m);
		}
	}
}

And the sample usage code:

import com.chargedweb.utils.MatrixUtil;

var bmp:Bitmap = new Bitmap(new Image(0,0));
addChild(bmp);
bmp.filters = [MatrixUtil.setBrightness(20),
			   MatrixUtil.setContrast(20),
			   MatrixUtil.setSaturation(-100)];

I’ve already twitted/faced about this editor a while ago, but still, now that i’ve contacted Ivan Dembicki, the CEO and developer of Realaxy LTD (you might know Iv by his bezier project) and Evgeniy Potapenko (CEO), i’ve sniffed out some new details about their revolutionary actionscript editor called Realaxy ActionScript Editor.

So, for those of you that don’t know what’s this all about – it’s all about the new revolutionary actionscript editor called the Realaxy ActionScript Editor developed by the Realaxy team.

UPDATED (clickable)

So, what is so revolutionary about it?
Well, here are its advantages at first sight:

• written on JetBrains MPS
• smart autocomplite
• autocomplete E4X
• metadata autocomplete
• extended smart E4X
• rapid development of methods, fields, and other language constructs only by pressing Enter
• method parameters suggestion in code
• getters/setters generation
• toString generation
• event handlers generation
• override/implements methods
• lots of Refactorings features
• powerful bug tracing (FlexUnit, Debugger and Profiler in dev)
• Language extensions (Realaxy Action Script Editor is the only ActionScript editor allowing you to create and use language extensions. Even today Enums, Collection Language and Generics language extensions are available for you. Next in turn are Flow Language, plug-in architecture support, pattern support and caching language. But even that is not all. You can create language extensions and share them with other editor users.)

…and MORE

Here’s the “Smart auto complete demo” that i just love say hi to adobe

See other Realaxy editor demos here.

Release date: Realaxy Action Script Editor 1.0 is planned to the end of august 2010.

That’s it for now, guys. All that i can tell for now.
I’ll keep you in touch.

ps: can’t wait to get my hands on the private demo

UPDATE:

I’ve just sneaked out some new vital & hillarious Realaxy features.
You will be able to code java and objective C applications on your favourite ActionScript 3.0. Unbelievable, isn’t it?

The whole thing is that there’s a retranslation mechanism which will automatically generate a java/objective c code for ya, as i’ve understood. And what that means is that you WILL be able to dev apps for the Apple AppStore.
Say “hi” to Steveeee

We believe this initiative will help our users in the following ways:
* When users download Chrome, they will also receive the latest version of Adobe Flash Player. There will be no need to install Flash Player separately.
* Users will automatically receive updates related to Flash Player using Google Chrome’s auto-update mechanism. This eliminates the need to manually download separate updates and reduces the security risk of using outdated versions.
* With Adobe’s help, we plan to further protect users by extending Chrome’s “sandbox” to web pages with Flash content.

More about it here:
Bringing improved support for Adobe Flash Player to Google Chrome
Improved Flash Player Support in Chrome

ps: ain’t that awesome? No need for player detection, version updates in Chrome now ^_^

• Design in Mind: provide a framework meant for continuous collaboration between designer and developer.
• Developer Productivity: improve compiler performance and add productivity enhancements to language features like data binding
• Framework Evolution: take advantage of new Flash Player capabilities and add features required by common use-cases

ps: sry too tired to write more. But soon.

private var rc:Number = 1/3, gc:Number = 1/3, bc:Number = 1/3;
private var sf:ColorMatrixFilter = new ColorMatrixFilter([rc, gc, bc, 0, 0, rc, gc, bc, 0, 0, rc, gc, bc, 0, 0, 0, 0, 0, 1, 0]);

private function blackAndWhite(target:UIComponent, enabled:Boolean):void
{
   if(enabled) target.filters = [sf];
   else target.filters = [];
}

So there i was, trying to build my latest application which involved run-time cursor loading/usage.
I knew that the flex sdk had that static CursorManager class (i.e. mx.core.CursorManager), but as i looked up the manual – there’s no loadIcon() method, only setters that require class references which is sooooo unhandy if u deal with run-time loading assets (like i do).
So, i got myself some coffee, opened the eclipse and after some time spend – eureka!
I came to this slight solution which besides is elementary.

Ok, less words – more action.
Here’s the class and the usage below:

////////////////////////////////////////////////////////////////////////////////
//
//  Copyright 2009 Julius Loa | jloa@chargedweb.com
//  All Rights Reserved.
//  license: GNU {http://www.opensource.org/licenses/gpl-2.0.php}
//  notice: just keep the header plz
//
////////////////////////////////////////////////////////////////////////////////

package com.chargedweb.utils
{
import flash.net.URLRequest;
import flash.display.Loader;

/**
 * CursorFactory class for usage with @see mx.core.CursorManager
 *
 * @example
 * <pre>
 * import com.chargedweb.utils.CursorFactory;
 * import mx.core.CursorManager;
 *
 * CursorFactory.URL = "../assets/skins/icons/my_cursor.png";
 * CursorManager.setCursor(CursorFactory);
 * </pre>
 */

public class CursorFactory extends Loader
 {
   /**
    * Custom cursor url value
    */
   public static var URL:String;

   /**
    * Constructor
    */
   public function CursorFactory()
   {
      super();
      if(URL) load(new URLRequest(URL));
   }
 }
}

And the sample usage code (in case u didn’t notice it in the class comments):

import com.chargedweb.utils.CursorFactory;
import mx.core.CursorManager;

CursorFactory.URL = "../assets/skins/icons/my_cursor.png";
CursorManager.setCursor(CursorFactory);

I liked the previous version more.
Honestly, guys, the previous version was better.

Read more at Lee Brimelow’s blog

UPD: Thibault Imbert and Michael tryed out the flash player 10.1 on the Google Nexus One phone. They tested out some flash web sites, games which weren’t actually optimized for the mobile platform i.e. those r typical web sites from the fwa. And the nexus one managed to get that content work nice and smoth.

Flash Player 10.1 on Google Nexus One from michael chaize on Vimeo.

ps: don’t forget that cs5 (which will improve dev for the mobile devices including iphone) is about to release soon

Download SkypeStatusIcon sources

Yes, but that was until i found Ben Stucki‘s slight solution to this issue.
He wrote a nice utility class called IconUtility which creates BitmapAssets at run-time. This class is huge.
Sample button icon load up code:

var myBtn:Button = new Button();

myBtn.label = "press me";
myBtn.setStyle("icon", IconUtility.getClass(myBtn, "assets/my_icon.png"));
addChild(myBtn);

IconUtility Component for Dynamic Run-Time Icons

Download: IconUtility Class (302 kb)

As some of you probably now, adobe has released the air2beta2 at their labs, which brings new ablities like:

• Enhanced support for interacting with printers (beta 2)
• Support for TLS/SSL socket communication (beta 2)
• Support for the detection of mass storage devices.
• Advanced networking capabilities like secure sockets, UDP support, and the ability to listen on sockets.
• Support for native code integration.
• The ability to open a file with its default application.
• Multi-touch and gesture support.
• New APIs for access to raw microphone data.
• Webkit update with HTML5/CSS3 support.
• Global error handling.
• Improved cross-platform printing
• Improved security and support for enterprise and government standards.
• Native process support

I’ve spend the whole day yesturday playing with the new api and in order that you not waste your time adjusting the sdk’s, figuring out how to build an exe/dmg file with full sdk support i’ve decided to post a little tutorial here.

So, first of all you should start with downloading the air sdk @ http://labs.adobe.com/downloads/air2.html and overlay it for use with Flex SDK.

Here‘s a nice instruction on how to overlay the air sdk.

Once you’ve done that you are ready to start building apps using the new api.

How to create an air2beta2 file:

1. open your application xml file and make sure you’ve added the extended desktop support:

<supportedProfiles>extendedDesktop   desktop</supportedProfiles>

2. compile your application at an AIR file (use the “export release build” option for example)

3. once you’ve created an AIR file u just compile it to an exe/dmg/rpm file (that’s needed for your app to be able to use the new sdk abilities) using the console (well, i did it that way)

adt  -package -target native exported_file_path your_air_file_path

Example (for exe):

adt -package -target native  C:\AIRSample.exe  C:\dev\air\AIRSample.air

Example (for dmg)

adt  -package -target native  C:\AIRSample.dmg  C:\dev\air\AIRSample.air

Example (for rpm)

adt  -package -target native  C:\AIRSample.rpm  C:\dev\air\AIRSample.air

Useful links:

Developer faq

Download air2beta2 sdk

How to overlay air sdk

Your first air2 exe file

If you’r on windows, you can use my small app that converts air => exe/dmg/rpm i.e. it’s a GUI for the adt for those who don’t like console usage. I called it AIRPackager.

Read more about AIRPackager.

Hope 2 help/save yr time.

Nice apps building

Ps: you can also download the source files of my sample PowerOff application that uses the NativeProcess class and use it as a sample air2beta2 app.

Read more about PowerOff app.

UPD: lots of people use very strange/complicated methods to sort vectors.
Guys, stop complicating yr life – the task is way much easier.

So, here’s how i do the sortOn() with Vectors:

/**
* Converts vector to an array
* @param    v:*        vector to be converted
* @return    Array    converted array
*/
function vectorToArray(v:*):Array
{
var n:int = v.length; var a:Array = new Array();
for(var i:int = 0; i < n; i++) a[i] = v[i];
return a;
}

/**
* Here's a little example on how to sort a Vector using sortOn
*/
var v:Vector.<Object> = new Vector.<Object>();
v.push({id:5, email:"andrew@someweb.com"});
v.push({id:35, email:"david@someweb.com"});
v.push({id:12, email:"jill@someweb.com"});

// now to sort the Vector on the "id" property
var vSorted:Vector.<Object> = Vector.<Object>(vectorToArray(v).sortOn("id", Array.NUMERIC));
// easy and convinient isn't it? ^_^

Hope might be useful.
Cheers

Do u guys remember the MyBrute casual flash game?

Valentin Simonov recently showed me a sort of modification of MyBrute called Crouching panda hidden swine (wonder who came to that name .

Anyways, the game is awesome! Nice graphics, animation, gameplay.
It really makes u relax a bit. Totally recommend it.
Try it your own.

ps: btw mybrute has just emailed me to “stay tuned” omg my account is still there http://julius-loa.mybrute.com/cellule

UPD: now works with air 2 runtime

AirPackager is a small app that will help you generate exe/dmg/rpm files out of your air package in other words – it’s just a GUI for the adt.
To install the app you need the AIR2 beta2 runtime AIR2 runtime
Again, works only on windows.

Download AirPackager.exe

PowerOff is a simple shutdown timer, which i created just to reveal (test) some of the new features of AIR2 beta2 api.
To install the app you need the AIR2 beta2 runtime AIR2 runtime
And, btw, it works only on windows.

Download PowerOff.exe

Download PowerOff source files

SWFSize is a simple, lightweight library to control the swf’s container metrics & use the browser’s native scrollbars.
Project page http://chargedweb.com/swfsize/.

UPD: version updated to 1.1
UPD: version updated to 1.2
UPD: version updated to 1.3
UPD: version updated to 1.4.0
UPD: version updated to 1.4.1

Some time ago i was surfing the net and i noticed that flash captchas are very popular on such components stores like flashden etc, but just few of them are actually made properly and can prevent spammers from doing their magic ^_^.

So, i’ve decided to write a little sample catcha validator class for those of u that need or would need one.

Demo available here

Download source files

How to use CaptchaValidator (flash sample):

import fl.controls.Button;
import flash.display.Loader;
import flash.display.SimpleButton;
import flash.text.TextField;
import flash.text.TextFormat;
import flash.events.MouseEvent;
import com.chargedweb.net.CaptchaValidator;
import com.chargedweb.events.CaptchaValidatorEvent;

var tFo:TextFormat = new TextFormat("Verdana", 10);
var capVal:CaptchaValidator = new CaptchaValidator();
capVal.addEventListener(CaptchaValidatorEvent.SUCCESS, onCaptchaSuccess);
capVal.addEventListener(CaptchaValidatorEvent.ERROR_VARS, onErrorVars);
capVal.addEventListener(CaptchaValidatorEvent.ERROR_CAPTCHA, onErrorCaptcha);

var titleTF:TextField = new TextField();
titleTF.multiline = false;
titleTF.autoSize = "left";
titleTF.text = "Try to input the captcha code and click the send button | Click on the image to reload the captcha";
titleTF.x = titleTF.y = 10;
titleTF.setTextFormat(tFo);
addChild(titleTF);

var inputTF:TextField = new TextField();
inputTF.multiline = false;
inputTF.type = "input";
inputTF.width = 100;
inputTF.height = 20;
inputTF.border = true;
inputTF.defaultTextFormat = tFo;
inputTF.setTextFormat(tFo);
inputTF.x = titleTF.x;
inputTF.y = titleTF.y + int(titleTF.height + 5);
addChild(inputTF);

var statusTF:TextField = new TextField();
statusTF.multiline = true;
statusTF.text = "Server results go here";
statusTF.width = 200;
statusTF.height = 100;
statusTF.border = true;
statusTF.setTextFormat(tFo);
statusTF.x = stage.stageWidth - statusTF.width;
statusTF.y = stage.stageHeight - statusTF.height;
addChild(statusTF);

var captchaLdr:Loader = new Loader();
captchaLdr.addEventListener(MouseEvent.CLICK, captchaLdrClick);
captchaLdr.x = inputTF.x;
captchaLdr.y = inputTF.y + int(inputTF.height + 5);
addChild(captchaLdr);

var sendBtn:Button = new Button();
sendBtn.addEventListener(MouseEvent.CLICK, sendBtnClick);
sendBtn.setStyle("textFormat", tFo);
sendBtn.label = "verify captcha";
sendBtn.x = inputTF.x + int(inputTF.width + 5);
sendBtn.y = inputTF.y;
sendBtn.width = 150;
sendBtn.height = inputTF.height;
addChild(sendBtn);

loadCaptchaImage();

function loadCaptchaImage():void
{
captchaLdr.load(new URLRequest("base/captcha.php"));
}

function captchaLdrClick(event:MouseEvent):void
{
loadCaptchaImage();
}

function sendBtnClick(event:MouseEvent):void
{
capVal.captcha = inputTF.text;
capVal.load();
}

function onCaptchaSuccess(event:CaptchaValidatorEvent):void
{
statusTF.appendText("\nOk, captcha verivied");
}

function onErrorVars(event:CaptchaValidatorEvent):void
{
statusTF.appendText("\n#error: Captcha variable not set/wrong send method");
}

function onErrorCaptcha(event:CaptchaValidatorEvent):void
{
statusTF.appendText("\n#error: Wrong captcha code");
}