Синтаксис условий 1С

В общем виде условный оператор выглядит следующим образом:

Если <Логическое выражение> Тогда
    // Операторы
[ИначеЕсли <Логическое выражение> Тогда]
    // Операторы
[Иначе]
    // Операторы
КонецЕсли;

Из приведенного синтаксиса, можно сказать об основных особенностях оператора:

1. Логический оператор всегда начинается с ключевой фразы Если и заканчивается фразой КонецЕсли;
2. Логическое выражение — выражение, результатом которого является значение типа Булево, то есть Истина или Ложь. Если результат выполнения логического выражения — Истина, выполняется блок операторов, идущих после ключевого слова Тогда;
3. В логическом выражении могут быть использованы операции сравнения: «=», «<>» (не равно), «>», «<«, «>=» (больше или равно), «<=» (меньше или равно);
4. Также в логическом выражении могут применятся булевы операции: «И», «ИЛИ», «НЕ»;
5. Можно создавать неограниченное количество блоков ИначеЕсли, выражение которых будет проверяться, если выражения предыдущих блоков Если и ИначеЕсли вернули Ложь;
6. Также можно использовать один блок Иначе. Он будет выполняться, если не выполнился ни один из предыдущих блоков Если и ИначеЕсли.

Примеры использования условий в 1С

От теории перейдем к практике. Приведем несколько примеров использования условий. Обработку с разобранными примерами можно скачать Здесь.

Простые условия

Пример 1. Пусть у нас есть две числовые переменные Число1 и Число2. Вывести пользователю сообщение, если значения этих переменных равны.

Если Число1 = Число2 Тогда
    Сообщить("Числа равны");
КонецЕсли;

Таким образом мы реализовали простейшее условие в 1с 8. Операция сравнения «=» проверяет равенство переменных расположенных слева и справа от нее. Если значения равны, выполняются операторы после ключевого слова Тогда (в нашем случае оператор один — Сообщить). Если же значения не равны, операторы расположенные в условии не выполнятся.

Пример 2. Немного усложним первый пример. Выведем сообщение в случае неравенства чисел.

Если Число1 = Число2 Тогда
    Сообщить("Числа равны");
Иначе
    Сообщить("Числа не равны");
КонецЕсли;

В случае равенства чисел алгоритм будет отрабатывать также, как и в первом примере. А вот в случае их неравенства, выполнятся операторы после Иначе. Тут нет смысла использовать дополнительные условия, так как числа либо равны друг другу, либо нет.

Составные условия

Пример 3. Пусть у нас есть три числовые переменные Число1,Число2 и Число3. Разделить Число1 либо на Число2, либо на Число3. Делить на 0 нельзя, делитель будем выбирать исходя из этого условия.

Если Число2 <> 0 Тогда
		
    Частное = Число1 / Число2;
    Сообщить(Частное);
		
ИначеЕсли Число3 <> 0 Тогда
		
    Частное = Число1 / Число3;
    Сообщить(Частное);
		
Иначе
    Сообщить("Делители равны 0, операция невозможна");
КонецЕсли;

Теперь в условие добавился блок ИначеЕсли. Условный оператор отработает следующим образом:

• Если Число2 не равно нулю, тогда делим Число1 на Число2;
• Если первое условие вернуло Ложь (т.е. Число2 оказалось равным нулю.), только в этом случае произойдет проверка следующего условия (в блоке ИначеЕсли). Если Число3 не равно нулю, тогда делим Число1 на Число3;
• Если ни одно из предыдущих условий не выполнилось (и Число2 и Число3 оказались равны нулю), тогда выполняются операторы после Иначе (выводится сообщение о невозможности деления);

Также этот пример можно выполнить используя вместо операции «<>», комбинацию операции «=» и логической операции «Не»;

Если Не Число2 = 0 Тогда
    ...		
ИначеЕсли Не Число3 = 0 Тогда
    ...	
Иначе
    ...
КонецЕсли;

Логика получается точно такая же — «не равно». Только сначала произойдет проверка на равенство, а потом изменение полученного значение на противоположное (Истина на Ложь, Ложь на Истина).

Условия 1С со сложными логическими выражениями

Пример 4. Разделить Число1 на сумму переменных Число2 и Число3. Чтобы не получить ошибку деления, произвести проверку на 0.

Если Число2 = 0 И Число3 = 0 Тогда
    Сообщить("Нельзя делить на 0");
Иначе
		
    Частное = Число1 / (Число2 + Число3);
    Сообщить(Частное);
		
КонецЕсли;

В логическом выражении используется операция «И». То есть для выполнения условия и Число2 и Число3 должны быть равными нулю. Вычисление логического выражения будет осуществляться в следующем порядке:

• Вычисляется значение первой части условия (Число2 = 0);
  • Если ее значение Ложь, вычисление второй части (Число3 = 0) производится не будет, выполнятся операторы расположенные после Иначе;
  • Если его значение Истина:
• Вычисляется значение второй части условия (Число3 = 0);
  • Если ее значение Ложь, выполнятся операторы расположенные после Иначе;
  • Если ее значение Истина, выполнятся операторы расположенные после Тогда.

Для выполнение составного условия 1с, разделенного операцией «И» требуется выполнение каждого под условия. Каждое под условие проверяется по порядку. Если при вычислении какого-то под условия получается Ложь, то следующие проверяться уже не будут.

Пример 5. Разделить Число1 на произведение переменных Число2 и Число3. Чтобы не получить ошибку деления, произвести проверку на 0.

Если Число2 = 0 Или Число3 = 0 Тогда
    Сообщить("Нельзя делить на 0");
Иначе
		
    Частное = Число1 / (Число2 * Число3);
    Сообщить(Частное);
		
КонецЕсли;

В логическом выражении используется операция «ИЛИ». То есть для выполнения условия Число2 или Число3 должно быть равным нулю. При использовании операции «Или» всегда вычисляются все под условия.

Сообщение Условия 1С. Использование условного оператора появились сначала на 1cguide.ru.

В 1с существует три вида циклов:

Цикл Пока

Данный цикл предназначен для осуществления повторений, пока выполняется условие. Синтаксис цикла выглядит так:

Пока <Логическое выражение> Цикл
    // Операторы
КонецЦикла;

Для выполнения очередного повторения Логическое выражение должно возвращать значение Истина. Это работает следующим образом:

1. Вычисляем значение Логического выражения. Если оно Ложь, цикл завершается. Если Истина:
2. Выполняем операторы цикла;
3. Возвращаемся на п. 1.

Пример 1. При помощи сообщения вывести пользователю цифры от 1 до 10.

Цифра = 1;
Пока Цифра <= 10 Цикл
		
    Сообщить(Цифра);
    Цифра = Цифра + 1;
		
КонецЦикла;

Таким образом в цикле Пока нам необходимо не только выполнить требуемое действие, но и изменить переменную участвующую в проверке его условия. Если забыть это сделать, можно получить бесконечный цикл, который приведет к зависанию системы.

Пример 2. А теперь только не четные, в интервале от 1 до 100, в обратном порядке.

Цифра = 100;
Пока Цифра >= 1 Цикл
		
    Если Цифра % 2 = 1 Тогда	
	Сообщить(Цифра);
    КонецЕсли;
		
    Цифра = Цифра - 1;
		
КонецЦикла;

В примере используется операция %. Она получает остаток от деления одного числа на другое.

При помощи цикла Пока можно обойти массив или любую другую коллекцию в обратном порядке. Это необходимо не часто, но реализовать такой механизм при помощи других циклов проблематично. Рассмотрим такой механизм в примере 3.

Массив = Новый Массив;
Массив.Добавить(1);
Массив.Добавить(2);
Массив.Добавить(3);
	
Индекс = Массив.Количество();
Пока Индекс > 0 Цикл
		
    ЭлементМассива = Массив[Индекс - 1];
    Сообщить(ЭлементМассива);
		
    Индекс = Индекс - 1;
		
КонецЦикла;

Также цикл Пока часто используется для обхода выборки из результата запроса. У выборки для этого есть специальный метод Следующий(). Он осуществляет переход на следующую строку и возвращает Истина, если такая строка есть. Если же следующая строка отсутствует в выборке, метод возвращает Ложь. Нельзя забывать, что работу с запросом можно осуществлять только в серверной процедуре (или функции).

Пример 4. При помощи запроса выбрать всех пользователей, кроме недействительных. Обойти выборку циклом Пока.

Запрос = Новый Запрос;
Запрос.Текст = 
"ВЫБРАТЬ
|    Пользователи.Ссылка КАК Ссылка
|ИЗ
|    Справочник.Пользователи КАК Пользователи
|ГДЕ
|    НЕ Пользователи.Недействителен";
	
Выборка = Запрос.Выполнить().Выбрать();
	
Пока Выборка.Следующий() Цикл
    Сообщить(Выборка.Ссылка);
КонецЦикла;

Цикл Для

Предназначен для осуществления заданного количества повторений, это так называемый цикл со счетчиком.

Для <Счетчик> = <Выражение1> По <Выражение2> Цикл
    // Операторы
КонецЦикла;

При каждом проходе цикл увеличивает значение в переменной Счетчик на 1. Начальное значение счетчика указывается в Выражение1, конечное в Выражение2.

Пример 5. Воспользуемся заданием из первого примера и выведем числа от 1 до 10.

Для Счетчик = 1 По 10 Цикл
    Сообщить(Счетчик);
КонецЦикла;

Таким образом в начале выполнения, переменная счетчик будет содержать значение 1. При каждом следующем повторении значение счетчика будет увеличиваться также на единицу, пока не достигнет 10. Повторение со значением счетчика 10, будет последним.

Пример 6. Вывести посимвольно строку «Привет мир!».

Текст = "Привет мир!";
ДлинаСтроки = СтрДлина(Текст);
	
Для НомерСимвола = 1 По ДлинаСтроки Цикл
		
    Символ = Сред(Текст, НомерСимвола, 1);
    Сообщить(Символ);
		
КонецЦикла;

То есть при помощи цикла Для мы обходим номера символов строки. А внутри цикла получаем символ по его номеру.

Цикл Для Каждого

Используется для обхода коллекций. Может обходить таблицы значений, массивы, структуры, списки значений (и любые другие коллекции).

Для каждого <Переменная1> Из <Переменная2> Цикл
    // Операторы
КонецЦикла;

В Переменная2 указывается коллекция, а в Переменная1 на каждом проходе цикла будет содержаться элемент коллекции. Контролировать количество элементов при этом не нужно, это делается автоматически. То есть цикл закончит выполняться, как только закончатся элементы коллекции.

Пример 7. Получить сумму элементов числового массива.

Массив = Новый Массив;
Массив.Добавить(100);
Массив.Добавить(-5);
Массив.Добавить(3.4);
Массив.Добавить(0);
Массив.Добавить(3);
	
СуммаЭлементов = 0;
	
Для Каждого ЭлементМассива Из Массив Цикл
    СуммаЭлементов = СуммаЭлементов + ЭлементМассива;
КонецЦикла;
	
Сообщить(СуммаЭлементов);

В переменной ЭлементМассива при каждом повторении цикла содержится число. Сложив их все, получаем: 101,4.

Цикл Для Каждого часто используется для обхода таблиц значений. В этом случае при каждом повторении цикла переменная элемента коллекции будет содержать не конкретное значение, а строку таблицы. В частности таблицу значений можно получить при выгрузке результата запроса (метод Выгрузить()).

Пример 8. При помощи запроса выбрать всех пользователей. Выгрузить результат в таблицу значений, обойти ее и вывести пользователей с заполненным физическим лицом.

Запрос = Новый Запрос;
Запрос.Текст = 
"ВЫБРАТЬ
|    Пользователи.Ссылка КАК Пользователь,
|    Пользователи.ФизическоеЛицо КАК ФизическоеЛицо
|ИЗ
|    Справочник.Пользователи КАК Пользователи";
	
Таблица = Запрос.Выполнить().Выгрузить();
	
Для Каждого СтрокаТаблицы Из Таблица Цикл
		
    Если ЗначениеЗаполнено(СтрокаТаблицы.ФизическоеЛицо) Тогда
        Сообщить(СтрокаТаблицы.Пользователь);
    КонецЕсли;
		
КонецЦикла;

В примере видно, что переменная СтрокаТаблицы на каждом проходе цикла, содержит очередную строку таблицы. Доступ к ее полям осуществляется через «точку».

Специальные операторы циклов

Циклы 1с могут использовать специальные операторы Продолжить и Прервать. Они предназначены для предварительного завершения итерации и всего цикла соответственно.

Оператор Продолжить завершает текущее повторение цикла, не дожидаясь выполнения следующих за ним операторов. То есть с его помощью мы можем пропускать не нужные действия внутри цикла.

Пример 9. Немного модифицируем код из предыдущего примера, и напишем его с использованием оператора Продолжить.

Для Каждого СтрокаТаблицы Из Таблица Цикл
		
    Если Не ЗначениеЗаполнено(СтрокаТаблицы.ФизическоеЛицо) Тогда
        Продолжить;	
    КонецЕсли;
		
    Сообщить(СтрокаТаблицы.Пользователь);
		
КонецЦикла;

Завершаем проход цикла, если физическое лицо не заполнено. Метод Сообщить будет выполняться, только при условии наличия физлица.

С оператором Прервать все еще проще, он завершает выполнение цикла. Вне зависимости от того, сколько повторений еще должно было выполниться.

Пример 10. Рассмотрим задачу из самого первого примера. Выведем числа от 1 до 10 циклом Пока. Но при этом модифицируем программный код.

Цифра = 1;
Пока Истина Цикл
		
    Если Цифра > 10 Тогда
	Прервать;
    КонецЕсли;
		
    Сообщить(Цифра);
    Цифра = Цифра + 1;
		
КонецЦикла;

Если в таком цикле не использовать оператор Прервать, то он станет бесконечным, так как в выражении напрямую установлено значение Истина. Получается, что проверка выхода из шапки цикла, перенесена в его тело. Конечно, в таком виде циклы 1с вряд ли будут использоваться, для решения подобной задачи. Но существуют реальные случаи применения конструкции Пока Истина Цикл, когда условие цикла задать проблематично и проще его прервать в нужный момент.

Также вы можете скачать обработку со всеми рассмотренными примерами Циклы 1с — примеры. Обработка написана под управляемое приложение, в качестве конфигурации для запросов использовалась демо-база БСП 3.1.

Сообщение Циклы 1с 8 — описание с примерами появились сначала на 1cguide.ru.

Рассмотрим пример. Разработаем обработку, которая будет представлять элемент справочника Пользователи в виде поля html документа. Для разработки примера я использовал демо БСП 3.1 (управляемое приложение).

Выведем в документ следующие поля справочника:

• Наименование и Комментарий в виде текста;
• ФизическоеЛицо и Подразделение в виде ссылок;
• Фотографию пользователя;
• Контактную информацию в виде таблицы.

Размещение реквизитов на форме

Для начала создадим внешнюю обработку и добавим форму. На форме создадим два реквизита Пользователь (тип СправочникСсылка.Пользователи) и ПредставлениеHTML (тип Строка неограниченной длины). Перетащим реквизиты в дерево элементов. Для элемента ПредставлениеHTML выберем вид Поле HTML документа и отключим отображение заголовка. Должно получится так:

Теперь поработаем над программной частью формы:

• Заполнять html поле данными будем при изменении пользователя. Поэтому создадим для него обработчик события ПриИзменении;
• Работа же с самим полем потребует перехода на сервер, так как нам необходимо выполнять запрос и получать данные из хранилища значений. Поэтому для заполнения данных html создадим функцию ЗаполнитьHTMLПредставление с директивой НаСервереБезКонтекста. В качестве параметра передадим в нее ссылку на пользователя;

В итоге должно получиться следующее:

&НаКлиенте
Процедура ПользовательПриИзменении(Элемент)
    ПредставлениеHTML = ЗаполнитьHTMLПредставление(Пользователь);	
КонецПроцедуры

&НаСервереБезКонтекста
Функция ЗаполнитьHTMLПредставление(Пользователь)
КонецФункции

Получение данных

Во входные параметры функции ЗаполнитьHTMLПредставление  мы передаем только ссылку на пользователя, поэтому для начала надо собрать все данные, необходимые для вывода в html документ. Для этого воспользуемся запросом, который вынесем в отдельную процедуру. Приводить текст процедуры здесь я не буду, чтобы не занимать много места. Ознакомиться с ним можно во внешней обработке, ссылка на которую находится внизу статьи.

Функция возвращает структуру, в которой содержится две выборки. Первая, ВыборкаДанных — содержит одну строку с основными данными пользователя. Вторая, ВыборкаКонтактов — содержит контактную информацию пользователя, в разрезе двух полей: Вид и Представление. Вызов функции получения данных выглядит так:

&НаСервереБезКонтекста
Функция ЗаполнитьHTMLПредставление(Пользователь)
	
    ДанныеПользователя = ПолучитьДанныеПользователя(Пользователь);
	
    Данные = ДанныеПользователя.ВыборкаДанных;
    Контакты = ДанныеПользователя.ВыборкаКонтактов;

    Если Не Данные.Следующий() Тогда
	Возврат "";
    КонецЕсли;

    ...

Заполнение стилей 1с html поля

Теперь в функции ЗаполнитьHTMLПредставление будем описывать html документ. Начнем с обязательных тегов <html> и <head>. После чего перейдем к заполнению стилей (тег <style>), которые будут применяться во всем документе, а также в отдельных его блоках.

HTMLТекст = 
"<html>
|<head>
|
|<style type=""text/css"">
|
|    body {
|         margin-top: 2px;
|         margin-left: 2px;
|         margin-right: 2px;
|         font-family: Arial; 
|         font-size: 12pt;}
|    table {
|          border: 1px solid;
|          border-collapse: collapse;}
|    td {
|       border: 1px solid;}
|    th {
|       border: 1px solid;}
|    a:link {
|           color: #006699;} 
|    a:hover {
|            color: #006699; 
|            text-decoration: underline;}
|    p {
|      margin-top: 10px;}
|    img {
|        width: 150;
|        height: 150}
|
|</style>
|</head>";

Рассмотрим заполнение стилей более подробно:

• body — описание стилей тела документа. Так как заголовки у нас отсутствуют, стили будут действовать для всего документа.
  

  Свойство	Описание
  margin-top	Отступ от верхнего края документа
  margin-left	Отступ от левого края документа
  font-family	Шрифт
  font-size	Размер шрифта

• table — описание стилей таблиц.
  

  Свойство	Описание
  border	Описание границы (толщина: 1px, одинарная линия: solid)
  border-collapse	Отображение границы вокруг ячеек таблицы (collapse: одна линия между ячейками)

• td — описание стилей ячеек таблиц. th — описание стилей заголовочных ячеек таблиц.
• a:link — описание стилей ссылок, a:hover — описание стилей ссылок, на которые наведен курсор.
  

  Свойство	Описание
  color	Цвет текста
  text-decoration	Оформление текста подчеркиванием (underline — подчеркнутый текст)

• p — описание стилей абзацев. Margin-top в данном контексте, означает отступ сверху абзаца.
• img — описание стилей изображений. Задавать стили можно и для каждого отдельного изображения. Но если изображение одно (как у меня) или все они однотипные, то удобнее описать их в общем блоке стилей.
  

  Свойство	Описание
  width	Ширина
  height	Высота

Создание тела html документа в 1с 8

После описания стилей займемся формированием тела документа. Для этого используем тег <body>.

HTMLТекст = HTMLТекст + "<body>";

Вывод изображения в html

Начнем с вывода фотографии пользователя. В элементе справочника она хранится в реквизите Фотография, в виде хранилища значения. Его мы получили вместе с остальными данными пользователя, при помощи запроса.

ДвоичныеДанныеФотографии = Данные.Фотография.Получить();
Base64ДанныеФотографии = Base64Строка(ДвоичныеДанныеФотографии);

HTMLТекст = HTMLТекст
    + "<img src='data:image/;base64,"
    + Base64ДанныеФотографии + "'>";

Разберем представленный код:

• Хранилище содержит двоичные данные изображения, их необходимо получить. Используем для этого метод Получить(), который распаковывает данные хранилища;
• В html мы можем вывести изображение либо указав ссылку на него, либо использовав его двоичные данные, в кодировке base64. Для этого используем метод Base64Строка;
• После подготовки данных, можно выводить их в документ.
  • Используем тег <img>, применяемый для вывода изображений;
  • Атрибут src указывает адрес выводимого изображения или его данные. У нас это двоичные данные, поэтому в дополнение к ним необходимо использовать префикс data:image/ и указание типа данных base64.

Для того чтобы отделить изображение от следующей информации, используем тег <p>. Он означает начало нового абзаца. При описании стилей мы указали, что перед началом нового абзаца устанавливается отступ в 10 пикселей.

HTMLТекст = HTMLТекст + "<p>";

Вывод текстового реквизита в html

После фотографии выведем основные данные пользователя в следующем формате:

ИмяРеквизита: Реквизит

Начнем с имени пользователя:

HTMLТекст = HTMLТекст + "<font color=#413003>";
HTMLТекст = HTMLТекст + "Полное имя: ";
HTMLТекст = HTMLТекст + "</font>";

HTMLТекст = HTMLТекст + Данные.Наименование;
HTMLТекст = HTMLТекст + "<br>";

Разберем представленный код:

• Для того, чтобы имя реквизита не сливалось с его содержанием, выделим его другим цветом. Для этого используем свойство <font>, позволяющее изменять характеристики текста. В нашем случае это цвет color.
• После вывода данных используем тег <br>. Он предназначен для перехода на следующую строку.

Вывод ссылки в html

Теперь выведем в документ физлицо пользователя. Так как оно представлено ссылочным типом, оформим его в виде ссылки.

ШаблонНавигационнойСсылки = "<A href=v8doc:%1>%2</A>";

HTMLТекст = HTMLТекст + "<FONT color=#413003>";
HTMLТекст = HTMLТекст + "Физическое лицо: ";
HTMLТекст = HTMLТекст + "</FONT>";

НавигационнаяСсылка = ПолучитьНавигационнуюСсылку(Данные.ФизическоеЛицо);
ФизическоеЛицо = СтрШаблон(ШаблонНавигационнойСсылки, 
                           НавигационнаяСсылка, 
                           Данные.ФизическоеЛицо);

HTMLТекст = HTMLТекст + ФизическоеЛицо;
HTMLТекст = HTMLТекст + "<br>";

Разберем представленный код:

• Для создания ссылок используется тег <a>. Его атрибут href задает адрес ссылки. Для удобства работы создадим шаблон для вывода навигационной ссылки на физлицо. В параметр %1 будем выводить ссылку, а в параметр %2 текст ссылки;
• Для получения навигационной ссылки используем метод ПолучитьНавигационнуюСсылку(<Ссылка>);
• Заполним параметры шаблона, используя строковую функцию СтрШаблон;

Далее нам необходимо будет вывести еще один текстовый реквизит и еще один ссылочный. Для того чтобы не дублировать код вынесем добавление реквизита в html в отдельную, универсальную процедуру.

&НаСервереБезКонтекста
Процедура ДобавитьРеквизит(HTMLТекст, Подпись, Значение)

    HTMLТекст = HTMLТекст + "<FONT color=#413003>";
    HTMLТекст = HTMLТекст + Подпись + ": ";
    HTMLТекст = HTMLТекст + "</FONT>";
  
    Если ТипЗнч(Значение) = Тип("Строка") Тогда 
        HTMLТекст = HTMLТекст + Значение;
    Иначе

        ШаблонНавигационнойСсылки = "<A href=v8doc:%1>%2</A>";

        НавигационнаяСсылка = ПолучитьНавигационнуюСсылку(Значение);
        HTMLТекст = HTMLТекст + СтрШаблон(ШаблонНавигационнойСсылки, 
                                          НавигационнаяСсылка, 
                                          Значение);

    КонецЕсли;

    HTMLТекст = HTMLТекст + "<br>";

КонецПроцедуры

Вывод всех реквизитов будет выглядеть следующим образом:

ДобавитьРеквизит(HTMLТекст, "Полное имя", Данные.Наименование);
ДобавитьРеквизит(HTMLТекст, "Физическое лицо", Данные.ФизическоеЛицо);
ДобавитьРеквизит(HTMLТекст, "Подразделение", Данные.Подразделение);
ДобавитьРеквизит(HTMLТекст, "Комментарий", Данные.Комментарий);	

Вывод таблицы в html 1с

Осталось вывести таблицу контактной информации пользователя. Это делается довольно просто.

HTMLТекст = HTMLТекст + "<table>";

//Шапка таблицы
HTMLТекст = HTMLТекст + "<tr>";

HTMLТекст = HTMLТекст + "<th>Вид</th>";
HTMLТекст = HTMLТекст + "<th>Описание</th>";

HTMLТекст = HTMLТекст + "</tr>";

//Тело таблицы
Пока Контакты.Следующий() Цикл

    HTMLТекст = HTMLТекст + "<tr>";

    HTMLТекст = HTMLТекст + "<td>" + Контакты.Вид + "</td>";
    HTMLТекст = HTMLТекст + "<td>" + Контакты.Представление + "</td>";

    HTMLТекст = HTMLТекст + "</tr>";

КонецЦикла;

HTMLТекст = HTMLТекст + "</table>";

Разберем код:

• Для вывода таблицы используется тег <table>;
• Для вывода строки таблицы тег <tr>;
• Тег <td> отвечает за вывод ячейки;
• Для вывода ячейки заголовка используется тег <th>.

На этом формирование поля html документа в 1с завершено. Осталось только закрыть теги и вернуть сформированный текст.

HTMLТекст = HTMLТекст + "</body></html>";

Возврат HTMLТекст;

В итоге у нас получается html поле, заполненное следующим образом:

Обработка нажатия на ссылку

В нашей обработке мы используем не веб ссылки, а на навигационные ссылки 1с. По этой причине система не может корректно обработать их нажатие. Это можно исправить, создав обработчик события ПриНажатии, для Поля HTML документа.

&НаКлиенте
Процедура ПредставлениеHTMLПриНажатии(Элемент, ДанныеСобытия, СтандартнаяОбработка)
	
    Если Лев(ДанныеСобытия.Href, 6) = "v8doc:" Тогда 
		
        СтандартнаяОбработка = Ложь;
		
	НавигационнаяСсылкаПоля = Сред(ДанныеСобытия.Href, 7);		
	ПерейтиПоНавигационнойСсылке(НавигационнаяСсылкаПоля);
		
    КонецЕсли;

КонецПроцедуры

В обработчике мы анализируем текст ссылки, на которую произошло нажатие. Если это навигационная ссылка, обрабатываем ее по отдельному алгоритму. Получаем текст и осуществляем переход. Таким образом при нажатии на ссылку, у нас произойдет переход на форму элемента справочника.

Скачать обработку формирования html поля можно здесь: СозданиеHTMLПоля

Сообщение 1С html. Cоздание поля html документа появились сначала на 1cguide.ru.

ДанныеСтроки = Элементы.ТаблицаФормы.ДанныеСтроки(ИдентификаторСтроки);

Вся информация, представленная в статье, относится только к управляемому приложению. Особенности использования метода ДанныеСтроки:

• Является клиентским, его нельзя использовать на сервере. Структуру данных, полученную в результате его использования также нельзя передать на сервер;
• Содержит данные реквизитов добавленных на форму, а также данные реквизитов с установленным флагом Использовать всегда. Остальные реквизиты отсутствуют в коллекции;
• Возвращает данные аналогичные свойству ТекущиеДанные таблицы формы. Разница лишь в том, что при помощи метода ДанныеСтроки можно получить структуру данных любой строки таблицы, а не только текущей;
• Идентификатор строки, передаваемый в параметре может быть разных типов, в зависимости от источника таблицы формы. Для источников ТаблицаЗначений, ДеревоЗначений, СписокЗначений, ТабличнаяЧасть идентификатор строки числовой. Для ДинамическогоСписка это обычно Ссылка, которая является ключом строки списка. Идентификатор текущей строки содержится в свойстве таблицы формы ТекущаяСтрока.

Таким образом для таблицы формы ТаблицаТоваров следующие действия будут идентичны (приведут к получению данных текущей строки):

ТекущаяСтрока = Элементы.ТаблицаТоваров.ТекущаяСтрока;
ТекущиеДанные = Элементы.ТаблицаТоваров.ДанныеСтроки(ТекущаяСтрока);

ТекущиеДанные = Элементы.ТаблицаТоваров.ТекущиеДанные;

Получение идентификаторов строк

Так как параметром метода ДанныеСтроки является идентификатор, важно знать откуда его можно получить:

• Для текущей строки таблицы формы идентификатор хранится в свойстве ТекущаяСтрока;

  ТекущаяСтрока = Элементы.ТаблицаТоваров.ТекущаяСтрока;

• Идентификаторы выделенных строк таблицы формы можно получить при помощи свойства ВыделенныеСтроки. В нем содержится массив идентификаторов.

  ВыделенныеСтроки = Элементы.ТаблицаТоваров.ВыделенныеСтроки;

• Идентификатор можно получить непосредственно из строки источника таблицы формы. Для этого используется метод ПолучитьИдентификатор(). Его можно применять и на клиенте и на сервере.

  Для Каждого СтрокаИсточника Из ТаблицаТоваров Цикл
      Идентификатор = СтрокаИсточника.ПолучитьИдентификатор();
  КонецЦикла;
  

Данные строки 1С — пример использования

Рассмотрим пример получения данных выделенных строк таблицы формы при нажатии кнопки.

&НаКлиенте
Процедура ПолучитьДанныеСтрок(Команда)
		
    ВыделенныеСтроки = Элементы.ТаблицаТоваров.ВыделенныеСтроки;
	
    Для Каждого ВыделеннаяСтрока Из ВыделенныеСтроки Цикл
		
        ДанныеСтроки = Элементы.ТаблицаТоваров.ДанныеСтроки(ВыделеннаяСтрока);
		
        Если Не ДанныеСтроки = Неопределено Тогда
	    //Код обрабатывающий данные выделенной строки
	КонецЕсли;
		
    КонецЦикла;
	
КонецПроцедуры

Сообщение Данные строки 1С — метод таблицы формы появились сначала на 1cguide.ru.

• Ссылка. Если у динамического списка задана основная таблица объектного типа данных (Справочник, Документ и т.п.);
• СтрокаГруппировкиДинамическогоСписка. Если в динамический список добавлены группировки и текущей является именно такая строка;
• КлючСтрокиДинамическогоСписка. Если у динамического списка не задана основная таблица и ключевые поля заданы вручную. Представляет из себя набор значений, обеспечивающих уникальный ключ для строки списка;
• <ТипРегистра>КлючЗаписи.<ИмяРегистра>. Ключ с уникальным набором значений, позволяющий идентифицировать запись регистра. Например:

  РегистрСведенийКлючЗаписи.ДополнительныеСведения

• Число. Используется в остальных случаях. Когда основная таблица списка и ключевые поля не заданы, либо в качестве вида ключа задан НомерСтроки;

Применение свойства Текущая строка 1С

Рассмотрим несколько способов практического применения свойства ТекущаяСтрока. С его помощью можно изменить текущую строку таблицы форы, получить строку таблицы источника и т. д.

Изменение текущей строки таблицы

Свойство ТекущаяСтрока доступно не только для чтения, но и для изменения. Таким образом с его помощью мы можем изменить текущую строку таблицы формы.

Пример 1. Для динамического списка справочника Номенклатура, создать процедуру изменяющую текущую строку списка. В качестве новой текущей строки, использовать ссылку на элемент справочника, переданную в параметре.

&НаКлиенте
Процедура ИзменитьТекущуюСтроку(СсылкаНаНоменклатуру);
    Элементы.СписокНоменклатуры.ТекущаяСтрока = СсылкаНаНоменклатуру;
КонецПроцедуры

Заметим, что если строки с указанной ссылкой не будет найдена в таблице формы, то свойство ТекущаяСтрока примет значение Неопределено. Что означает отсутствие текущей строки таблицы.

Получение строки источника

Так как свойство ТекущаяСтрока является идентификатором, его можно использовать в качестве параметра метода НайтиПоИдентификатору. При помощи данного метода можно получить строку источника таблицы формы (нельзя использовать для динамического списка). Так как строку источника можно искать и использовать не только на клиенте, но и на сервере, это дает некоторое преимущество, над свойством таблицы формы ТекущиеДанные.

Пример 2. В серверной процедуре получить данные текущей строки таблицы значений ТаблицаТоваров, которая расположена на форме.

&НаКлиенте
Процедура ПолучитьДанныеСтроки(Команда)
	
    Идентификатор = Элементы.ТаблицаТоваров.ТекущаяСтрока;
    ПолучитьДанныеСтрокиНаСервере(Идентификатор);
	
КонецПроцедуры

&НаСервере
Процедура ПолучитьДанныеСтрокиНаСервере(Идентификатор);

    СтрокаТаблицы = ТаблицаТоваров.НайтиПоИдентификатору(Идентификатор);
	
    Если Не СтрокаТаблицы = Неопределено Тогда
	//Код обрабатывающий данный полученной строки
    КонецЕсли;
	
КонецПроцедуры

Сообщение Использование свойства Текущая строка 1С появились сначала на 1cguide.ru.

Вся информация, представленная в статье, относится только к управляемому приложению.

Так как свойство относится к элементу формы (таблице), данные получаются именно из него, а не из источника. Из этого следует несколько особенностей свойства ТекущиеДанные:

• Доступно только на клиенте. Его нельзя передавать и использовать на сервере. Поэтому правильно будет получить значения нужных полей в клиентской процедуре и передать их в серверную, при необходимости.

  &НаКлиенте
  Процедура ТаблицаНоменклатурыНоменклатураПриИзменении(Элемент)
  
      ТекущиеДанные = Элементы.ТаблицаНоменклатуры.ТекущиеДанные;	
      НоменклатураПриИзмененииНаСервере(ТекущиеДанные.Номенклатура);
  	
  КонецПроцедуры
  
  &НаСервере
  Процедура НоменклатураПриИзмененииНаСервере(Номенклатура)
      //Серверная обработка изменения строки таблицы
  КонецПроцедуры
  

• Содержит данные реквизитов добавленных на форму, а также данные реквизитов с установленным флагом Использовать всегда. Остальные реквизиты отсутствуют в коллекции.
  
  Как видно на картинке, в текущих данных представлены реквизиты Номенклатура и Сумма, добавленные в таблицу и реквизит Количество с установленным флагом Использовать всегда.
• В случае, если таблица формы пустая или у нее нет активизированной строки, свойство ТекущиеДанные будет содержать значение Неопределено. Поэтому, перед использованием свойства, имеет смысл делать проверку. Но только в тех случаях, когда таблица действительно может быть пустой или не активизированной. Например событие ПриАктивизацииСтроки вызывается и для пустой таблицы. А вот событие ПриИзменении колонки таблицы, может вызываться только при наличии активизированной строки. Поэтому в проверке не будет смысла.

  &НаКлиенте
  Процедура ТаблицаНоменклатурыПриАктивизацииСтроки(Элемент)
  
      Если Элемент.ТекущиеДанные = Неопределено Тогда
          Возврат;
      КонецЕсли;
  	
      Сообщить(Элемент.ТекущиеДанные.Номенклатура);
  		
  КонецПроцедуры
  

• При помощи свойства ТекущиеДанные можно не только читать, но и изменять информацию. Исключение — таблица формы, источником которой является динамический список. В этом случае изменение текущих данных, не приведет к изменению строки таблицы.

  &НаКлиенте
  Процедура ТаблицаНоменклатурыКоличествоПриИзменении(Элемент)
  	
      ТекущиеДанные = Элементы.ТаблицаНоменклатуры.ТекущиеДанные;	
      ТекущиеДанные.Сумма = ТекущиеДанные.Количество * ТекущиеДанные.Цена; 
  	
  КонецПроцедуры
  

Варианты получения свойства Текущие данные 1С

В общем случае к свойству ТекущиеДанные можно обратиться через элемент формы к которому оно относится.

Элементы.<ИмяТаблицыФормы>.ТекущиеДанные

Например:

ТекущиеДанные = Элементы.ТаблицаНоменклатуры.ТекущиеДанные;

Но при обращении к текущим данным из обработчика события таблицы формы, можно воспользоваться параметром Элемент. В нем уже содержится таблица формы. В этом случае обращение к текущим данным будет выглядеть следующим образом:

Элемент.ТекущиеДанные

Например:

&НаКлиенте
Процедура ТаблицаНоменклатурыПриИзменении(Элемент)
	
    Если Элемент.ТекущиеДанные = Неопределено Тогда
        Возврат;
    КонецЕсли;

    //Код обрабатывающий событие
	
КонецПроцедуры

Такое обращение к текущим данным не получится реализовать в обработчиках событий колонок таблицы формы. Так как в параметр Элемент там передается ПолеФормы, относящееся к колонке.

Сообщение Работа со свойством текущие данные 1С появились сначала на 1cguide.ru.

Форматные строки используются в:

• Программном коде, в функции Формат;

  Формат(<Значение>, <ФорматнаяСтрока>)

• Свойствах полей формы, в свойстве ФорматРедактирования;
  
• Оформлении поля СКД. Схема компоновки -> вкладка Поля -> для нужного поля столбец Оформление -> Формат;
  
• Свойствах ячейки макета.
  

При использовании функции Формат, следует помнить, что она возвращает строковое значение, т.е. представление переданной даты в определенном формате.

Формат даты 1с при помощи форматной строки

При помощи форматной строки можно задать параметры форматирования даты. Не стоит описывать их полностью вручную. Лучше всего, воспользоваться встроенным в платформу конструктором, а затем отредактировать полученную форматную строку вручную. Это сэкономит ваши силы и позволит быстро добиться результата.

В свойствах полей, ячеек макета, конструктор форматной строки вызывается нажатием кнопки. А в коде он вызывается аналогично конструктору запроса: контекстное меню -> Конструктор форматной строки…

То есть правильный вызов конструктора для метода Формат, выглядит так:

• Следует описать функцию Формат, без форматной строки:

  ФорматДата = Формат(Дата, "");

• Поставить курсор между кавычек, вызвать конструктор;
• После окончания работы с конструктором нажать ОК.

  ФорматДата = Формат(Дата, "ДФ=dd.MM.yyyy");

Конструктор форматной строки

Сам же конструктор форматной строки представляет собой набор вкладок, предназначенных для форматирования данных различных типов. Нас интересует вкладка Дата. 

В первую очередь следует проверить, подходит ли для ваших целей Локальный формат даты. Если это так, то стоит воспользоваться именно им, так как он учитывает особенности построения дат для разных стран. То есть для русскоязычной версии будет отображать привычную нам дату, а для локализованных версий — привычную иностранным пользователям.

В остальных случаях можно пользоваться произвольным форматом даты. Его можно не только выбирать из выпадающего списка, но и редактировать вручную. Для редактирования используются следующие форматные коды:

• д (d) — день месяца (цифрами) без лидирующего нуля;
• дд (dd) — день месяца (цифрами) с лидирующим нулем;
• ддд (ddd) — краткое название дня недели;
• дддд (dddd) — полное название дня недели;
• М (m) — минута без лидирующего нуля;
• ММ (mm) — минута с лидирующим нулем;
• МММ (MMM) — краткое название месяца *);
• ММММ (MMMM) — полное название месяца *);
• к (q) — номер квартала в году;
• г (y) — номер года без века и лидирующего нуля;
• гг (yy) — номер года без века с лидирующим нулем;
• гггг (yyyy) — номер года с веком;
• ч (h) — час в 12-часовом варианте без лидирующих нулей;
• чч (hh) — час в 12-часовом варианте с лидирующим нулем;
• Ч (H) — час в 24-часовом варианте без лидирующих нулей;
• ЧЧ (HH) — час в 24-часовом варианте с лидирующим нулем;
• м (m) — минута без лидирующего нуля;
• мм (mm) — минута с лидирующим нулем;
• с (s) — секунда без лидирующего нуля;
• сс (ss) — секунда с лидирующим нулем;
• вв (tt) — отображение половины дня AM/PM (действительно только для языков конфигурирования, поддерживающих 12 часовой вариант представления времени).

Также можно добавлять в форматную строку произвольный текст, используя кавычки (если добавляемый текст не может быть интерпретирован, как составная часть даты, тогда можно обойтись и без кавычек):

Итоговый текст такой форматной строки будет выглядеть следующим образом:

ФорматДата = Формат(Дата, "ДФ='dd.MM.yyyy ""г.""'");

Примеры использования формата дат

Приведем несколько примеров форматирования даты.

Дата без времени (05.10.2020)

ФорматДата = Формат(Дата, "ДЛФ=D");

Только время (12:35:50)

ФорматДата = Формат(Дата, "ДЛФ=T");

Месяц текстом, год полностью (Октябрь 2020)

ФорматДата = Формат(Дата, "ДФ='ММММ гггг'");

Месяц текстом кратко, год без тысячелетия (окт. 20)

ФорматДата = Формат(Дата, "ДФ='МММ гг'");

Месяц числом, через точку год полностью (10.2020)

ФорматДата = Формат(Дата, "ДФ=ММ.гггг");

Склонение названия месяца

При форматировании даты не всегда достаточно именительного падежа. Иногда требуется указать, к примеру, что отчет сформирован в «Октябре 2020 г.», а не в «Октябрь 2020 г.». Для решения этой проблемы подойдет серверная строковая функция ПолучитьСклоненияСтроки (доступна, начиная с версии платформы 8.3.13).

ПолучитьСклоненияСтроки(<СклоняемаяСтрока>, <ОписаниеСтроки>, <ФорматнаяСтрока>);

Функция возвращает массив вариантов склонения строки. Подробнее прочитать про заполнение параметров можно в синтаксис помощнике.

Пример. Отформатировать дату в «месяц год», месяц в предложном падеже вывести в виде сообщения.

&НаСервереБезКонтекста
Процедура СклонениеПериодаНаСервере(Дата)

    Месяц = Формат(Дата, "ДФ='MMMM yyyy'");
	
    Описание = "ПЛ=Мужской";
    ФорматнаяСтрока = "ПД=Предложный";
    МассивСклонение = ПолучитьСклоненияСтроки(Месяц, Описание, ФорматнаяСтрока);

    Если Не МассивСклонение.Количество() = 0 Тогда
        МесяцПредложный = МассивСклонение[0];
    Иначе
        МесяцПредложный = Месяц;
    КонецЕсли;	
	
    ШаблонСообщения = "Отчет сформирован в %1";
    ТекстСообщения = СтрШаблон(ШаблонСообщения, МесяцПредложный);
	
    Сообщить(ТекстСообщения);
	
КонецПроцедуры

Сообщение Формат даты 1С использование на примерах появились сначала на 1cguide.ru.

Также можете ознакомиться с более простыми, но менее гибкими способами открыть форму по ссылке: Как в 1с открыть ссылку.

Метод ОткрытьФорму по имени

Самый гибкий и настраиваемый способ программного открытия формы в 1с 8. Рассмотрим подробно его параметры, а также разберем несколько примеров его использования.

ОткрытьФорму(<ИмяФормы>, 
             <Параметры>, 
             <Владелец>, 
             <Уникальность>, 
             <Окно>, 
             <НавигационнаяСсылка>, 
             <ОписаниеОповещенияОЗакрытии>, 
             <РежимОткрытияОкна>)

Следует заметить, что метод ОткрытьФорму является клиентским. Т.е его можно использовать либо в общих модулях с установленным флагом Клиент, либо в процедурах (функциях) форм с директивой &НаКлиенте.

Рассмотрим параметры метода и приведем необходимые примеры.

ИмяФормы

Содержит полный путь к форме. Можно указать, как путь к форме по умолчанию, так и путь к произвольной форме объекта метаданных. Имя формы указывается в следующих двух форматах:

<ТипОбъекта>.<ИмяОбъекта>.<ИмяФормыПоУмолчанию>

или

<ТипОбъекта>.<ИмяОбъекта>.Форма.<ИмяФормы>

• ТипОбъекта. Наименование типа объекта метаданных, например: Справочник, Документ, РегистрСведений и т. д.;
• ИмяОбъекта. Наименование объекта метаданных. Например для справочника: Пользователи, Номенклатура;
• ИмяФормыПоУмолчанию. Стандартное имя формы, набор имен по умолчанию различается для различных объектов метаданных. Например для документа: ФормаВыбора, ФормаОбъекта, ФормаСписка. Полный набор имен по умолчанию можно найти в синтаксис помощнике, в описании метода ОткрытьФорму;
• ИмяФормы. Произвольное имя формы, заданное при ее создании. Например у справочника Пользователи, форма СменаПочты.

Пример 1. Путь к форме выбора по умолчанию, справочника Номенклатура.

"Справочник.Номенклатура.ФормаВыбора"

Пример 2. Путь к форме СменаПочты справочника Пользователи, по ее имени.

"Справочник.Пользователи.Форма.СменаПочты"

Параметры

Содержит Структуру параметров, которые передаются в открываемую форму. Для каждого типа формы, существует набор стандартных параметров, которые не нужно дополнительно обрабатывать в самой форме. Также набор параметров может различаться и для объектов метаданных. Например, параметр Ключ, для форм объектов. В него можно передать ссылку на открываемый объект (если его не передать, будет открыта форма нового объекта).

Подробнее прочитать описание всех возможных стандартных параметров можно в синтаксис помощнике, в ветке Интерфейс (управляемый) -> Форма клиентского приложения (в старых версиях платформы Управляемая форма). Далее в ветках Расширение объектов, Расширение справочника  и т. д., можно найти Параметры формы. Там дается полный список возможных стандартных параметров с описаниями.

Также в структуру можно передавать произвольные параметры, которые можно обрабатывать программно, в открываемой форме. Например в обработчике события ПриСозданииНаСервере.

Рассмотрим примеры открытия различных форм с использованием параметров.

Пример 3. Открыть форму объекта справочника Пользователи, используя ссылку на объект.

ПараметрыФормы = Новый Структура;
ПараметрыФормы.Вставить("Ключ", Ссылка);
	
ОткрытьФорму("Справочник.Пользователи.ФормаОбъекта", ПараметрыФормы);

Пример 4. Открыть форму списка справочника Номенклатура с отбором по реквизиту ВидНоменклатуры и по списку родителей.

Отбор = Новый Структура;
Отбор.Вставить("ВидНоменклатуры", ВидНоменклатуры);
Отбор.Вставить("Родитель", СписокРодителей);
	
ПараметрыФормы = Новый Структура;
ПараметрыФормы.Вставить("Отбор", Отбор);
	
ОткрытьФорму("Справочник.Номенклатура.ФормаСписка", ПараметрыФормы); 

Здесь Отбор — это стандартный параметр для форм, использующих в качестве основного реквизита Динамический список. Например, это формы списка и выбора. Он представляет из себя Структуру, в которую можно добавить значения элементов отбора. В Ключ — имя реквизита, в Значение — значение отбора.

Данным способом можно отобрать значения, используя вид сравнения Равно или ВСписке. Для отбора ВСписке следует добавить в структуру Массив, ФиксированныйМассив, либо СписокЗначений. Следует заметить, что отбор ВИерархии установить данным способом не выйдет.

Владелец

В данный параметр передается элемент формы или форма клиентского приложения (управляемая форма) полностью. Используется для указания подчинения открываемой формы.

Это может потребоваться для многих целей, например для:

• Анализа владельца и выполнения определенных действий в открываемой форме;
• Корректной работы события ОбработкаЗаписиНового, в форме владельце;
• Самостоятельной реализации выбора в поле формы.

Пример 5. Реализовать программный выбор элемента Номенклатура, в поле ввода.

&НаКлиенте
Процедура НоменклатураНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
	
    СтандартнаяОбработка = Ложь;
	
    ПараметрыФормы = Новый Структура;
    ПараметрыФормы.Вставить("ТекущаяСтрока", Номенклатура);	
	
    ОткрытьФорму("Справочник.Номенклатура.ФормаВыбора", ПараметрыФормы, Элемент);
	
КонецПроцедуры

В данном случае необходимо:

• Создать обработчик события НачалоВыбора, для поля ввода;
• Отменить стандартную обработку выбора;
• В параметр Владелец передать элемент формы (поле).

Параметр ТекущаяСтрока, позволяет выделять ранее выбранный элемент в форме выбора. Стоит заменить, что в обычной ситуации такой метод выбора значений не применяется. Его применяют только тогда, когда нет возможности настроить форму выбора под условия задачи.

Уникальность

В параметре можно задать ключ уникальности формы произвольного типа. При открытии формы, платформа будет анализировать, есть в текущем сеансе уже открытая форма, с таким же ключом уникальности. Если такая форма будет найдена, то она будет активизирована, а новая не откроется. Этот механизм работает только для одинаковых форм. Если вы будете открывать формы объекта разных документов с одинаковым ключом, то откроются обе.

По умолчанию, платформа сама генерирует ключ уникальности. Поэтому помимо использования собственного ключа, в параметре Уникальность, можно регулировать использование стандартного. Если передать в него значение Ложь, то будет использован стандартный ключ, если значение Истина, то ключ не будет использоваться совсем. Т.е. будет создаваться новая форма, при каждом использовании метода ОткрытьФорму. Значением по умолчанию является Ложь, поэтому специально задавать его не требуется.

Пример 6. Одновременно открыть две формы объекта справочника Пользователи, по одной и той же ссылке.

ПараметрыФормы = Новый Структура;
ПараметрыФормы.Вставить("Ключ", Пользователь);
	
ОткрытьФорму("Справочник.Пользователи.ФормаОбъекта", ПараметрыФормы,, "1");
ОткрытьФорму("Справочник.Пользователи.ФормаОбъекта", ПараметрыФормы,, "2");

Окно

В параметре можно указать окно, в котором будет открыта новая форма. Тип параметра ОкноКлиентскогоПриложения.

Пример 7. Реализовать программный выбор элемента Номенклатура, в поле ввода. Реализовать выбор в окне формы, на которой расположено поле.

&НаКлиенте
Процедура НоменклатураНачалоВыбора(Элемент, ДанныеВыбора, СтандартнаяОбработка)
	
    СтандартнаяОбработка = Ложь;

    Окно = ЭтаФорма.Окно;
    ОткрытьФорму("Справочник._ДемоНоменклатура.ФормаВыбора",, Элемент,, Окно);
	
КонецПроцедуры

В этом примере мы получаем окно текущей формы и используем его для открытия формы выбора справочника.

НавигационнаяСсылка

Позволяет установить собственную навигационную ссылку для открываемой формы. Устанавливаемая навигационная ссылка должна иметь тип Строка. Значение по умолчанию: Неопределено, при использовании этого значения, навигационная ссылка задается автоматически.

ОписаниеОповещенияОЗакрытии

В параметр передается описание процедуры, которая будет вызвана после закрытия открываемой формы. Тип параметра: ОписаниеОповещения.

Пример 8. В 1с открыть форму программно. Использовать форму объекта справочника Пользователи. После ее закрытия сообщить, что карточка пользователя закрыта.

&НаКлиенте
Процедура ОткрытьФормуПользователя(Пользователь)

    ДопПараметры = Новый Структура;
    ДопПараметры.Вставить("Пользователь", Пользователь);
	
    Оповещение = Новый ОписаниеОповещения("ПослеЗакрытияФормыПользователя", 
                                          ЭтаФорма, 
                                          ДопПараметры);
	
    ПараметрыФормы = Новый Структура;
    ПараметрыФормы.Вставить("Ключ", Пользователь);
	
    ОткрытьФорму("Справочник.Пользователи.ФормаОбъекта", 
                 ПараметрыФормы,,,,, 
                 Оповещение);	

КонецПроцедуры

&НаКлиенте
Процедура ПослеЗакрытияФормыПользователя(Результат, ДопПараметры) Экспорт

    Пользователь = ДопПараметры.Пользователь;
	
    ШаблонСообщения = "Карточка пользователя ""%1"" закрыта";	
    ТекстСообщения = СтрШаблон(ШаблонСообщения, Пользователь);
	
    Сообщить(ТекстСообщения);	

КонецПроцедуры

Используемые в примере параметры описания оповещения:

• Первый: имя процедуры;
• Второй: модуль, в котором она расположена (в данном случае текущая форма);
• Третий: структура дополнительных параметров, которая будет передана в процедуру;

Описанная процедура обязательно должна иметь два параметра:

• Результат. Значение, которое возвращает форма при закрытии. Форма объекта не возвращает значений (если это специально не прописать), поэтому в данном случае значение параметра будет Неопределено. А вот форма выбора, например, вернет массив выбранных значений.
• ДопПараметры. Структура параметров, созданная в описании оповещения.

Также описанная процедура должна быть экспортной.

РежимОткрытияОкна

Позволяет указать режим открытия управляемой формы. По умолчанию Неопределено, вручную можно задать одно из значений системного перечисления РежимОткрытияОкнаФормы:

• БлокироватьВеcьИнтерфейс;
• БлокироватьОкноВладельца;
• Независимый.

Метод ОткрытьФорму по форме

Существует еще один вариант синтаксиса метода ОткрытьФорму.

ОткрытьФорму(<Форма>, <Окно>)

Используется, если вы уже получили форму, произвели с ней какие-то действия и теперь ее необходимо открыть.

Пример 9. Получить форму списка справочника Номенклатура, а затем в 1с открыть форму программно.

Форма = ПолучитьФорму("Справочник._ДемоНоменклатура.ФормаСписка");
ОткрытьФорму(Форма);

Сообщение Как в 1с открыть форму программно появились сначала на 1cguide.ru.

Открыть ссылку используя ПоказатьЗначение

Самый простой способ, использовать метод глобального контекста ПоказатьЗначение. Который показывает в диалоге значение переданное в параметре.

ПоказатьЗначение(<ОписаниеОповещенияОЗавершении>, <Значение>)

В параметр Значение передадим ссылку, которую необходимо открыть. Данный метод является ассинхронным, т.е. не ожидает закрытие указанного значения. Для целей ожидания и обработки закрытого значения, в процедуре существует первый параметр. Но для нашей задачи он не нужен и указывать его не следует.

Таким образом открытие ссылки будет выглядеть следующим образом:

ПоказатьЗначение(, Ссылка);

Если в вашей конфигурации разрешено открытие модальных окон (Свойства конфигурации -> Режим использования модальности, принимает значения Использовать или Использовать с предупреждениями), то можно использовать метод ОткрытьЗначение.

ОткрытьЗначение(<Значение>)

Открытие формы по ссылке

Также в 1с открыть ссылку можно при помощи метода ОткрытьФорму. Этот способ более сложен в реализации, но зато универсален. У него довольно много параметров, но для данной задачи нас интересуют первые два.

ОткрытьФорму(<ИмяФормы>, <Параметры>)

ИмяФормы — в параметре следует указать полный путь к форме, которую вы собираетесь открыть.

Пример 1. Можно указать форму, которая является формой объекта по умолчанию:

"Документ.ПоступлениеТоваров.ФормаОбъекта"

Пример 2. Либо указать имя конкретной формы, которую вы хотите открыть. Если, например, форм объекта несколько.

"Документ.ПоступлениеТоваров.Форма.МояФормаОбъекта"

Параметры — структура параметров, которая передается в форму. Набор параметров разработчик выбирает сам, исходя их своих целей. Но некоторые параметры являются стандартными и используются для конкретных целей. Например, параметр Ключ, используется для указания платформе, форму какого объекта следует открыть (если Ключ, не указан, то будет открыта форма нового объекта). Таким образом в данный параметр необходимо передать ссылку на открываемый объект.

Пример 3. Открыть форму объекта для документа Поступление товаров.

ПараметрыФормы = Новый Структура;
ПараметрыФормы.Вставить("Ключ", Ссылка);
	
ОткрытьФорму("Документ.ПоступлениеТоваров.ФормаОбъекта", ПараметрыФормы);

Получить более подробную информацию по методу ОткрытьФорму можно в статье Как в 1с открыть форму программно

Открытие формы по навигационной ссылке

Если у вас есть навигационная ссылка на документ или справочник, перейти по ней и открыть форму объекта можно, используя метод ПерейтиПоНавигационнойСсылке.

ПерейтиПоНавигационнойСсылке(<НавигационнаяСсылка>)

Пример 4.

НавигационнаяСсылка = "e1cib/data/Документ._ДемоПоступлениеТоваров?ref=acb79eb068770e2511e47c89f0b33406";
ПерейтиПоНавигационнойСсылке(НавигационнаяСсылка);

Также навигационную ссылку можно получить из обычной ссылки. Для этого используется метод ПолучитьНавигационнуюСсылку.

ПолучитьНавигационнуюСсылку(<Объект>, <ИмяРеквизита>, <Индекс>)

В параметр Объект, в том числе, можно передать ссылку на документ или справочник.

Пример 5. Получить навигационную ссылку, используя обычную ссылку и открыть форму объекта.

НавигационнаяСсылка = ПолучитьНавигационнуюСсылку(Ссылка);
ПерейтиПоНавигационнойСсылке(НавигационнаяСсылка);

Сообщение Как в 1с открыть ссылку на документ появились сначала на 1cguide.ru.

• условиях раздела ГДЕ;
• в качестве значения поля запроса;
• конструкциях ВЫБОР КОГДА…;
• конструкциях ЕСТЬNULL;
• условиях связей таблиц.

Пустая ссылка в условиях запросов 1с

Для использования пустой ссылки ее необходимо передать ее в запрос при помощи параметра. Также можно использовать конструкцию ЗНАЧЕНИЕ.

ЗНАЧЕНИЕ(<ОбъектМетаданных>.ПустаяСсылка)

Здесь ОбъектМетаданных выражение вида:

• Документ.ИмяДокумента;
• Справочник.ИмяДокумента и т.д.

Пример 1. При помощи запроса получить верхний уровень иерархии справочника Номенклатура.

Запрос = Новый Запрос;
Запрос.Текст = 
"ВЫБРАТЬ
|    Номенклатура.Ссылка КАК Ссылка
|ИЗ
|    Справочник.Номенклатура КАК Номенклатура
|ГДЕ
|    Номенклатура.Родитель = ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка)";

Пример 2. При помощи запроса получить все элементы справочника Номенклатура, кроме тех, у кого нет родителя.

Запрос = Новый Запрос;

ПустаяСсылка = Справочники.Номенклатура.ПустаяСсылка;
Запрос.УстановитьПараметр("ПустаяСсылка", ПустаяСсылка);

Запрос.Текст = 
"ВЫБРАТЬ
|    Номенклатура.Ссылка КАК Ссылка
|ИЗ
|    Справочник.Номенклатура КАК Номенклатура
|ГДЕ
|    НЕ Номенклатура.Родитель = &ПустаяСсылка";

Следует помнить, что в запросе нельзя реализовать проверку сразу на все пустые ссылки. Всегда требуется указывать, пустую ссылку какого справочника, документа вы имеете в виду.

Пустая ссылка в качестве значения поля

Пустая ссылка в запросе 1с может использоваться в качестве значения поля. Как в чистом виде, так и в конструкциях ВЫБОР КОГДА… или ЕСТЬNULL.

Пример 3. Создать пустую временную таблицу ТаблицаНоменклатуры.

Запрос.Текст = 
"ВЫБРАТЬ
|    ЗНАЧЕНИЕ(Справочник.Номенклатура.ПустаяСсылка) КАК Номенклатура,
|    0 КАК Цена
|ПОМЕСТИТЬ ТаблицаНоменклатуры
|ГДЕ
|    ЛОЖЬ

Пример 4. При помощи запроса получить список номенклатуры со значениями дополнительного сведения Цвет.

Запрос.Текст = 
"ВЫБРАТЬ
|    Номенклатура.Ссылка КАК Ссылка,
|    ЕСТЬNULL(Сведения.Значение, 
|             ЗНАЧЕНИЕ(Справочник.ЗначенияСвойствОбъектов.ПустаяСсылка)) КАК Цвет
|ИЗ
|    Справочник.Номенклатура КАК Номенклатура
|    ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ДополнительныеСведения КАК Сведения
|        ПО Номенклатура.Ссылка = Сведения.Объект
|            И Сведения.Свойство = &СвойствоЦвет";

Пример 5. В запросе из предыдущего примера использовать конструкцию ВЫБОР КОГДА… вместо ЕСТЬNULL.

Запрос.Текст = 
"ВЫБРАТЬ
|    Номенклатура.Ссылка КАК Ссылка,
|    ВЫБОР
|        КОГДА НЕ Сведения.Значение ЕСТЬ NULL
|            ТОГДА Сведения.Значение
|        ИНАЧЕ ЗНАЧЕНИЕ(Справочник.ЗначенияСвойствОбъектов.ПустаяСсылка)
|    КОНЕЦ КАК Цвет
|ИЗ
|    Справочник.Номенклатура КАК Номенклатура
|    ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ДополнительныеСведения КАК Сведения
|        ПО Номенклатура.Ссылка = Сведения.Объект
|        И Сведения.Свойство = &СвойствоЦвет";

Пустая ссылка в связях запроса 1с

Проверку на пустую ссылку можно использовать и в условиях связи таблиц.

Пример 6. Получить список номенклатуры, а также значения дополнительного сведения Индекс. Индекс выводить только для номенклатуры с заполненным реквизитом СтранаПроисхождения.

Запрос.Текст = 
"ВЫБРАТЬ
|    Номенклатура.Ссылка КАК Ссылка,
|    Сведения.Значение КАК ПочтовыйИндекс
|ИЗ
|    Справочник.Номенклатура КАК Номенклатура
|    ЛЕВОЕ СОЕДИНЕНИЕ РегистрСведений.ДополнительныеСведения КАК Сведения
|    ПО (Номенклатура.Ссылка = Сведения.Объект
|        И Сведения.Свойство = &СвойствоИндекс
|        И Номенклатура.СтранаПроисхождения 
|               <> ЗНАЧЕНИЕ(Справочник.СтраныМира.ПустаяСсылка))";

Также прочитайте статью о структуре оператора Выбрать, языка запросов: Язык запросов 1с — оператор Выбрать

Сообщение Пустая ссылка в запросе 1с проверка и использование появились сначала на 1cguide.ru.