/**
 * mp3Real.SampleDataEvent.SAMPLE_DATA
 **/
private function onSampleData(e:SampleDataEvent):void
{
	currentPosition = uint(_position);
 
	var currentTimeIntDiff_1:uint = uint(_position) / 44100;
	currentTime = toDoubleString(uint(currentTimeIntDiff_1 / 60)) + ":" + toDoubleString(currentTimeIntDiff_1 % 60);
 
	var bytes:ByteArray = new ByteArray();
	mp3Proxy.extract(bytes, 4096, _position);
	bytes.position = 0;
	e.data.writeBytes(bytes);
 
	if(!isThumbPress)
		hs_time.value = _position / maxPosition;
 
	bytesSpeed = playbackSpeed * BYTES_PER_CALLBACK;
 
	_position += bytesSpeed;
}

/**
 * mp3Real.SampleDataEvent.SAMPLE_DATA
 **/
private function onSampleData(e:SampleDataEvent):void
{
	var l:Number;
	var r:Number;
	var p:uint;
 
	var loadedSamples:ByteArray = new ByteArray();
	currentPosition = uint(_phase);
 
	bytesSpeed = playbackSpeed * BYTES_PER_CALLBACK;
 
	var currentTimeIntDiff_2:uint = currentPosition / 44100;
	currentTime = toDoubleString(uint(currentTimeIntDiff_2 / 60)) + ":" + toDoubleString(currentTimeIntDiff_2 % 60);
 
	if (_isPlayingSound && currentTime == maxTime)
	{
		_isPlayingSound = false;
	} 
 
 
	if(!isThumbPress)
		hs_time.value = _phase / maxPosition;
 
	mp3Proxy.extract(loadedSamples, BYTES_PER_CALLBACK * playbackSpeed, currentPosition);
	loadedSamples.position = 0;
 
	while (loadedSamples.bytesAvailable > 0)
	{
		p = uint(_phase - currentPosition) * 8;
 
		if (p < loadedSamples.length - 8 && e.data.length <= BYTES_PER_CALLBACK * 8)
		{
			loadedSamples.position = p;
 
			l = loadedSamples.readFloat();
			r = loadedSamples.readFloat();
 
			e.data.writeFloat(l);
			e.data.writeFloat(r);
		}
		else
		{
			loadedSamples.position = loadedSamples.length;
		}
 
		_phase += playbackSpeed;
	}
}

package
{
	import flash.display.DisplayObject;
	import flash.display.MovieClip;
	import flash.display.StageAlign;
	import flash.display.StageScaleMode;
	import flash.events.Event;
	import flash.events.ProgressEvent;
	import flash.text.TextField;
	import flash.text.TextFieldAutoSize;
	import flash.utils.getDefinitionByName;
 
	public class PreloaderApp extends MovieClip
	{
 
		/**
		 * PreloaderApp Constructor.
		 */
		public function PreloaderApp()
		{
			this.addEventListener(Event.ADDED_TO_STAGE, handleToStage);
		}
 
		/**
		 * Handle ADDED_TO_STAGE event.
		 * @param event
		 */
		private function handleToStage(event:Event):void
		{
			this.removeEventListener(Event.ADDED_TO_STAGE, handleToStage);
 
			//stage setting
			stage.showDefaultContextMenu = false;
			stage.align = StageAlign.TOP_LEFT;
			stage.scaleMode = StageScaleMode.NO_SCALE;
 
			createChildren();
 
			addEventListener(Event.ENTER_FRAME, loadApplication);
 
			this.loaderInfo.addEventListener(ProgressEvent.PROGRESS, handleProgress);
			this.loaderInfo.addEventListener(Event.COMPLETE, handleComplete);
		}
 
		private var _preLoadingText:TextField;
		/**
		 * createChildren
		 */
		private function createChildren():void
		{
			_preLoadingText = new TextField();
			_preLoadingText.text = "Loading...";
			_preLoadingText.textColor = 0x000000;
			_preLoadingText.x = (stage.stageWidth / 2) - (_preLoadingText.width / 2);
			_preLoadingText.y = (stage.stageHeight / 2) - (_preLoadingText.height / 2);
			_preLoadingText.autoSize = TextFieldAutoSize.CENTER;
			addChild(_preLoadingText);
		}
 
		/**
		 * Handle progress.
		 * @param event
		 */
		private function handleProgress(event:ProgressEvent):void
		{
			var percent:int = Math.floor(event.bytesLoaded / event.bytesTotal * 100);
			_preLoadingText.text = "Loading..." + percent + "%";
		}
 
		/**
		 * Handle load complete.
		 * @param event
		 */
		private function handleComplete(event:Event):void
		{
			this.loaderInfo.removeEventListener(ProgressEvent.PROGRESS, handleProgress);
			this.loaderInfo.removeEventListener(Event.COMPLETE, handleComplete);
		}
 
		/**
		 * Load main application.
		 * @param e
		 */
		private function loadApplication(event:Event):void
		{
			if (currentFrame == totalFrames)
			{
				removeEventListener(Event.ENTER_FRAME, loadApplication);
				stop();
 
				var cls:Class = getDefinitionByName("Application") as Class;
				addChild(new cls() as DisplayObject);
 
				removeChild(_preLoadingText);
				_preLoadingText = null;
			}
		}
	}
}

package
{
	import flash.display.Sprite;
	import flash.events.Event;
 
	public class Application extends Sprite
	{
 
		private static var _instance:Application;
		/**
		 * Unique instance.
		 * @return
		 */
		public static function getInstance():Application
		{
			return _instance;
		}
 
		/**
		 * Application Constructor.
		 */
		public function Application()
		{
			super();
			addEventListener(Event.ADDED_TO_STAGE, initOnStage);
		}
 
		/**
		 * Handle ADDED_TO_STAGE event.
		 * @param event
		 */
		protected function initOnStage(event:Event):void
		{
			//remove ADDED_TO_STAGE listener.
			this.removeEventListener(Event.ADDED_TO_STAGE, initOnStage);
 
			//Set unique instance.
			if (!_instance)
				_instance = this;
 
			//...
		}
	}
}